Övervaka NetStream-händelser

Det finns två typer av händelser som tillhandahåller värdefulla användardata: netStatus och mediaTypeData . Dessutom kan en timer användas för att med jämna mellanrum logga positionen för NetStream-spelhuvudet.

netStatus -händelser ger information som du kan använda för att bestämma hur mycket av en direktuppspelning som en användare kunde se. Buffring och övergångshändelser för RTMFP-direktuppspelning resulterar även i en netStatus -händelse.

mediaTypeData -händelser tillhandahåller metadata och XMP-datainformation. Händelsen Netstream.Play.Complete skickas som en mediaTypeData -händelse. Även andra data inbäddade i direktuppspelningen är tillgängliga via mediaTypeData -händelser, inklusive referenspunkter, text och bilder.

I följande exempel visas hur du skapar en klass för att övervaka status- och datahändelser från aktiva NetStreams i ett program. Vanligtvis skulle en sådan klass skicka data som var intressant att analysera till en server för att samlas in.

package com.adobe.example 
{ 
    import flash.events.NetDataEvent; 
    import flash.events.NetMonitorEvent; 
    import flash.events.NetStatusEvent; 
    import flash.net.NetMonitor; 
    import flash.net.NetStream; 
     
    public class NetStreamEventMonitor 
    { 
        private var netmon:NetMonitor; 
        private var heartbeat:Timer = new Timer( 5000 ); 
         
        public function NetStreamEventMonitor() 
        { 
            //Create NetMonitor object 
            netmon = new NetMonitor(); 
            netmon.addEventListener( NetMonitorEvent.NET_STREAM_CREATE, newNetStream ); 
 
            //Start the heartbeat timer 
            heartbeat.addEventListener( TimerEvent.TIMER, onHeartbeat ); 
            heartbeat.start(); 
        } 
         
        //On new NetStream 
        private function newNetStream( event:NetMonitorEvent ):void 
        { 
            trace( "New Netstream object"); 
            var stream:NetStream = event.netStream; 
            stream.addEventListener(NetDataEvent.MEDIA_TYPE_DATA, onStreamData); 
            stream.addEventListener(NetStatusEvent.NET_STATUS, onStatus);             
        } 
         
        //On data events from a NetStream object 
        private function onStreamData( event:NetDataEvent ):void 
        { 
             
            var netStream:NetStream = event.target as NetStream; 
            trace( "Data event from " + netStream.info.uri + " at " + event.timestamp ); 
            switch( event.info.handler ) 
            { 
                case "onMetaData": 
                    //handle metadata; 
                    break; 
                case "onXMPData": 
                    //handle XMP; 
                    break; 
                case "onPlayStatus": 
                    //handle NetStream.Play.Complete 
                case "onImageData": 
                    //handle image 
                    break; 
                case "onTextData": 
                    //handle text 
                    break; 
                default: 
                    //handle other events 
                     
            } 
        } 
         
        //On status events from a NetStream object 
        private function onStatus( event:NetStatusEvent ):void 
        { 
            trace( "Status event from " + event.target.info.uri + " at " + event.target.time ); 
            //handle status events 
        } 
        //On heartbeat timer 
        private function onHeartbeat( event:TimerEvent ):void 
        { 
            var streams:Vector.<NetStream> = netmon.listStreams(); 
            for( var i:int = 0; i < streams.length; i++ ) 
            { 
                trace( "Heartbeat on " + streams[i].info.uri + " at " + streams[i].time ); 
                //handle heartbeat event 
            } 
        } 
         
    } 
}