Använda klassen Math med ritmetoder

Flash Player 9 och senare, Adobe AIR 1.0 och senare

Ett Graphics-objekt ritar cirklar och fyrkanter, men det kan också rita mer komplicerade former, särskilt om ritmetoderna används i kombination med egenskaperna och metoderna i klassen Math. Klassen Math innehåller vanliga matematiska konstanter, till exempel Math.PI (approximativt 3,14159265...), en konstant för förhållandet mellan en cirkels omkrets och dess diameter. Dessutom innehåller den metoder för trigonometriska funktioner, bland annat Math.sin() , Math.cos() och Math.tan() . Att rita former med dessa metoder och konstanter ger mer dynamiska visuella effekter, särskilt när de används med repetition eller rekursion.

Många metoder i klassen Math kräver cirkulära mått i radianer i stället för i grader. Att konvertera mått mellan dessa enheter är en vanlig användning av klassen Math:

var degrees = 121; 
var radians = degrees * Math.PI / 180; 
trace(radians) // 2.111848394913139

I följande exempel skapas en sinusvåg och en cosinusvåg som visar skillnaden mellan metoderna Math.sin() och Math.cos() för ett visst värde.

var sinWavePosition = 100; 
var cosWavePosition = 200; 
var sinWaveColor:uint = 0xFF0000; 
var cosWaveColor:uint = 0x00FF00; 
var waveMultiplier:Number = 10; 
var waveStretcher:Number = 5; 
 
var i:uint; 
for(i = 1; i < stage.stageWidth; i++) 
{ 
    var sinPosY:Number = Math.sin(i / waveStretcher) * waveMultiplier; 
    var cosPosY:Number = Math.cos(i / waveStretcher) * waveMultiplier; 
     
    graphics.beginFill(sinWaveColor); 
    graphics.drawRect(i, sinWavePosition + sinPosY, 2, 2);  
    graphics.beginFill(cosWaveColor); 
    graphics.drawRect(i, cosWavePosition + cosPosY, 2, 2); 
}