Ters kinematikle çalışma

Ters kinematik (IK), gerçeğe uygun olarak birbirine göre hareket edecek şekilde parçaları bağlayarak gerçekçi animasyonlar oluşturmanıza olanak sağlar.

Örneğin, IK'yi kullanarak, istediğiniz pozu elde etmek için bacaktaki gerekli eklem hareketlerini gerçekleştirip bir bacağı belirli bir konuma taşıyabilirsiniz. IK, IK armatürü adı verilen bir yapıda zincirlenmiş kemikler çerçevesini kullanır. fl.ik paketi, doğal harekete benzer animasyonlar oluşturmanıza yardımcı olur. IK algoritmasının ardındaki fizik kuralları hakkında çok bilgi sahibi olmanız gerekmeden kusursuz şekilde birden çok IK armatürüne animasyon uygulamanızı sağlar.

Flash Professional ile yardımcı eklem ve bağlantılar içeren TK armatürü oluşturun. Böylece çalışma zamanında bunlara animasyon uygulamak için IK sınıflarına erişebilirsiniz.

TK armatürünün nasıl oluşturulduğuyla ilgili ayrıntılı talimatlar için Flash Professional'ı Kullanma kısmında Ters kinematikleri kullanma bölümüne bakın.

Flash Professional'da bir TK armatürü oluşturduktan sonra, çalışma zamanında bu armatürün hareketini sınırlamak, olaylarını izlemek ve armatüre animasyon uygulamak için fl.ik sınıflarını kullanın.

Aşağıdaki şekilde, Wheel adında bir film klibi gösterilmektedir. Aks, Axle adında bir IKArmature örneğidir. IKMover sınıfı, tekerlek dönüşüyle eşzamanlı olarak armatürü hareket ettirir. Armatürdeki IKBone, ikBone2 öğesi, kuyruk ekleminde tekerleğe bağlıdır.

A.

Wheel

B.

Axle

C.

ikBone2

Çalışma zamanında, tekerlek Animasyonu açıklama bölümünde anlatılan __motion_Wheel hareket arasıyla bağlantılı olarak döner. IKMover nesnesi, aksın hareketini başlatır ve kontrol eder. Aşağıdaki resimde, dönüşteki farklı karelerde dönen tekerleğe eklenen aks armatürünün iki anlık görüntüsü gösterilmektedir.

import fl.ik.* 
 
var tree:IKArmature = IKManager.getArmatureByName("Axle"); 
var bone:IKBone = tree.getBoneByName("ikBone2"); 
var endEffector:IKJoint = bone.tailJoint; 
var pos:Point = endEffector.position; 
 
var ik:IKMover = new IKMover(endEffector, pos); 
ik.limitByDistance = true; 
ik.distanceLimit = 0.1; 
ik.limitByIteration = true; 
ik.iterationLimit = 10; 
 
Wheel.addEventListener(Event.ENTER_FRAME, frameFunc); 
 
function frameFunc(event:Event) 
{ 
    if (Wheel != null) 
    { 
        var mat:Matrix = Wheel.transform.matrix; 
        var pt = new Point(90, 0); 
        pt = mat.transformPoint(pt); 
         
        ik.moveTo(pt); 
    } 
}

Aksı taşımak için kullanılan IK sınıfları şunlardır:

Bu sınıflarla ilgili eksiksiz ve detaylı açıklamalar için bkz. ik package .

Öncelikle, taşımak istediğiniz parçaları oluşturan armatür, kemik ve eklem değişkenlerini bildirin.

Aşağıdaki kod, Axle armatürünün değerini tree IKArmature değişkenine atamak için IKManager sınıfının getArmatureByName() yöntemini kullanır. Axle armatürü önceden Flash Professional ile oluşturulurdu.

var tree:IKArmature = IKManager.getArmatureByName("Axle");

Aynı şekilde, aşağıdaki kod ikBone2 kemiğinin IKBone değişkenine atamak için IKArmature sınıfının getBoneByName() yöntemini kullanır.

var bone:IKBone = tree.getBoneByName("ikBone2");

ikBone2 kemiğinin kuyruk eklemi, armatürün dönen tekerleğe eklenen bölümüdür.

Aşağıdaki satır, endEffector değişkenini bildirir ve bu değişkeni ikBone2 kemiğinin tailjoint özelliğine atar:

var endEffector:IKJoint = home.tailjoint;

var pos:Point = endEffector.position;

Bu örnekte, pos öğesi, aksın sonundaki eklemin tekerleğe bağlandığı konumudur. Bu değişkenin orijinal değeri, IKJoint öğesinin position özelliğinden elde edilir.

IKMover sınıfının bir örneği aksı hareket ettirir.

var ik:IKMover = new IKMover(endEffector, pos);

IKMover sınıfının özellikleri, bir armatürün hareketini sınırlamanıza olanak sağlar. Mesafe, yineleme ve hareket süresini esas alarak hareketi sınırlayabilirsiniz.

Aşağıdaki özellik çiftleri bu sınırlamaları zorlar. Çiftler, hareketin sınırlanmış olup olmadığını ve sınırlamayı belirten bir tam sayıyı gösteren Boolean değerini içerir:

Varsayılan olarak, tüm Boolean değerleri false değerine ayarlıdır, bundan dolayı hareket siz bir Boolean değerini true olacak şekilde açıkça ayarlamadıkça sınırlanmaz. Bir sınırı zorlamak için, uygun özelliği true değerine ayarlayın ve ardından karşılık gelen tam sayı özelliği için bir değer belirleyin. Karşılık gelen Boolean özelliğini ayarlamadan sınırlamayı bir değere ayarlarsanız, sınırlama yok sayılır. Bu durumda, IK motoru IKMover öğesinin başka bir sınırına veya hedef konumuna ulaşılıncaya kadar hareket etmeye devam eder.

ik.limitByDistance = true; 
ik.distanceLimit = 0.1; 
ik.limitByIteration = true; 
ik.iterationLimit = 10; 

Flash Professional CS5’teki ters kinematik, eklem yayını destekler. Eklem yayı, geliştirme sırasında ayarlanabilir ve eklem yayı nitelikleri çalışma zamanında eklenebilir veya değiştirilebilir. Yay, eklemin ve bağlantı yerlerinin bir özelliğidir. İki niteliği vardır: yayın miktarını ayarlayan IKJoint.springStrength ve kuvvet değerine direnç ekleyen ve yayın aşınma oranını değiştiren IKJoint.springDamping .

Yay kuvveti, varsayılan 0 (çok sıkı) ile 100 (çok gevşek ve fizik tarafından kontrol edilir) arasında yüzde cinsinden bir değerdir. Eklemler, bağlantı yerlerinin hareketine yay tepkimesi gösterir. Etkinleştirilmiş başka bir çeviri (dönüş, x veya y) yoktur; yay ayarlarının hiçbir etkisi olmaz.

Yay sönümlemesi varsayılan 0 (dirençsiz) ile 100 (aşırı derecede sönümlü) arasında yüzde cinsinden bir değerdir. Sönüm, bir eklemin ilk hareketi ve dinlenme konumuna dönüşü arasında geçen zaman miktarını değiştirir.

IKArmature.springsEnabled özelliğini kontrol ederek bir IKArmature nesnesi için yayların etkin olup olmadığını kontrol edebilirsiniz. Diğer yay özellikleri ve yöntemleri ayrı IKJoint nesnelerine aittir. Bir bağlantı noktası x ve y eksenleri boyunca açısal dönüş ve çeviri açısından etkinleştirilebilir. Bir döndürme bağlantı noktasının yay açısını IKJoint.setSpringAngle ve çevirme bağlantı noktasının yay konumunu IKJoint.setSpringPt ile konumlandırabilirsiniz.

Bu örnek ada göre bir eklem seçer ve tailJoint öğesini tanımlar. Kod, yayların etkinleştirilip etkinleştirilmediğini anlamak için üst armatürü test eder ve ardından bağlantı yeri için yay özelliklerini belirler.

var arm:IKArmature = IKManager.getArmatureAt(0); 
var bone:IKBone = arm.getBoneByName("c"); 
var joint:IKJoint = bone.tailJoint; 
if (arm.springsEnabled) { 
    joint.springStrength = 50; //medium spring strength 
    joint.springDamping = 10; //light damping resistance 
    if (joint.hasSpringAngle) { 
        joint.setSpringAngle(30); //set angle for rotational spring 
    } 
}

IKEvent sınıfı, IK Olayları hakkında bilgi içeren bir olay nesnesi oluşturmanıza olanak sağlar. IKEvent bilgileri, belirtilen süre, mesafe veya yineleme sınırı aşıldığından sonlandırılmış olan hareketi açıklar.

Aşağıdaki kod, zaman sınırı olaylarının izlenmesine yönelik bir olay dinleyicisini ve işleyicisini gösterir. Bu olay işleyicisi, IKMover öğesinin zaman sınırı aşıldığında ortaya çıkan bir olayın süre, mesafe, yineleme sayısı ve eklem özelliklerini bildirir.

var ikmover:IKMover = new IKMover(endjoint, pos); 
ikMover.limitByTime = true; 
ikMover.timeLimit = 1000; 
 
ikmover.addEventListener(IKEvent.TIME_LIMIT, timeLimitFunction); 
 
function timeLimitFunction(evt:IKEvent):void 
{ 
    trace("timeLimit hit"); 
    trace("time is " + evt.time); 
    trace("distance is " + evt.distance); 
    trace("iterationCount is " + evt.iterationCount); 
    trace("IKJoint is " + evt.joint.name); 
}