剪贴板数据格式

使用自定义数据格式将对象写入剪贴板后，可以从剪贴板中将对象数据作为引用读取，也可以将其作为原始对象的序列化副本读取。共有四种传输模式，这些模式确定了对象是以引用还是以序列化副本的形式传输：

将对象写入剪贴板时，可将任何不以保留前缀 air: 或 flash: 开头的字符串用于 格式 参数。请使用相同字符串作为读取对象的格式。下面的示例说明了如何从剪贴板读取对象和向其中写入对象：

public function createClipboardObject(object:Object):Clipboard{ 
    var transfer:Clipboard = Clipboard.generalClipboard; 
    transfer.setData("object", object, true); 
} 

function createClipboardObject(object){ 
    var transfer = new air.Clipboard(); 
    transfer.setData("object", object, true); 
}

若要从 Clipboard 对象中提取序列化对象（放置或粘贴操作之后），请使用相同格式名称和 CLONE_ONLY 或 CLONE_PREFFERED 传输模式。

var transfer:Object = clipboard.getData("object", ClipboardTransferMode.CLONE_ONLY); 

var transfer = clipboard.getData("object", air.ClipboardTransferMode.CLONE_ONLY);

此时将始终向 Clipboard 对象添加一个引用。若要从 Clipboard 对象中提取引用（放置或粘贴操作之后）而不是提取序列化副本，请使用 ORIGINAL_ONLY 或 ORIGINAL_PREFFERED 传输模式：

var transferredObject:Object =  
    clipboard.getData("object", ClipboardTransferMode.ORIGINAL_ONLY); 

var transferredObject =  
    clipboard.getData("object", air.ClipboardTransferMode.ORIGINAL_ONLY);

仅当 Clipboard 对象是源自当前应用程序中时，引用才有效。当引用可用时，可使用 ORIGINAL_PREFFERED 传输模式访问该引用；当引用不可用时，则可使用该模式访问序列化副本。

下面的示例说明了如何实现延迟呈现函数。

当用户按下“Copy”按钮时，应用程序将清除系统剪贴板以确保不会留下上次剪贴板操作的数据。然后， setDataHandler() 方法将 renderData() 函数设置为剪贴板渲染器。

当用户从目标文本字段的上下文菜单中选择“粘贴”命令时，应用程序将访问剪贴板并设置目标文本。由于已使用函数而不是字符串设置了剪贴板上的文本数据格式，剪贴板将调用 renderData() 函数。 renderData() 函数将返回源文本中的文本，然后将其分配给目标文本。

请注意，如果按下“Paste”按钮前编辑源文本，则此编辑操作将反映到粘贴的文本中，即使按下“Paste”按钮后再进行编辑也是如此。这是因为呈现函数直到按下“Paste”按钮后才会复制源文本。（当在实际的应用程序中使用延迟呈现时，最好以某种方式存储或保护源数据以防止出现此问题。）

 package {  
    import flash.desktop.Clipboard; 
    import flash.desktop.ClipboardFormats; 
    import flash.desktop.ClipboardTransferMode; 
    import flash.display.Sprite; 
    import flash.text.TextField; 
    import flash.text.TextFormat; 
    import flash.text.TextFieldType; 
    import flash.events.MouseEvent; 
    import flash.events.Event; 
    public class DeferredRenderingExample extends Sprite  
    {  
         private var sourceTextField:TextField; 
        private var destination:TextField; 
        private var copyText:TextField; 
        public function DeferredRenderingExample():void 
        { 
            sourceTextField = createTextField(10, 10, 380, 90); 
            sourceTextField.text = "Neque porro quisquam est qui dolorem " 
                + "ipsum quia dolor sit amet, consectetur, adipisci velit."; 
                 
            copyText = createTextField(10, 110, 35, 20); 
            copyText.htmlText = "<a href='#'>Copy</a>"; 
            copyText.addEventListener(MouseEvent.CLICK, onCopy); 
 
            destination = createTextField(10, 145, 380, 90); 
            destination.addEventListener(Event.PASTE, onPaste); 
        } 
        private function createTextField(x:Number, y:Number, width:Number, 
                        height:Number):TextField 
        { 
            var newTxt:TextField = new TextField(); 
            newTxt.x = x; 
            newTxt.y = y; 
            newTxt.height = height; 
            newTxt.width = width; 
            newTxt.border = true; 
            newTxt.multiline = true; 
            newTxt.wordWrap = true; 
            newTxt.type = TextFieldType.INPUT; 
            addChild(newTxt); 
            return newTxt; 
        } 
        public function onCopy(event:MouseEvent):void 
        { 
            Clipboard.generalClipboard.clear(); 
            Clipboard.generalClipboard.setDataHandler(ClipboardFormats.TEXT_FORMAT, 
                            renderData); 
        } 
        public function onPaste(event:Event):void 
        { 
            sourceTextField.text = 
            Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT).toString; 
        } 
        public function renderData():String 
        { 
            trace("Rendering data"); 
            var sourceStr:String = sourceTextField.text; 
            if (sourceTextField.selectionEndIndex > 
                     sourceTextField.selectionBeginIndex) 
            { 
                return sourceStr.substring(sourceTextField.selectionBeginIndex, 
                                    sourceTextField.selectionEndIndex); 
            } 
            else 
            { 
                return sourceStr; 
            } 
        } 
    } 
}

<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" width="326" height="330" applicationComplete="init()"> 
    <mx:Script> 
    <![CDATA[ 
    import flash.desktop.Clipboard; 
    import flash.desktop.ClipboardFormats; 
     
    public function init():void 
    { 
        destination.addEventListener("paste", doPaste); 
    } 
 
    public function doCopy():void 
    { 
        Clipboard.generalClipboard.clear(); 
        Clipboard.generalClipboard.setDataHandler(ClipboardFormats.TEXT_FORMAT, renderData); 
    } 
    public function doPaste(event:Event):void 
    { 
        destination.text = Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT).toString; 
    } 
     
    public function renderData():String{ 
        trace("Rendering data"); 
        return source.text; 
    } 
    ]]> 
    </mx:Script> 
    <mx:Label x="10" y="10" text="Source"/> 
    <mx:TextArea id="source" x="10" y="36" width="300" height="100"> 
        <mx:text>Neque porro quisquam est qui dolorem ipsum quia dolor sit amet, consectetur, adipisci velit.</mx:text> 
    </mx:TextArea> 
    <mx:Label x="10" y="181" text="Destination"/> 
    <mx:TextArea id="destination"  x="12" y="207" width="300" height="100"/> 
    <mx:Button click="doCopy();" x="91" y="156" label="Copy"/> 
</mx:Application>