Hämta textinmatningar

Flash Player 9 och senare, Adobe AIR 1.0 och senare

Som standard är egenskapen type för ett textfält inställt på dynamic . Om du ställer in egenskapen type på input med klassen TextFieldType, kan du samla in användarindata och spara värdena för användning i andra delar av programmet. Inmatningsfält är praktiska för formulär och andra program där användaren ska definiera ett textvärde för användning på andra ställen i programmet.

Koden nedan skapar t.ex. ett inmatningsfält kallat myTextBox . En textInput -händelse aktiveras när användaren skriver text i fältet. En händelsehanterare som kallas textInputCapture hämtar den skrivna textsträngen och tilldelar den en variabel. Flash Player eller AIR visar den nya texten i ett annat textfält kallat myOutputBox .

package 
{ 
    import flash.display.Sprite; 
    import flash.display.Stage; 
    import flash.text.*; 
    import flash.events.*; 
 
    public class CaptureUserInput extends Sprite 
    { 
        private var myTextBox:TextField = new TextField(); 
        private var myOutputBox:TextField = new TextField(); 
        private var myText:String = "Type your text here."; 
 
        public function CaptureUserInput() 
        { 
            captureText(); 
        } 
         
        public function captureText():void 
        { 
            myTextBox.type = TextFieldType.INPUT; 
            myTextBox.background = true; 
            addChild(myTextBox); 
            myTextBox.text = myText; 
            myTextBox.addEventListener(TextEvent.TEXT_INPUT, textInputCapture); 
        } 
         
        public function textInputCapture(event:TextEvent):void 
        { 
            var str:String = myTextBox.text; 
            createOutputBox(str); 
        } 
             
        public function createOutputBox(str:String):void 
        { 
            myOutputBox.background = true; 
            myOutputBox.x = 200; 
            addChild(myOutputBox); 
            myOutputBox.text = str; 
        } 
         
    } 
}