Label bileşenini kullanma

Etiket bileşeni genellikle bir web sayfasında başka bir öğeyi ya da etkinliği tanımlamak için tek bir metin satırı görüntüler. Metin biçimlendirme etiketlerinden yararlanmak için bir etiketin HTML ile biçimlendirileceğini belirtebilirsiniz. Ayrıca etiketin hizalamasını ve boyutunu da denetleyebilirsiniz. Etiket bileşenleri kenarlıklara sahip değildir, odaklanamazlar ve olayları yayınlamazlar.

Her bir Label örneğinin canlı önizlemesi, geliştirme sırasında Özellik denetçisinde veya Bileşen denetçisinde parametrelere yapılan değişiklikleri yansıtır. Etiketin kenarlığı yoktur, bu nedenle canlı önizlemesini görmenin tek yolu, etiketin metin parametresini ayarlamaktır.

Label bileşeniyle kullanıcı etkileşimi

Bir formda, kullanıcının adını kabul eden TextInput alanının solunda “Ad:” etiketi gibi başka bir metin etiketi oluşturmak için Label bileşenini kullanın. Tutarlı bir görünüm elde etmek için stilleri kullanabildiğinizden, düz metin alanı yerine Label bileşeninin kullanılması iyi bir fikirdir.

Bir Label bileşenini döndürmek istiyorsanız, fontları gömmeniz gerekir; aksi takdirde siz filmi test ederken gösterilmezler.

Label bileşeni parametreleri

Her Label bileşeni örneği için Özellik denetçisinde veya Bileşen denetçisinde şu geliştirme parametrelerini ayarlayabilirsiniz: autoSize , CondenseWhite , seçilebilir , text ve wordWrap . Bu parametrelerin her biri, aynı adda, karşılık gelen ActionScript özelliğine sahiptir. Bu parametrelerin olası değerleriyle ilgili bilgi için, Adobe® Flash® Professional CS5 için ActionScript® 3.0 Başvurusu bölümündeki Label sınıfına bakın.

Label bileşeniyle uygulama oluşturma

Aşağıdaki prosedür, geliştirme sırasında bir uygulamaya nasıl Label bileşeni ekleneceğini açıklamaktadır. Bu örnekte, etiket yalnızca “Expiration Date” metnini görüntüler.

  1. Yeni bir Flash (ActionScript 3.0) belgesi oluşturun.

  2. Bir Label bileşenini Bileşenler panelinden Sahne Alanı'na sürükleyin ve Özellik denetçisinde bileşene şu değerleri verin:

    • Örnek adı için aLabel girin.

    • W değeri için 80 girin.

    • X değeri için 100 girin.

    • Y değeri için 100 girin.

    • text parametresi için Expiration Date girin.

  3. Bir TextArea bileşenini Sahne Alanı'na sürükleyin ve Özellik denetçisinde bileşene şu değerleri verin:

    • Örnek adı için aTa girin.

    • H değeri için 22 girin.

    • X değeri için 200 girin.

    • Y değeri için 100 girin.

  4. Eylemler panelini açın, ana Zaman Çizelgesi'nde Kare 1'i seçin ve şu ActionScript kodunu girin: 

    var today:Date = new Date(); 
var expDate:Date = addDays(today, 14); 
aTa.text = expDate.toDateString(); 
 
function addDays(date:Date, days:Number):Date { 
return addHours(date, days*24); 
} 
 
function addHours(date:Date, hrs:Number):Date { 
return addMinutes(date, hrs*60); 
} 
 
function addMinutes(date:Date, mins:Number):Date { 
return addSeconds(date, mins*60); 
} 
 
function addSeconds(date:Date, secs:Number):Date { 
var mSecs:Number = secs * 1000; 
var sum:Number = mSecs + date.getTime(); 
return new Date(sum); 
}

  5. Kontrol Et > Filmi Test Et'i seçin.

ActionScript kullanarak Label bileşen örneği oluşturma

Aşağıdaki örnek, ActionScript kullanarak bir Label parametresi oluşturur. ColorPicker bileşeninin işlevini tanımlamak için bir Label öğesini kullanır ve Label metnine biçimlendirme uygulamak için htmlText özelliğini kullanır.

  1. Yeni bir Flash (ActionScript 3.0) belgesi oluşturun.

  2. Label bileşenini Bileşenler panelinden geçerli belgenin Kütüphane paneline sürükleyin.

  3. ColorPicker bileşenini Bileşenler panelinden geçerli belgenin Kütüphane paneline sürükleyin.

  4. Eylemler panelini açın, ana Zaman Çizelgesi'nde Kare 1'i seçin ve şu ActionScript kodunu girin: 

    import fl.controls.Label; 
import fl.controls.ColorPicker; 
 
var aLabel:Label = new Label(); 
var aCp:ColorPicker = new ColorPicker(); 
 
addChild(aLabel); 
addChild(aCp); 
 
aLabel.htmlText = '<font face="Arial" color="#FF0000" size="14">Fill:</font>'; 
aLabel.x = 200; 
aLabel.y = 150; 
aLabel.width = 25; 
aLabel.height = 22; 
 
aCp.x = 230; 
aCp.y = 150;

  5. Kontrol Et > Filmi Test Et'i seçin.