För enkelhetens skull har ActionScript 3.0 metoder som ritar vanliga former som cirklar, ellipser, rektanglar och rektanglar med rundade hörn åt dig. Dessa är metoderna
drawCircle()
,
drawEllipse()
,
drawRect()
och
drawRoundRect()
i klassen Graphics. Dessa metoder kan användas i stället för metoderna
lineTo()
och
CurveTo()
. Observera dock att du ändå måste ange linje- och fyllningsformat innan du anropar metoderna.
I följande exempel återskapas exemplet med röda, gröna och blå kvadrater med bredden och höjden 100 pixlar. I koden används metoden
drawRect()
. Dessutom anges att fyllningsfärgen ska ha alfavärdet 50 % (0.5):
var squareSize:uint = 100;
var square:Shape = new Shape();
square.graphics.beginFill(0xFF0000, 0.5);
square.graphics.drawRect(0, 0, squareSize, squareSize);
square.graphics.beginFill(0x00FF00, 0.5);
square.graphics.drawRect(200, 0, squareSize, squareSize);
square.graphics.beginFill(0x0000FF, 0.5);
square.graphics.drawRect(400, 0, squareSize, squareSize);
square.graphics.endFill();
this.addChild(square);
I ett Sprite- eller MovieClip-objekt visas alltid ritinnehållet som skapas med
graphics
-egenskapen bakom alla underordnade objekt som finns i objektet. Dessutom är inte
graphics
-objektets innehåll ett separat visningsobjekt. Därför visas det inte i listan över ett Sprite- eller MovieClip-objekts underordnade objekt. I följande Sprite-objekt ritas till exempel en cirkel med
graphics
-egenskapen och ett TextField-objekt finns i listan med underordnade visningsobjekt:
var mySprite:Sprite = new Sprite();
mySprite.graphics.beginFill(0xFFCC00);
mySprite.graphics.drawCircle(30, 30, 30);
var label:TextField = new TextField();
label.width = 200;
label.text = "They call me mellow yellow...";
label.x = 20;
label.y = 20;
mySprite.addChild(label);
this.addChild(mySprite);
Observera att TextField-objektet visas ovanpå cirkeln som visas med graphics-objektet.
