Exempel på XML i ActionScript: läsa in RSS-data från Internet

Klassen RSSParser innehåller en xmlLoaded() -metod som konverterar RSS-indata, i variabeln rssXML , som sparas i en sträng som innehåller HTML-formaterade utdata, rssOutput .

I början av metoden anger koden standard-XML-namnutrymmet om källans RSS-data innehåller ett standardnamnutrymme:

if (rssXML.namespace("") != undefined) 
{ 
    default xml namespace = rssXML.namespace(""); 
}

Nästa rad skapar sedan en slinga genom innehållet för källans XML-data och varje underordnad egenskap med namnet item undersöks:

for each (var item:XML in rssXML..item) 
{ 
    var itemTitle:String = item.title.toString(); 
    var itemDescription:String = item.description.toString(); 
    var itemLink:String = item.link.toString(); 
    outXML += buildItemHTML(itemTitle,  
                            itemDescription, 
                            itemLink); 
}

De första tre raderna anger strängvariablerna så att de representerar titel-, beskrivnings- och länkegenskaperna för egenskapen item för XML-datan. Nästa rad anropar metoden buildItemHTML() så att HTML-data hämtas i form av ett XMLList-objekt och för detta används tre nya strängvariabler som parametrar.

HTML-informationen (ett XMLList-objekt) har följande format:

<b>itemTitle</b> 
<p> 
    itemDescription 
    <br /> 
    <a href="link"> 
        <font color="#008000">More...</font> 
    </a> 
</p>

De första raderna i metoden rensar standard-XML-namnutrymmet:

default xml namespace = new Namespace();

Direktivet default xml namespace omfattar funktionens blocknivå. Det innebär att deklarationens omfattning är metoden buildItemHTML() .

Med de rader som följer samlas XMLList in utifrån strängargumenten som skickas till funktionen:

var body:XMLList = new XMLList(); 
body += new XML("<b>" + itemTitle + "</b>"); 
var p:XML = new XML("<p>" + itemDescription + "</p>"); 
 
var link:XML = <a></a>; 
link.@href = itemLink; // <link href="itemLinkString"></link> 
link.font.@color = "#008000";  
        // <font color="#008000"></font></a> 
        // 0x008000 = green 
link.font = "More..."; 
 
p.appendChild(<br/>);  
p.appendChild(link);  
body += p;

Detta XMLList-objekt representerar strängdata och är lämpligt för ett HTML-textfält för ActionScript.

Metoden xmlLoaded() använder returvärdet för metoden buildItemHTML() och konverterar det till en sträng:

XML.prettyPrinting = false; 
rssOutput = outXML.toXMLString();    

Metoden xmlLoaded() anger en rssTitle -strängvariabel baserat på informationen i XML-datan för källan:

rssTitle = rssXML.channel.title.toString();

Slutligen genererar metoden xmlLoaded() en händelse som meddelar programmet att data har tolkats och är tillgängliga:

            dataWritten = new Event("dataWritten", true);