List bileşenini kullanma

Yeni bir Flash (ActionScript 3.0) belgesi oluşturun.

List bileşenini Bileşenler panelinden Sahne Alanı'na sürükleyin.

Özellik denetçisinde şunları yapın:

• aList örnek adını girin.

• W (genişlik) öğesine 200 değerini atayın.

aList öğesinin aşağısında bir metin alanı oluşturmak için Metin aracını kullanın ve bu metin alanına aTf örnek adını verin.

Eylemler panelini açın, ana Zaman Çizelgesi'nde Kare 1'i seçin ve şu ActionScript kodunu girin:

import fl.controls.List; 
import flash.text.TextField; 
 
aTf.type = TextFieldType.DYNAMIC; 
aTf.border = false; 
 
// Create these items in the Property inspector when data and label 
// parameters are available. 
aList.addItem({label:"1956 Chevy (Cherry Red)", data:35000}); 
aList.addItem({label:"1966 Mustang (Classic)", data:27000}); 
aList.addItem({label:"1976 Volvo (Xcllnt Cond)", data:17000}); 
aList.allowMultipleSelection = true; 
 
aList.addEventListener(Event.CHANGE, showData); 
 
function showData(event:Event) { 
    aTf.text = "This car is priced at: $" + event.target.selectedItem.data; 
}

Bu kod, aList öğesini üç öğeyle doldurmak için addItem() yöntemini kullanır ve öğelerin her birine listede görüntülenen bir label değeri ve bir data değeri atar. List öğesinde bir öğeyi seçtiğinizde, olay dinleyicisi, seçili öğe için data değerini görüntüleyen showData() işlevini çağırır.

Bu uygulamayı derlemek ve çalıştırmak için Kontrol Et > Filmi Test Et seçeneklerini belirleyin.

Yeni bir Flash (ActionScript 3.0) belgesi oluşturun.

List bileşenini Bileşenler panelinden Sahne Alanı'na sürükleyin.

Özellik denetçisinde şunları yapın:

• aList örnek adını girin.

• W (genişlik) öğesine 200 değerini atayın.

aList öğesinin aşağısında bir metin alanı oluşturmak için Metin aracını kullanın ve bu metin alanına aTf örnek adını verin.

Eylemler panelini açın, ana Zaman Çizelgesi'nde Kare 1'i seçin ve şu ActionScript kodunu girin:

import fl.controls.List; 
import fl.data.DataProvider; 
import flash.text.TextField; 
 
aTf.type = TextFieldType.DYNAMIC; 
aTf.border = false; 
 
var cars:Array = [ 
{label:"1956 Chevy (Cherry Red)", data:35000}, 
{label:"1966 Mustang (Classic)", data:27000}, 
{label:"1976 Volvo (Xcllnt Cond)", data:17000}, 
]; 
aList.dataProvider = new DataProvider(cars); 
aList.allowMultipleSelection = true; 
 
aList.addEventListener(Event.CHANGE, showData); 
 
function showData(event:Event) { 
    aTf.text = "This car is priced at: $" + event.target.selectedItem.data; 
}

Öğelerin yer aldığı List öğesini görmek için Kontrol Et > Filmi Test Et seçeneklerini belirleyin.

Flash (ActionScript 3.0) belgesi oluşturun.

List bileşenini Bileşenler panelinden Sahne Alanı'na sürükleyin ve Özellik denetçisinde bileşene şu değerleri verin:

• Örnek adı için aList girin.

• H değeri için 60 girin.

• X değeri için 100 girin.

• Y değeri için 150 girin.

Eylemler panelini açın, ana Zaman Çizelgesi'nde Kare 1'i seçin ve şu ActionScript kodunu girin:

aList.addItem({label:"Blue", data:0x0000CC}); 
aList.addItem({label:"Green", data:0x00CC00}); 
aList.addItem({label:"Yellow", data:0xFFFF00}); 
aList.addItem({label:"Orange", data:0xFF6600}); 
aList.addItem({label:"Black", data:0x000000}); 
 
var aBox:MovieClip = new MovieClip(); 
addChild(aBox); 
 
aList.addEventListener(Event.CHANGE, changeHandler); 
function changeHandler(event:Event) { 
    drawBox(aBox, event.target.selectedItem.data); 
}; 
 
function drawBox(box:MovieClip,color:uint):void { 
            box.graphics.beginFill(color, 1.0); 
            box.graphics.drawRect(225, 150, 100, 100); 
            box.graphics.endFill();         
}

Uygulamayı çalıştırmak için Kontrol Et > Filmi Test Et'i seçin.

List öğesindeki renkleri MovieClip öğesinde görüntülenmesi için tıklatın.

Yeni bir Flash (ActionScript 3.0) belgesi oluşturun.

List bileşenini Bileşenler panelinden Kütüphane paneline sürükleyin.

Eylemler panelini açın, ana Zaman Çizelgesi'nde Kare 1'i seçin ve şu ActionScript kodunu girin:

import fl.controls.List; 
 
var aList:List = new List(); 
aList.addItem({label:"One", data:1}); 
aList.addItem({label:"Two", data:2}); 
aList.addItem({label:"Three", data:3}); 
aList.addItem({label:"Four", data:4}); 
aList.addItem({label:"Five", data:5}); 
aList.setSize(60, 40); 
aList.move(200,200); 
addChild(aList); 
aList.addEventListener(Event.CHANGE, changeHandler); 
function changeHandler(event:Event):void { 
    trace(event.target.selectedItem.data); 
}

Uygulamayı çalıştırmak için Kontrol Et > Filmi Test Et'i seçin.