Paylaşılan nesneler

Paylaşılan nesneler tarayıcı tanımlama bilgileri gibi işlev görür. Kullanıcının yerel sabit sürücüsünde veri depolamak ve aynı oturumda veya daha sonraki bir oturumda bu veriyi çağırmak için SharedObject sınıfını kullanırsınız. Uygulamalar yalnızca kendi SharedObject verilerine erişebilir, ve bunu yalnızca aynı etki alanında çalışıyorsa yapabilir. Veri sunucuya gönderilmez ve diğer etki alanlarında çalışan uygulamaları tarafından erişilemez, ancak aynı etki alanında bulunan uygulamalar tarafından erişilebilir hale getirilebilir.

Bir SharedObject nesnesi oluşturmak için şu sözdizimine sahip olan SharedObject.getLocal() yöntemini kullanın:

SharedObject.getLocal("objectName" [, pathname]): SharedObject

Aşağıdaki örnek mySO adlı bir paylaşılan nesne oluşturur:

public var mySO:SharedObject; 
mySO = SharedObject.getLocal("preferences");

Bu işlem, istemcinin makinesinde preferences.sol adlı bir dosya oluşturur.

Yerel terimi paylaşılan nesnenin konumuyla ilgilidir. Bu durumda Adobe® Flash® Player, SharedObject dosyasını istemcinin ana dizininde yerel olarak saklar.

Bir paylaşılan nesne oluşturduğunuzda, Flash Player, sanal alanının içindeki etki alanı ve uygulama için yeni bir dizin oluşturur. Ayrıca SharedObject verisini saklayan bir *.sol dosyası oluşturur. Bu dosyanın varsayılan konumu, kullanıcının ana dizininin bir altdizinidir. Aşağıdaki tabloda bu dizinin varsayılan konumları gösterilmektedir:

c:/Documents and Settings/username/Application Data/Macromedia/Flash Player/#SharedObjects

c:/Users/username/AppData/Roaming/Macromedia/Flash Player/#SharedObjects

/Users/username/Library/Preferences/Macromedia/Flash Player/#SharedObjects/web_domain/path_to_application/application_name/object_name.sol

/home/username/.macromedia/Flash_Player/#SharedObjects/web_domain/path_to_application/application_name/object_name.sol

#SharedObjects dizininin altında rastgele adlandırılmış bir dizin mevcuttur. Onun altında uygulamayı önce ana bilgisayar adıyla, ardından yolla ve son olarak da *.sol dosyasıyla eşleştiren bir dizin bulunmaktadır.

Örneğin, yerel ana bilgisayarda, /sos adlı bir altdizinde bulunan MyApp.swf adlı bir uygulama talep ederseniz, Flash Player *.sol dosyasını Windows XP'de aşağıdaki konumda saklar:

c:/Documents and Settings/fred/Application Data/Macromedia/Flash Player/#SharedObjects/KROKWXRK/#localhost/sos/MyApp.swf/data.sol

Varsayılan olarak Flash, etki alanı başına 100 KB'a kadar büyüklüğe sahip yerel olarak kalıcı SharedObject nesnelerini kaydedebilir. Bu değer kullanıcı tarafından yapılandırılabilir. Uygulama, bir paylaşılan nesneye veri kaydetmeye çalıştığında (bu işlem veri boyutunu 100 KB'tan fazla yapar), Flash Player, Yerel Saklama iletişim kutusunu görüntüler ve bu da kullanıcının erişim talep eden etki alanı için daha fazla yerel saklama alanına izin verebilmesini veya bunu engelleyebilmesini sağlar.

getLocal() veya getRemote() öğesini kullanarak yerel ya da uzak bir SharedObject oluşturduğunuzda, bu paylaşılan nesneye erişimin, HTTPS bağlantısı üzerinden teslim edilen SWF dosyalarıyla kısıtlı olup olmadığını belirleyen secure adında isteğe bağlı bir parametre vardır. Bu parametre true değerine ayarlanırsa ve SWF dosyanız HTTPS üzerinden teslim edilirse, Flash Player uygulaması yeni bir güvenli paylaşılan nesne oluşturur veya varolan güvenli paylaşılan nesneye başvuruyu alır. Yalnızca güvenli parametresi true değerine ayarlanmış şekilde SharedObject.getLocal() öğesini çağıran ve HTTPS üzerinden teslim edilen SWF dosyaları tarafından bu güvenli paylaşılan nesne okunabilir veya bu güvenli paylaşılan nesneye yazılabilir. Bu parametre false değerine ayarlanırsa ve SWF dosyanız HTTPS üzerinden teslim edilirse, Flash Player uygulaması yeni bir paylaşılan nesne oluşturur veya varolan paylaşılan nesneye başvuruyu alır.

HTTPS olmayan bağlantılar üzerinden teslim edilen SWF dosyaları tarafından bu paylaşılan nesne okunabilir veya bu paylaşılan nesneye yazılabilir. SWF dosyanız HTTPS olmayan bir bağlantı üzerinden teslim edilirse ve siz bu parametreyi true değerine ayarlamayı denerseniz, yeni paylaşılan nesne oluşturma işlemi (veya önceden oluşturulmuş güvenli paylaşılan nesne erişimi) başarısız olur, bir hata atılır ve paylaşılan nesne null değerine ayarlanır. HTTPS olmayan bir bağlantıdan aşağıdaki kod parçasını çalıştırmayı denerseniz, SharedObject.getLocal() yöntemi bir hata atar:

try 
{ 
    var so:SharedObject = SharedObject.getLocal("contactManager", null, true); 
} 
catch (error:Error) 
{ 
    trace("Unable to create SharedObject."); 
}

Bu parametrenin değerine bakılmaksızın, oluşturulmuş paylaşılan nesnelerin sayısı, bir etki alanı için izin verilen toplam disk alanı miktarı kadar olabilir.

Değerler, data özelliği içinde paylaşılan nesnelerde saklanır. Aşağıdaki örnekte gösterildiği gibi, bir for..in döngüsünü kullanarak paylaşılan nesne örneği içinde her değer üzerinde döngü oluşturabilirsiniz:

var so:SharedObject = SharedObject.getLocal("test"); 
so.data.hello = "world"; 
so.data.foo = "bar"; 
so.data.timezone = new Date().timezoneOffset; 
for (var i:String in so.data) 
{ 
    trace(i + ":\t" + so.data[i]); 
}

İstemcide bulunan bir SharedObject öğesini ortadan kaldırmak için, SharedObject.clear() yöntemini kullanın. Bu işlem, uygulamanın paylaşılan nesnelerine ait varsayılan yoldaki dizinleri yok etmez.

Aşağıdaki örnek istemciden SharedObject dosyasını siler:

public function destroySharedObject():void { 
    mySO.clear(); 
}

Aşağıdaki örnek, bir Date nesnesi gibi basit nesneleri, o nesneleri el ile serileştirmek veya seri numarasını kaldırmak zorunda kalmadan bir SharedObject nesnesinde depolayabileceğinizi gösterir.

Aşağıdaki örnek sizi ilk defa gelen bir ziyaretçi gibi karşılayarak başlar. Oturumu Kapat'ı tıklattığınızda, uygulama geçerli tarihi paylaşılan bir nesnede saklar. Bu uygulamayı bir sonraki sefer başlattığınızda veya sayfayı yenilediğinizde, uygulama sizi oturumu kapattığınız zamanı gösteren bir hatırlatma ile tekrar karşılar.

Uygulamayı çalışır halinde görmek için başlatın, Oturumu Kapat'ı tıklatın ve ardından sayfayı yenileyin. Uygulama bir önceki ziyaretinizde Oturumu Kapat düğmesini tıklattığınız tarih ve zamanı gösterir. Saklanan bilgileri istediğiniz zaman LSO'yu Sil düğmesine basarak silebilirsiniz.

<?xml version="1.0"?> 
<!-- lsos/WelcomeMessage.mxml --> 
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" initialize="initApp()"> 
  <mx:Script><![CDATA[ 
  public var mySO:SharedObject; 
  [Bindable] 
  public var welcomeMessage:String; 
 
  public function initApp():void { 
     mySO = SharedObject.getLocal("mydata"); 
     if (mySO.data.visitDate==null) { 
        welcomeMessage = "Hello first-timer!" 
     } else { 
        welcomeMessage = "Welcome back. You last visited on " + 
           getVisitDate(); 
     } 
  } 
 
  private function getVisitDate():Date { 
     return mySO.data.visitDate; 
  } 
 
  private function storeDate():void { 
     mySO.data.visitDate = new Date(); 
     mySO.flush(); 
  } 
  
  private function deleteLSO():void { 
     // Deletes the SharedObject from the client machine. 
     // Next time they log in, they will be a 'first-timer'. 
     mySO.clear(); 
  } 
  
  ]]></mx:Script> 
  <mx:Label id="label1" text="{welcomeMessage}"/> 
  <mx:Button label="Log Out" click="storeDate()"/> 
  <mx:Button label="Delete LSO" click="deleteLSO()"/> 
</mx:Application>