Korumalı içerik iş akışını anlama

Aşağıdaki adımlar, bir DRMContentData nesnesi kullanarak korumalı bir medya dosyası için makbuzu önceden yüklemeye yönelik iş akışını anlatmaktadır.

1. Paketlenmiş içeriğe ait ikili meta verileri alın. Flash Access Java Referans Paketleyicisi kullanılıyorsa, bu meta veri dosyası otomatik olarak .metadata uzantısıyla oluşturulur. Örneğin bu meta verileri URLLoader sınıfını kullanarak indirebilirsiniz.

2. Yapıcı işlevine meta verileri geçirerek bir DRMContentData nesnesi oluşturun:

   var drmData:DRMContentData = new DRMContentData( metadata );

3. Geri kalan adımlar, Korumalı içerik iş akışını anlama bölümünde anlatılan iş akışıyla aynıdır.

Aşağıdaki adımlar, preloadEmbeddedMetadata() kullanan DRM korumalı bir medya dosyasına için makbuzu önceden yüklemeye ilişkin iş akışını açıklar():

1. Medya dosyasını indirin ve saklayın. (DRM meta verileri yalnızca yerel olarak saklanan dosyalardan önceden yüklenebilir.)

2. NetStream istemci nesnesinin onDRMContentData() ve onPlayStatus() geri çağırma işlevleri için uygulamaları sağlayarak NetConnection ve NetStream nesnelerini oluşturun.

3. Bir NetStreamPlayOptions nesnesi oluşturun ve stream özelliğini yerel medya dosyasının URL'sine ayarlayın.

4. Ayrıştırılacak medya dosyasını tanımlayan NetStreamPlayOptions nesnesini aktaran NetStream preloadEmbeddedMetadata() yöntemini çağırın.

5. Medya dosyası DRM meta verileri içeriyorsa, onDRMContentData() geri çağırma işlevi çağrılır. Meta veriler bu işleve bir DRMContentData nesnesi olarak aktarılır.

6. DRMManager loadVoucher() yöntemini kullanarak makbuzu elde etmek için DRMContentData nesnesini kullanın.

   DRMContentData nesnesine ait authenticationMethod özelliğinin değeri userNameAndPassword olduğunda, makbuzu yüklemeden önce medya hakları sunucusundaki kullanıcının kimlik doğrulamasını yapın. DRMContentData nesnesinin serverURL ve domain özellikleri, kullanıcının kimlik bilgileriyle birlikte DRMManager authenticate() yöntemine aktarılabilir.

7. Dosya ayrıştırma tamamlandığında onPlayStatus() geri çağırma işlevi çağrılır. onDRMContentData() işlevi çağrılmadıysa, dosya makbuzu almak için gerekli olan meta verileri içermez. Bu eksik çağrı büyük ihtimalle Flash Access'in bu dosyayı korumadığı anlamına da gelir.

Aşağıdaki AIR kod örneği, yerel bir medya dosyası için makbuzunun nasıl önceden yükleneceğini gösterir:

package 
{ 
import flash.display.Sprite; 
import flash.events.DRMAuthenticationCompleteEvent; 
import flash.events.DRMAuthenticationErrorEvent; 
import flash.events.DRMErrorEvent;   
import flash.ev ents.DRMStatusEvent; 
import flash.events.NetStatusEvent; 
import flash.net.NetConnection; 
import flash.net.NetStream; 
import flash.net.NetStreamPlayOptions; 
import flash.net.drm.AuthenticationMethod; 
import flash.net.drm.DRMContentData; 
import flash.net.drm.DRMManager; 
import flash.net.drm.LoadVoucherSetting;   
public class DRMPreloader extends Sprite  
{ 
     private var videoURL:String = "app-storage:/video.flv"; 
    private var userName:String = "user"; 
    private var password:String = "password";  
    private var preloadConnection:NetConnection; 
    private var preloadStream:NetStream; 
    private var drmManager:DRMManager = DRMManager.getDRMManager(); 
    private var drmContentData:DRMContentData; 
    public function DRMPreloader():void { 
        drmManager.addEventListener( 
            DRMAuthenticationCompleteEvent.AUTHENTICATION_COMPLETE, 
            onAuthenticationComplete); 
        drmManager.addEventListener(DRMAuthenticationErrorEvent.AUTHENTICATION_ERROR, 
            onAuthenticationError);             
        drmManager.addEventListener(DRMStatusEvent.DRM_STATUS, onDRMStatus); 
        drmManager.addEventListener(DRMErrorEvent.DRM_ERROR, onDRMError); 
        preloadConnection = new NetConnection(); 
        preloadConnection.addEventListener(NetStatusEvent.NET_STATUS, onConnect); 
        preloadConnection.connect(null);            
    } 
 
    private function onConnect( event:NetStatusEvent ):void 
    { 
        preloadMetadata(); 
    } 
    private function preloadMetadata():void 
    { 
        preloadStream = new NetStream( preloadConnection ); 
        preloadStream.client = this; 
        var options:NetStreamPlayOptions = new NetStreamPlayOptions(); 
        options.streamName = videoURL; 
        preloadStream.preloadEmbeddedData( options );                         
    }     
    public function onDRMContentData( drmMetadata:DRMContentData ):void 
    { 
        drmContentData = drmMetadata; 
        if ( drmMetadata.authenticationMethod == AuthenticationMethod.USERNAME_AND_PASSWORD ) 
        { 
            authenticateUser(); 
        } 
        else 
            { 
                getVoucher(); 
            } 
    } 
    private function getVoucher():void 
    { 
        drmManager.loadVoucher( drmContentData, LoadVoucherSetting.ALLOW_SERVER ); 
    } 
 
    private function authenticateUser():void 
    { 
        drmManager.authenticate( drmContentData.serverURL, drmContentData.domain, userName, password ); 
    } 
    private function onAuthenticationError( event:DRMAuthenticationErrorEvent ):void 
    { 
        trace( "Authentication error: " + event.errorID + ", " + event.subErrorID ); 
    } 
 
    private function onAuthenticationComplete( event:DRMAuthenticationCompleteEvent ):void 
    { 
        trace( "Authenticated to: " + event.serverURL + ", domain: " + event.domain ); 
        getVoucher(); 
    } 
    private function onDRMStatus( event:DRMStatusEvent ):void 
    { 
        trace( "DRM Status: " + event.detail); 
        trace("--Voucher allows offline playback = " + event.isAvailableOffline ); 
        trace("--Voucher already cached          = " + event.isLocal ); 
        trace("--Voucher required authentication = " + !event.isAnonymous ); 
    } 
    private function onDRMError( event:DRMErrorEvent ):void 
    { 
        trace( "DRM error event: " + event.errorID + ", " + event.subErrorID + ", " + event.text ); 
    } 
    public function onPlayStatus( info:Object ):void 
    { 
        preloadStream.close(); 
    } 
} 
}