Metin girdisi yakalama

Varsayılan olarak, bir metin alanının type özelliği dynamic olarak ayarlanmıştır. TextFieldType sınıfını kullanarak type özelliğini input olarak ayarlarsanız, kullanıcı girdisini toplayabilir ve değeri uygulamanızın diğer bölümlerinde kullanmak için kaydedebilirsiniz. Girdi metinleri, formlar ve programın başka bir yerinde kullanılmak üzere kullanıcı tarafından bir metin değeri tanımlanmasını isteyen herhangi bir uygulama için kullanışlıdır.

Örneğin, aşağıdaki kod myTextBox adlı bir girdi metni alanı oluşturur. Kullanıcı alana metin girdiğinde, textInput olayı tetiklenir. textInputCapture adlı bir olay işleyicisi, girilen metnin dizesini yakalar ve bu dizeye bir değişken atar. Flash Player veya AIR, yeni metni myOutputBox adlı başka bir metin alanında görüntüler.

package 
{ 
    import flash.display.Sprite; 
    import flash.display.Stage; 
    import flash.text.*; 
    import flash.events.*; 
 
    public class CaptureUserInput extends Sprite 
    { 
        private var myTextBox:TextField = new TextField(); 
        private var myOutputBox:TextField = new TextField(); 
        private var myText:String = "Type your text here."; 
 
        public function CaptureUserInput() 
        { 
            captureText(); 
        } 
         
        public function captureText():void 
        { 
            myTextBox.type = TextFieldType.INPUT; 
            myTextBox.background = true; 
            addChild(myTextBox); 
            myTextBox.text = myText; 
            myTextBox.addEventListener(TextEvent.TEXT_INPUT, textInputCapture); 
        } 
         
        public function textInputCapture(event:TextEvent):void 
        { 
            var str:String = myTextBox.text; 
            createOutputBox(str); 
        } 
             
        public function createOutputBox(str:String):void 
        { 
            myOutputBox.background = true; 
            myOutputBox.x = 200; 
            addChild(myOutputBox); 
            myOutputBox.text = str; 
        } 
         
    } 
}