DNSResolver

Paket	flash.net.dns
Sınıf	public class DNSResolver
Miras Alma	DNSResolver EventDispatcher Object

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 2

DNSResolver sınıfı Etki Alanı Adı Sistemi (DNS) kaynak kayıtlarını aramanıza olanak verir.

AIR profili desteği: Bu özellik tüm masaüstü işletim sistemlerinde desteklenir ancak mobil aygıtlarda desteklenmez. AIR for TV aygıtlarında kısmen desteklenir. Desteği çalışma zamanında DNSResolver.isSupported özelliğini kullanarak test edebilirsiniz. Birden fazla profilde API desteği ile ilgili daha fazla bilgi için bkz. AIR Profil Desteği.

Aşağıdaki kaynak kaydı türlerini arayabilirsiniz:

ARecord: bir ana bilgisayara ilişkin IPv4 adresi.
AAAARecord: bir ana bilgisayara ilişkin IPv4 adresi.
MXRecord: bir ana bilgisayara ilişkin posta alışverişi kaydı.
PTRRecord: bir IP adresine ilişkin ana bilgisayar adı.
SRVRecord: bir servise ilişkin servis kaydı

Aşağıdaki tabloda, AIR for TV aygıtlarına yönelik DNS araması desteği gösterilmektedir. Desteklenmeyen istekler DNSResolver nesnesinin bir flash.events.ErrorEvent nesnesi göndermesiyle sonuçlanır.

`DNSResolver.lookup()` öğesinde belirtilen kayıt türü	Destek
ARecord	Tam destek
AAAARecord	Tam destek
MXRecord	Desteklenmez
PTRRecord	Yalnızca IPv4 adresleri için desteklenir, IPv6 adresleri için desteklenmez
SRVRecord	Desteklenmez

Örnekleri görüntüle

İlgili API Öğeleri

ARecord
AAAARecord
MXRecord
PTRRecord
SRVRecord

Genel Özellikler

Miras Alınan Genel Özellikleri Gizle

Miras Alınan Genel Özellikleri Göster

	Özellik		Tanımlayan:
		constructor : Object Belirli bir nesne örneği için sınıf nesnesine veya yapıcı işlevine bir başvuru.	Object
		isSupported : Boolean [statik] [salt okunur] DNS aramalarının istemci sisteminde desteklenip desteklenmediğini gösterir.	DNSResolver

Genel Yöntemler

Miras Alınan Genel Yöntemleri Gizle

Miras Alınan Genel Yöntemleri Göster

	Yöntem		Tanımlayan:
		DNSResolver() Bir DNSResolver nesnesi oluşturur.	DNSResolver
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void EventDispatcher nesnesi olan bir olay dinleyici nesnesini, dinleyicinin bir olayın bildirimini alması için kaydeder.	EventDispatcher
		dispatchEvent(event:Event):Boolean Olay akışına bir olay gönderir.	EventDispatcher
		hasEventListener(type:String):Boolean EventDispatcher nesnesinin belirli bir olay türü için kayıtlı dinleyicisi olup olmadığını kontrol eder.	EventDispatcher
		hasOwnProperty(name:String):Boolean Bir nesnenin belirli bir özelliğinin tanımlı olup olmadığını gösterir.	Object
		isPrototypeOf(theClass:Object):Boolean Object sınıfının bir örneğinin parametre olarak belirtilen nesnenin prototip zincirinde olup olmadığını gösterir.	Object
		lookup(host:String, recordType:Class):void Bir sorgu dizesini temel alarak bir DNS kaynak kaydını arar.	DNSResolver
		propertyIsEnumerable(name:String):Boolean Belirtilen özelliğin bulunup bulunmadığını ve numaralandırılabilir olup olmadığını gösterir.	Object
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void EventDispatcher nesnesinden bir dinleyiciyi kaldırır.	EventDispatcher
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Dinamik bir özelliğin döngü işlemlerinde kullanılabilirliğini ayarlar.	Object
		toLocaleString():String Bu nesnenin, yerel ayara özel kurallara göre biçimlendirilmiş dize temsilini döndürür.	Object
		toString():String Belirtilen nesnenin dize olarak temsil edilen halini döndürür.	Object
		valueOf():Object Belirtilen nesnenin temel değerini döndürür.	Object
		willTrigger(type:String):Boolean Bir olay dinleyicisinin bu EventDispatcher nesnesiyle mi, yoksa onun belirtilen olay türüne yönelik üst öğelerinden biriyle mi kayıtlı olduğunu kontrol eder.	EventDispatcher

Olaylar

Olaylarla ilgili daha fazla bilgi için tıklatın

Miras Alınan Olayları Gizle

Miras Alınan Olayları Göster

	Özet	Tanımlayan:
activate	[broadcast olayı] Flash Player veya AIR uygulaması işletim sistemi odağına gelip etkin olduğunda gönderilir.	EventDispatcher
deactivate	[broadcast olayı] Çalışan Flash Player veya AIR uygulaması sistem odağını kaybettiğinde ve etkin olmayan duruma geldiğinde gönderilir.	EventDispatcher
error	Bir DNS araması sırasında bir hata oluştuğunda gönderilir.	DNSResolver
lookup	Bir DNS araması tamamlandığında gönderilir.	DNSResolver

Özellik Ayrıntısı

isSupported

özellik

isSupported:Boolean [salt okunur]

Çalışma Zamanı Sürümleri:

AIR 2

DNS aramalarının istemci sisteminde desteklenip desteklenmediğini gösterir.

Uygulama
public static function get isSupported():Boolean

Yapıcı Ayrıntı

()

Yapıcı

public function DNSResolver()

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 2

Bir DNSResolver nesnesi oluşturur.

Yöntem Ayrıntısı

lookup

()

yöntem

public function lookup(host:String, recordType:Class):void

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 2

Bir sorgu dizesini temel alarak bir DNS kaynak kaydını arar.

lookup() yöntemi senkronize olmayan bir şekilde bir DNS araması yapar. Arama sonuçlarını almak için arama olayını dinleyin. Hataları almak için hata olayını dinleyin. Sonuçlar bir DNSResolverEvent nesnesinde gönderilir.

Aranacak kaynak kaydı türünü belirtmek için, recordType parametresinde karşılık gelen sınıfı iletin. (Sınıf adını içeren bir dize değil, sınıf adının kendisini iletin.)

Yönteme iletilen sorgu dizesinin içeriği aranan kaynak kaydının türüne bağlıdır. Aşağıdaki liste kayıt türlerinin her biri için kullanılacak sorgu dizesini gösterir.

Kayıt türü	Sorgu dizesi	Örnek
ARecord	ana bilgisayar adı	"example.com"
AAAARecord	ana bilgisayar adı	"example.com"
MXRecord	ana bilgisayar adı	"example.com"
PTRRecord	IP adresi	"208.77.188.166"
SRVRecord	_service._protocol.host.	"_sip._tcp.example.com."

Parametreler

	`host:String` — sorgu dizesi, örneğin bir ana bilgisayar adı, IP adresi veya servis konumlandırıcısı

	`recordType:Class` — Aranacak DNS kaynak kaydının türünü temsil eden sınıf.

Olaylar

	`lookup:DNSResolverEvent` — arama başarıyla tamamlandığında gönderilir.

	`error:ErrorEvent` — arama başarısız olduğunda (bir kaydın mevcut olmaması dahil) gönderilir.

Atar

ArgumentError — host parametre değeri uygun bir sorgu dizesi değildir veya recordType sınıfı tanınmaz.

İlgili API Öğeleri

DNSResolverEvent

Olay Ayrıntısı

error

Olay

Olay Nesne Türü: flash.events.ErrorEvent
özellik ErrorEvent.type = flash.events.ErrorEvent.ERROR

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 2

Bir DNS araması sırasında bir hata oluştuğunda gönderilir.

Bir error olay nesnesinin type özelliğinin değerini tanımlar.

Bu olay şu özelliklere sahiptir:

Özellik	Değer
`bubbles`	`false`
`cancelable`	`false`; iptal edilecek varsayılan davranış yoktur.
`currentTarget`	Bu Event nesnesini olay dinleyicisiyle etkin olarak işleyen nesne.
`target`	Ağ işlemi arızası yaşayan nesne.
`text`	Hata mesajı olarak gösterilecek metin.

lookup

Olay

Olay Nesne Türü: flash.events.DNSResolverEvent
özellik DNSResolverEvent.type = flash.events.DNSResolverEvent.LOOKUP

Dil Sürümü:

ActionScript 3.0

Çalışma Zamanı Sürümleri:

AIR 2

Bir DNS araması tamamlandığında gönderilir.

Bir lookup event nesnesinin type özelliği değerini tanımlar.

Örnekler Bu örnek nasıl kullanılır?

DNSResolverExample.as

Aşağıdaki örnek DNS kayıtlarının desteklenen türlerine nasıl bakılacağını gösterir:

package
{
    import flash.desktop.NativeApplication;
    import flash.display.Sprite;
    import flash.events.DNSResolverEvent;
    import flash.events.ErrorEvent;
    import flash.events.Event;
    import flash.events.MouseEvent;
    import flash.net.dns.AAAARecord;
    import flash.net.dns.ARecord;
    import flash.net.dns.DNSResolver;
    import flash.net.dns.MXRecord;
    import flash.net.dns.PTRRecord;
    import flash.net.dns.SRVRecord;
    import flash.utils.getQualifiedClassName;
    
    public class DNSResolverExample extends Sprite
    {
        private var resolver:DNSResolver = new DNSResolver();
        
        public function DNSResolverExample()
        {
            resolver.addEventListener( DNSResolverEvent.LOOKUP, lookupComplete );
            resolver.addEventListener( ErrorEvent.ERROR, lookupError );
            
            //Look up records
            resolver.lookup( "www.example.com", ARecord );
            resolver.lookup( "example.com", AAAARecord );
            resolver.lookup( "example.com", MXRecord );
            resolver.lookup( "208.77.188.166", PTRRecord );
            resolver.lookup( "127.0.0.1", PTRRecord );
            resolver.lookup( "2001:1890:110b:1e19:f06b:72db:7026:3d7a", PTRRecord );
            resolver.lookup( "_sip._tcp.example.com.", SRVRecord );
            resolver.lookup( "www.example.com", ARecord );
            
            this.stage.nativeWindow.activate();
        }
        
        private function lookupComplete( event:DNSResolverEvent ):void
        {
            trace( "Query string: " + event.host );
            trace( "Record type: " +  flash.utils.getQualifiedClassName( event.resourceRecords[0] ) + 
                ", count: " + event.resourceRecords.length );
            for each( var record in event.resourceRecords )
            {
                if( record is ARecord ) trace( record.name + " : " + record.address );
                if( record is AAAARecord ) trace( record.name + " : " + record.address );
                if( record is MXRecord ) trace( record.name + " : " + record.exchange + ", " + record.preference );
                if( record is PTRRecord ) trace( record.name + " : " + record.ptrdName );
                if( record is SRVRecord ) trace( record.name + " : " + record.target + ", " + record.port +
                    ", " + record.priority + ", " + record.weight );
            }            
        }
        
        private function lookupError( error:ErrorEvent ):void
        {
            trace("Error: " + error.text );
        }
    }
}

Yasal Uyarılar | Çevrimiçi Gizlilik İlkesi

DNSResolver - AS3

Sınıflar x

isSupported

DNSResolver

lookup

error

lookup