索引数组

可以使用多种方法来创建 Array 实例或 Vector 实例。但是，创建每种数组类型的方法多少有些不同。

用于将元素添加到索引数组的最基本方法是使用数组访问 ( [] ) 运算符。若要设置索引数组元素的值，请在赋值语句的左侧使用 Array 或 Vector 对象名称和索引编号：

songTitles[5] = "Happy Birthday";

如果 Array 或 Vector 在该索引处还没有元素，则会创建该索引并将值存储在那里。如果该索引处存在值，则新值会替换现有值。

Array 对象允许您在任何索引位置创建元素。但是对于 Vector 对象，您只能向现有索引或下一个可用索引赋值。下一个可用索引对应于 Vector 对象的 length 属性。向 Vector 对象添加新元素的最安全方式是使用类似于下面的清单的代码：

myVector[myVector.length] = valueToAdd;

可以使用 Array 和 Vector 类的三种方法（ push() 、 unshift() 和 splice() ）将元素插入索引数组。 push() 方法用于在数组末尾添加一个或多个元素。换言之，使用 push() 方法在数组中插入的最后一个元素将具有最大索引号。 unshift() 方法用于在数组开头插入一个或多个元素，并且始终在索引号 0 处插入。 splice() 方法用于在数组中的指定索引处插入任意数目的项目。

下面的示例对所有三种方法进行了说明。它创建一个名为 planets 的数组，以便按照行星距离太阳由近到远的顺序存储各个行星的名称。首先，调用 push() 方法以添加初始项目 Mars 。接着，调用 unshift() 方法在数组开头插入项 Mercury 。最后，调用 splice() 方法在 Mercury 之后和 Mars 之前插入项 Venus 和 Earth 。传递给 splice() 的第一个参数是整数 1，它用于指示从索引 1 处开始插入。传递给 splice() 的第二个参数是整数 0，它指示不应删除任何项。传递给 splice() 的第三和第四个参数 Venus 和 Earth 为要插入的项。

var planets:Array = new Array(); 
planets.push("Mars"); // array contents: Mars 
planets.unshift("Mercury"); // array contents: Mercury,Mars 
planets.splice(1, 0, "Venus", "Earth"); 
trace(planets); // array contents: Mercury,Venus,Earth,Mars

push() 和 unshift() 方法均返回一个无符号整数，它们表示修改后的数组长度。在用于插入元素时， splice() 方法返回空数组，这看上去也许有点奇怪，但考虑到 splice() 方法的多用途性，您便会觉得这样更有意义。通过使用 splice() 方法，不仅可以将元素插入到数组中，而且还可以从数组中删除元素。用于删除元素时， splice() 方法将返回包含被删除元素的数组。

用于检索索引数组中的元素值的最简单方法是使用数组访问 ( [] ) 运算符。若要检索索引数组元素的值，请在赋值语句的右侧使用 Array 或 Vector 对象名称和索引编号：

var myFavoriteSong:String = songTitles[3];

可以尝试使用不存在元素的位置的索引来检索 Array 或 Vector 中的值。在这种情况下，Array 对象返回未定义的值，而 Vector 会引发 RangeError 异常。

可以使用 Array 和 Vector 类的三种方法（ pop() 、 shift() 和 splice() ）删除元素。 pop() 方法用于从数组末尾删除一个元素。换言之，它将删除位于最大索引号处的元素。 shift() 方法用于从数组开头删除一个元素，也就是说，它始终删除索引号 0 处的元素。 splice() 方法既可用来插入元素，也可以删除任意数目的元素，其操作的起始位置位于由发送到此方法的第一个参数指定的索引号处。

下面的示例使用所有三种方法从 Array 实例中删除元素。该示例创建一个名为 oceans 的 Array，用于存储较大水域的名称。Array 中的某些名称为湖泊的名称而非海洋的名称，因此需要将其删除。

首先，使用 splice() 方法删除项 Aral 和 Superior ，并插入项 Atlantic 和 Indian 。传递给 splice() 的第一个参数是整数 2，它指示应从列表中的第三个项（即索引 2 处）开始执行操作。第二个参数 2 指示应删除两个项。其余两个参数 Atlantic 和 Indian 是要在索引 2 处插入的值。

然后，使用 pop() 方法删除数组中的最后一个元素 Huron 。最后，使用 shift() 方法删除数组中的第一个项 Victoria 。

var oceans:Array = ["Victoria", "Pacific", "Aral", "Superior", "Indian", "Huron"]; 
oceans.splice(2, 2, "Arctic", "Atlantic"); // replaces Aral and Superior 
oceans.pop(); // removes Huron 
oceans.shift(); // removes Victoria 
trace(oceans);// output: Pacific,Arctic,Atlantic,Indian

pop() 和 shift() 方法均返回已删除的项。对于 Array 实例，由于数组可以包含任意数据类型的值，因而返回值的数据类型为 Object。对于 Vector 实例，返回值的数据类型是 Vector 的基本类型。 splice() 方法返回包含所删除的值的 Array 或 Vector。可以更改 oceans Array 示例，以使 splice() 调用将返回的 Array 分配给新的 Array 变量，如下面的示例所示：

var lakes:Array = oceans.splice(2, 2, "Arctic", "Atlantic"); 
trace(lakes); // output: Aral,Superior

您可能会遇到对 Array 对象元素使用 delete 运算符的代码。 delete 运算符会将 Array 元素的值设置为 undefined ，但它不会从 Array 中删除元素。例如，下面的代码对 oceans Array 中的第三个元素使用 delete 运算符，但此 Array 的长度仍然为 5：

var oceans:Array = ["Arctic", "Pacific", "Victoria", "Indian", "Atlantic"]; 
delete oceans[2]; 
trace(oceans);// output: Arctic,Pacific,,Indian,Atlantic 
trace(oceans[2]); // output: undefined 
trace(oceans.length); // output: 5

可以使用数组的 length 属性截断 Array 或 Vector。如果您将某个索引数组的 length 属性设置为小于该数组的当前长度的长度，则该数组会被截断，从而删除存储在比 length 的新值减 1 大的索引编号处的所有元素。例如，如果 oceans 数组进行了排序，以使所有有效项都位于数组开头，则可以使用 length 属性删除位于数组后部的项，如下面的代码所示：

var oceans:Array = ["Arctic", "Pacific", "Victoria", "Aral", "Superior"]; 
oceans.length = 2; 
trace(oceans); // output: Arctic,Pacific

可以使用三种方法（ reverse() 、 sort() 和 sortOn() ）通过排序或反向排序来更改索引数组的顺序。所有这些方法都用来修改现有数组。下表概述了这些方法及其针对 Array 和 Vector 对象的行为：

var oceans:Array = ["Arctic", "Atlantic", "Indian", "Pacific"]; 
oceans.reverse(); 
trace(oceans); // output: Pacific,Indian,Atlantic,Arctic

var poets:Array = ["Blake", "cummings", "Angelou", "Dante"]; 
poets.sort(); // default sort 
trace(poets); // output: Angelou,Blake,Dante,cummings 
 
poets.sort(Array.CASEINSENSITIVE); 
trace(poets); // output: Angelou,Blake,cummings,Dante 
 
poets.sort(Array.DESCENDING); 
trace(poets); // output: cummings,Dante,Blake,Angelou 
 
poets.sort(Array.DESCENDING | Array.CASEINSENSITIVE); // use two options 
trace(poets); // output: Dante,cummings,Blake,Angelou

var names:Array = new Array("John Q. Smith", "Jane Doe", "Mike Jones"); 
function orderLastName(a, b):int 
{ 
    var lastName:RegExp = /\b\S+$/; 
    var name1 = a.match(lastName); 
    var name2 = b.match(lastName); 
    if (name1 < name2) 
    { 
        return -1; 
    } 
    else if (name1 > name2) 
    { 
        return 1; 
    } 
    else 
    { 
        return 0; 
    } 
} 
trace(names); // output: John Q. Smith,Jane Doe,Mike Jones 
names.sort(orderLastName); 
trace(names); // output: Jane Doe,Mike Jones,John Q. Smith

var poets:Array = new Array(); 
poets.push({name:"Angelou", born:"1928"}); 
poets.push({name:"Blake", born:"1757"}); 
poets.push({name:"cummings", born:"1894"}); 
poets.push({name:"Dante", born:"1265"}); 
poets.push({name:"Wang", born:"701"});

poets.sortOn("born", Array.NUMERIC); 
for (var i:int = 0; i < poets.length; ++i) 
{ 
    trace(poets[i].name, poets[i].born); 
} 
/* output: 
Wang 701 
Dante 1265 
Blake 1757 
cummings 1894 
Angelou 1928 
*/

var indices:Array; 
indices = poets.sortOn("born", Array.NUMERIC | Array.RETURNINDEXEDARRAY); 
for (var i:int = 0; i < indices.length; ++i) 
{ 
    var index:int = indices[i]; 
    trace(poets[index].name, poets[index].born); 
} 
/* output: 
Wang 701 
Dante 1265 
Blake 1757 
cummings 1894 
Angelou 1928 
*/

Array 和 Vector 类的四种方法 concat() 、 join() 、 slice() 和 toString() 均可用于查询数组的信息，而不修改数组。 concat() 和 slice() 方法返回新数组；而 join() 和 toString() 方法返回字符串。 concat() 方法将新数组和元素列表作为参数，并将其与现有数组结合起来创建新数组。 slice() 方法有两个名为 startIndex 和 endIndex 的参数，并返回一个新数组，新数组中包含从现有数组“分离”的元素副本。分离从 startIndex 处的元素开始，到 endIndex 处的前一个元素结束。值得强调的是， endIndex 处的元素不包括在返回值中。

以下示例通过 concat() 和 slice() 方法，使用其他数组的元素创建新数组：

var array1:Array = ["alpha", "beta"]; 
var array2:Array = array1.concat("gamma", "delta"); 
trace(array2); // output: alpha,beta,gamma,delta 
 
var array3:Array = array1.concat(array2); 
trace(array3); // output: alpha,beta,alpha,beta,gamma,delta 
 
var array4:Array = array3.slice(2,5); 
trace(array4); // output: alpha,beta,gamma

可以使用 join() 和 toString() 方法查询数组，并将其内容作为字符串返回。如果 join() 方法没有使用参数，则这两个方法的行为相同，它们都返回一个字符串，其中包含数组中所有元素的逗号分隔列表。与 toString() 方法不同， join() 方法接受名为 delimiter 的参数；可以使用此参数，选择要用作返回字符串中各个元素之间分隔符的符号。

下面的示例创建名为 rivers 的 Array，并调用 join() 和 toString() 以便采用字符串形式返回该 Array 中的值。 toString() 方法用于返回以逗号分隔的值 ( riverCSV )；而 join() 方法用于返回以 + 字符分隔的值。

var rivers:Array = ["Nile", "Amazon", "Yangtze", "Mississippi"]; 
var riverCSV:String = rivers.toString(); 
trace(riverCSV); // output: Nile,Amazon,Yangtze,Mississippi 
var riverPSV:String = rivers.join("+"); 
trace(riverPSV); // output: Nile+Amazon+Yangtze+Mississippi

对于 join() 方法，应注意的一个问题是，无论为主数组元素指定的分隔符是什么，为嵌套 Array 或 Vector 实例返回的值始终以逗号作为分隔符，如下面的示例所示：

var nested:Array = ["b","c","d"]; 
var letters:Array = ["a",nested,"e"];  
var joined:String = letters.join("+"); 
trace(joined); // output: a+b,c,d+e