Samla in och omforma XML-objekt

Flash Player 9 och senare, Adobe AIR 1.0 och senare

Använd metoderna prependChild() eller appendChild() för att lägga till egenskaper i början av en XML-objektslista med egenskaper, enligt följande exempel: 

var x1:XML = <p>Line 1</p>  
var x2:XML = <p>Line 2</p>  
var x:XML = <body></body> 
x = x.appendChild(x1); 
x = x.appendChild(x2); 
x = x.prependChild(<p>Line 0</p>); 
    // x == <body><p>Line 0</p><p>Line 1</p><p>Line 2</p></body>

Använda metoderna insertChildBefore() eller insertChildAfter() för att lägga till egenskaper före eller efter en angiven egenskap, enligt följande: 

var x:XML =  
    <body> 
        <p>Paragraph 1</p>  
        <p>Paragraph 2</p> 
    </body> 
var newNode:XML = <p>Paragraph 1.5</p>  
x = x.insertChildAfter(x.p[0], newNode) 
x = x.insertChildBefore(x.p[2], <p>Paragraph 1.75</p>)

Som framgår av nästa exempel kan du också använda klammerparenteser ( { och } ) för att skicka data som referens (från andra variabler) när du konstruerar XML-objekt: 

var ids:Array = [121, 122, 123];  
var names:Array = [["Murphy","Pat"], ["Thibaut","Jean"], ["Smith","Vijay"]] 
var x:XML = new XML("<employeeList></employeeList>"); 
 
for (var i:int = 0; i < 3; i++) 
{ 
    var newnode:XML = new XML();  
    newnode = 
        <employee id={ids[i]}> 
            <last>{names[i][0]}</last> 
            <first>{names[i][1]}</first> 
        </employee>; 
 
    x = x.appendChild(newnode) 
}

Du kan tilldela egenskaper och attribut till ett XML-objekt med hjälp av operatorn = , vilket visas i nästa exempel: 

var x:XML =  
    <employee> 
        <lastname>Smith</lastname> 
    </employee> 
x.firstname = "Jean"; 
x.@id = "239";

Detta ställer in XML-objektet x till följande: 

<employee id="239"> 
    <lastname>Smith</lastname> 
    <firstname>Jean</firstname> 
</employee>

Med operatorerna + och += kan du sammanfoga XMLList-objekt: 

var x1:XML = <a>test1</a>  
var x2:XML = <b>test2</b>  
var xList:XMLList = x1 + x2; 
xList += <c>test3</c>

Detta ställer in XMLList-objektet xList till följande: 

<a>test1</a> 
<b>test2</b> 
<c>test3</c>