针对 JavaScript 开发人员的 ActionScript 基础知识

与 JavaScript 类似，ActionScript 也基于 ECMAScript 语言规范；因此这两种语言包含公用的核心语法。例如，以下代码在 JavaScript 和 ActionScript 中的功能是一样的：

var str1 = "hello"; 
var str2 = " world."; 
var str = reverseString(str1 + str2); 
     
function reverseString(s) { 
    var newString = ""; 
    var i; 
    for (i = s.length - 1; i >= 0; i--) { 
        newString += s.charAt(i); 
    } 
    return newString; 
}

不过，这两种语言在语法和工作方式上存在差异。例如，如果使用 ActionScript 3.0，则前面的代码示例可以写成如下形式（在 SWF 文件中）：

function reverseString(s:String):String { 
    var newString:String = ""; 
    for (var i:int = s.length - 1; i >= 0; i--) { 
        newString += s.charAt(i); 
    } 
    return newString; 
}

Adobe AIR 中的 HTML 内容所支持的 JavaScript 版本为 JavaScript 1.7。本主题介绍了 JavaScript 1.7 和 ActionScript 3.0 之间的差异。

运行时包括一些可提供高级功能的内置类。在运行时，HTML 页中的 JavaScript 可以访问这些类。相同的运行时类既可用于 ActionScript（在 SWF 文件中），也可用于 JavaScript（在浏览器上运行的 HTML 文件中）。但是，当前有关这些类（未包含在 针对 HTML 开发人员的 Adobe AIR API 参考 中）的 API 文档使用 ActionScript 语法描述它们。换句话说，有关运行时的某些高级功能，请参阅 用于 Adobe Flash Platform 的 ActionScript 3.0 参考 。了解 ActionScript 的基础知识有助于您了解如何在 JavaScript 中使用这些运行时类。

例如，以下 JavaScript 代码可播放 MP3 文件的声音：

var file = air.File.userDirectory.resolve("My Music/test.mp3"); 
var sound = air.Sound(file); 
sound.play();

基中每个代码行通过 JavaScript 调用运行时功能。

在 SWF 文件中，ActionScript 代码可以访问这些运行时功能，如下面的代码所示：

var file:File = File.userDirectory.resolve("My Music/test.mp3"); 
var sound = new Sound(file); 
sound.play();

ActionScript 3.0 是一种 强类型 语言。这意味着您可以为变量指定数据类型。例如，前面示例中的第一行可以写成如下形式：

var str1:String = "hello";

其中 str1 变量被声明为 String 类型。针对 str1 变量的所有后续赋值都将向该变量赋予 String 值。

您可以为变量、函数参数和函数返回类型指定类型。因此，前面示例中的函数声明在 ActionScript 中将如下所示：

function reverseString(s:String):String { 
       var newString:String = ""; 
       for (var i:int = s.length - 1; i >= 0; i--) { 
           newString += s.charAt(i); 
       } 
       return newString; 
}

尽管指定类型在 ActionScript 中是一项可选操作，但声明对象类型具有以下优势：

• 对于指定了类型的对象，不仅可以在运行时检查数据类型，而且还可以在编译时检查数据类型（只要您使用的是严格模式）。在编译时进行类型检查有助于识别错误。（严格模式属于编译器选项。）

• 使用具有类型的对象可创建更有效的应用程序。

  为此，ActionScript 文档中的示例将使用数据类型。通常，只要删除类型声明（如“ :String ”），就可以将示例 ActionScript 代码转换为 JavaScript。

function exampleFunction(n:*):* { 
       trace("hi, " + n); 
}

ActionScript 3.0 包含 JavaScript 1.7 中所没有的类的相关功能。

public class ExampleClass { 
    public var x:Number; 
    public function ExampleClass(input:Number):void { 
        x = input; 
    } 
    public function greet():void { 
        trace("The value of x is: ", x); 
    } 
}

flash.filesystem.File

var myFile = new air.flash.filesystem.File();

在 ActionScript 3.0 和 JavaScript 中，函数可以包括参数。在 ActionScript 3.0 中，参数可以是必需参数，也可以是可选参数；而在 JavaScript 中，参数始终是可选参数。

以下 ActionScript 3.0 代码定义了一个函数，其中的一个参数 n 是必需参数：

function cube(n:Number):Number { 
    return n*n*n; 
}

以下 ActionScript 3.0 代码定义了一个要求 n 参数的函数。它还包含可选的 p 参数，其默认值为 1：

function root(n:Number, p:Number = 1):Number { 
    return Math.pow(n, 1/p); 
}

ActionScript 3.0 函数还可以接收任意数量的参数，这些参数通过在参数列表的结尾处使用 ...rest 语法来表示，如下所示：

function average(... args) : Number{ 
    var sum:Number = 0; 
    for (var i:int = 0; i < args.length; i++) { 
        sum += args[i]; 
    } 
    return (sum / args.length); 
}

在 ActionScript 3.0 编程中，将使用 事件侦听器 处理所有事件。事件侦听器是一个函数。当对象调度事件时，事件侦听器将响应该事件。将 ActionScript 对象事件作为函数参数传递给事件侦听器。此事件对象的使用与 JavaScript 中使用的 DOM 事件模型不同。

例如，当您调用 Sound 对象的 load() 方法（加载一个 MP3 文件）时，Sound 对象将尝试加载声音。然后，Sound 对象将调度下列任一事件：

任何可以调度事件的类可扩展 EventDispatcher 类或实现 IEventDispatcher 接口。（ActionScript 3.0 接口是用于定义类可实现的一系列方法的数据类型。）在 ActionScript 语言参考中，针对这些类的每个类列表中都包含一组该类可以调度的事件。

您可以注册事件侦听器函数，以使用调度该事件的对象的 addEventListener() 方法处理任何事件。例如，就 Sound 对象来说，您可以注册 progress 和 complete 事件，如以下 ActionScript 代码所示：

var sound:Sound = new Sound(); 
var urlReq:URLRequest = new URLRequest("test.mp3"); 
sound.load(urlReq); 
sound.addEventListener(ProgressEvent.PROGRESS, progressHandler); 
sound.addEventListener(Event.COMPLETE, completeHandler); 
 
function progressHandler(progressEvent):void { 
      trace("Progress " + progressEvent.bytesTotal + " bytes out of " + progressEvent.bytesTotal); 
} 
 
function completeHandler(completeEvent):void { 
      trace("Sound loaded."); 
}

在 AIR 中运行的 HTML 内容中，您可以将 JavaScript 函数注册为事件侦听器。以下代码对此进行了说明。（此代码假定 HTML 文档包含名为 progressTextArea 的 TextArea 对象。）

var sound = new runtime.flash.media.Sound(); 
var urlReq = new runtime.flash.net.URLRequest("test.mp3"); 
sound.load(urlReq); 
sound.addEventListener(runtime.flash.events.ProgressEvent.PROGRESS, progressHandler); 
sound.addEventListener(runtime.flash.events.Event.COMPLETE, completeHandler); 
 
function progressHandler(progressEvent) { 
      document.progressTextArea.value += "Progress " + progressEvent.bytesTotal + " bytes out of " + progressEvent.bytesTotal; 
} 
 
function completeHandler(completeEvent) { 
      document.progressTextArea.value += "Sound loaded.";