Ağ iletişimi ve iletişim temelleri

NetworkInfo nesnesini uygulamanızda kullanabileceğiniz mevcut donanım ve yazılım ağlarını keşfetmek için kullanabilirsiniz. NetworkInfo nesnesi bir singleton nesnesidir. Bu nedenle bir tane oluşturmanıza gerek yoktur. NetworkInfo nesnesine ulaşmak için onun yerine networkInfo statik sınıf özelliğini kullanın. NetworkInfo nesnesi ayrıca, kullanılabilir arabirimlerden biri değiştiğinde networkChange olayı gönderir.

NetworkInterface nesnelerinin listesi için findInterfaces() yöntemini çağırın. Listedeki her Each NetworkInterface nesnesi kullanılabilir arabirimlerden birini tanımlar. NetworkInterface nesnesi IP adresi, donanım adresi, maksimum iletim birimi ve arabirimin etkin olup olmadığıyla ilgili bilgiler sağlar.

Aşağıdaki kod örneği, istemci bilgisayarın her arabiriminin NetworkInterface özelliklerini izler:

package { 
import flash.display.Sprite; 
import flash.net.InterfaceAddress; 
import flash.net.NetworkInfo; 
import flash.net.NetworkInterface; 
 
public class NetworkInformationExample extends Sprite 
{ 
    public function NetworkInformationExample() 
    { 
        var networkInfo:NetworkInfo = NetworkInfo.networkInfo; 
        var interfaces:Vector.<NetworkInterface> = networkInfo.findInterfaces(); 
         
        if( interfaces != null ) 
        { 
            trace( "Interface count: " + interfaces.length ); 
            for each ( var interfaceObj:NetworkInterface in interfaces ) 
            { 
                trace( "\nname: "             + interfaceObj.name ); 
                trace( "display name: "     + interfaceObj.displayName ); 
                trace( "mtu: "                 + interfaceObj.mtu ); 
                trace( "active?: "             + interfaceObj.active ); 
                trace( "parent interface: " + interfaceObj.parent ); 
                trace( "hardware address: " + interfaceObj.hardwareAddress ); 
                if( interfaceObj.subInterfaces != null ) 
                { 
                    trace( "# subinterfaces: " + interfaceObj.subInterfaces.length ); 
                } 
                trace("# addresses: "     + interfaceObj.addresses.length ); 
                for each ( var address:InterfaceAddress in interfaceObj.addresses ) 
                { 
                    trace( "  type: "           + address.ipVersion ); 
                    trace( "  address: "         + address.address ); 
                    trace( "  broadcast: "         + address.broadcast ); 
                    trace( "  prefix length: "     + address.prefixLength ); 
                } 
            }             
        } 
    }     
} 
}

Daha fazla bilgi için bkz.:

• NetworkInfo

• NetworkInterface

• InterfaceAddress

• Flexpert: Detecting the network connection type with Flex 4.5 (Flex 4.5 ile ağ bağlantısı türünü belirleme)

AIR uygulamanız, güvenli olmayan ve değişken ağ bağlantıları içeren ortamlarda çalışabilir. Adobe AIR, bir uygulamanın çevrimiçi kaynaklara yönelik bağlantıları yönetmesine yardımcı olmak için, ağ bağlantısının her kullanılabilir veya kullanılamaz oluşunda bir ağ değişikliği olayı gönderir. Hem NetworkInfo nesnesi hem de uygulamanın NativeApplication nesnesi, networkChange olayını gönderir. Bu olaya tepki vermek için bir dinleyici ekleyin:

NetworkInfo.networkInfo.addEventListener(Event.NETWORK_CHANGE, onNetworkChange); 

Ve bir olay işleyici işlevi tanımlayın:

function onNetworkChange(event:Event) 
{ 
    //Check resource availability 
} 

networkChange olayı, tüm ağ etkinliğinde gerçekleşen bir değişikliği değil, yalnızca bir ağ bağlantısının değiştiğini gösterir. AIR, ağ değişikliğinin anlamını yorumlamaya çalışmaz. Ağa bağlı bir bilgisayar birçok gerçek ve sanal bağlantıya sahip olabilir. Bu nedenle bir bağlantının kaybedilmesi, kaynağın kaybedilmesi anlamına gelmeyebilir. Diğer yandan, yeni bağlantılar da iyileştirilmiş kaynak kullanılabilirliğini garanti etmez. Bazen yeni bir bağlantı, önceden kullanılabilir olan bir kaynağa erişimi bloke bile edebilir (örneğin VPN'e bağlanıldığında).

Genellikle, bir uygulamanın uzak bir kaynağa bağlanıp bağlanamayacağını belirlemenin tek yolu, denemektir. Hizmet izleme çerçevesi, ağ bağlanabilirliğindeki değişikliklere yanıt vermek için belirli bir ana bilgisayara olay bazlı araçlar sağlar.

DNSResolver sınıfını kullanarak DNS kaynak kayıtlarını arayabilirsiniz. DNS kaynak kayıtları alan adının IP adresi ve IP adresinin alan adı gibi bilgiler verir. Aşağıdaki türlerdeki DNS kaynak kayıtlarını arayabilirsiniz:

• ARecord—Bir sunucunun IPv4 adresi

• AAAARecord—Bir ana bilgisayarın IPv6 adresi

• MXRecord (mail exchange record)—ana bilgisayarın mesaj alışverişi kaydı.

• PTRRecord—bir IP adresinin internet sunucu adresi

• SRVRecord—bir hizmetin hizmet kaydıdır.

Bir kayıt aramak için sorgulama dizesini kayıt türünü gösteren sınıf nesnesini DNSResolver nesnesinin lookup() yöntemine geçirin. Sorgulama dizesi kayıt türüne göre değişir:

Aşağıdaki kod örneği ana bilgisayarın “example.com” IP adresini arar.

package 
{ 
    import flash.display.Sprite; 
    import flash.events.DNSResolverEvent; 
    import flash.events.ErrorEvent; 
    import flash.net.dns.ARecord; 
    import flash.net.dns.DNSResolver; 
 
    public class DNSResolverExample extends Sprite 
    { 
         
        public function DNSResolverExample() 
        { 
            var resolver:DNSResolver = new DNSResolver(); 
            resolver.addEventListener( DNSResolverEvent.LOOKUP, lookupComplete ); 
            resolver.addEventListener( ErrorEvent.ERROR, lookupError ); 
 
            resolver.lookup( "example.com.", ARecord ); 
        } 
         
        private function lookupComplete( event:DNSResolverEvent ):void 
        { 
            trace( "Query string: " + event.host ); 
            trace( "Record count: " + event.resourceRecords.length ); 
            for each( var record:* in event.resourceRecords ) 
            { 
                if( record is ARecord ) trace( record.address ); 
            } 
             
        } 
 
        private function lookupError( error:ErrorEvent ):void 
        { 
            trace("Error: " + error.text ); 
        } 
    } 
}

Daha fazla bilgi için bkz.:

• DNSResolver

• DNSResolverEvent

• ARecord

• AAAARecord

• MXRecord

• PTRRecord

• SRVRecord