Format för Clipboard-data

När ett objekt skrivs till Urklipp med hjälp av ett anpassat dataformat, kan objektdata läsas från Urklipp antingen som en referens eller som en serialiserad kopia av det ursprungliga objektet. Det finns fyra överföringslägen som avgör om objekten överförs som referenser eller som serialiserade kopior:

När ett objekt skrivs till Urklipp kan du använda valfri sträng som inte börjar med något av de reserverade prefixen air: eller flash: för parametern format . Använd samma sträng som formatet som ska läsa objektet. I följande exempel visas hur objekt läses och skrivs till Urklipp:

public function createClipboardObject(object:Object):Clipboard{ 
    var transfer:Clipboard = Clipboard.generalClipboard; 
    transfer.setData("object", object, true); 
} 

Om du vill extrahera ett serialiserat objekt från urklippsobjektet (efter en åtgärd av typen släppa eller klistra in) använder du samma formatnamn och överföringsläget CLONE_ONLY eller CLONE_PREFFERED .

var transfer:Object = clipboard.getData("object", ClipboardTransferMode.CLONE_ONLY); 

En referens läggs alltid till i objektet Clipboard. Om du vill extrahera referensen från urklippsobjektet (efter en åtgärd av typen släppa eller klistra in), i stället för en serialiserad kopia, använder du överföringsläget ORIGINAL_ONLY eller ORIGINAL_PREFFERED :

var transferredObject:Object =  
    clipboard.getData("object", ClipboardTransferMode.ORIGINAL_ONLY); 

Referenserna är bara giltiga om Clipboard-objektet härstammar från det aktuella programmet. Använd överföringsläget ORIGINAL_PREFFERED om du vill få tillgång till referensen när den är tillgänglig och till den serialiserade klonen när referensen inte är tillgänglig.

I följande exempel visas hur du implementerar en funktion för fördröjd återgivning.

När användaren klickar på knappen Kopiera, raderas systemets Urklipp så att inga data finns kvar från föregående urklippsåtgärder. Metoden setDataHandler() ställer sedan in funktionen renderData() som urklippsåtergivning.

När användaren väljer kommandot Klistra in på snabbmenyn i måltextfältet får programmet tillgång till urklipp och ställer in måltexten. Eftersom textdataformatet i Urklipp har ställts in med en funktion i stället för en sträng, anropar Urklipp funktionen renderData() . Funktionen renderData() returnerar texten i källtexten, som sedan tilldelas måltexten.

Observera, att om du redigerar källtexten innan du trycker på knappen Klistra in, återspeglas redigeringen i den inklistrade texten även om redigeringen görs efter att knappen Kopiera trycks ned. Detta beror på att återgivningsfunktionen inte kopierar källtexten förrän knappen Klistra in trycks ned. (När fördröjd återgivning används i ett riktigt program, kanske du bör lagra eller skydda källdata på något sätt för att undvika det här problemet.)

 package {  
    import flash.desktop.Clipboard; 
    import flash.desktop.ClipboardFormats; 
    import flash.desktop.ClipboardTransferMode; 
    import flash.display.Sprite; 
    import flash.text.TextField; 
    import flash.text.TextFormat; 
    import flash.text.TextFieldType; 
    import flash.events.MouseEvent; 
    import flash.events.Event; 
    public class DeferredRenderingExample extends Sprite  
    {  
         private var sourceTextField:TextField; 
        private var destination:TextField; 
        private var copyText:TextField; 
        public function DeferredRenderingExample():void 
        { 
            sourceTextField = createTextField(10, 10, 380, 90); 
            sourceTextField.text = "Neque porro quisquam est qui dolorem " 
                + "ipsum quia dolor sit amet, consectetur, adipisci velit."; 
                 
            copyText = createTextField(10, 110, 35, 20); 
            copyText.htmlText = "<a href='#'>Copy</a>"; 
            copyText.addEventListener(MouseEvent.CLICK, onCopy); 
 
            destination = createTextField(10, 145, 380, 90); 
            destination.addEventListener(Event.PASTE, onPaste); 
        } 
        private function createTextField(x:Number, y:Number, width:Number, 
                        height:Number):TextField 
        { 
            var newTxt:TextField = new TextField(); 
            newTxt.x = x; 
            newTxt.y = y; 
            newTxt.height = height; 
            newTxt.width = width; 
            newTxt.border = true; 
            newTxt.multiline = true; 
            newTxt.wordWrap = true; 
            newTxt.type = TextFieldType.INPUT; 
            addChild(newTxt); 
            return newTxt; 
        } 
        public function onCopy(event:MouseEvent):void 
        { 
            Clipboard.generalClipboard.clear(); 
            Clipboard.generalClipboard.setDataHandler(ClipboardFormats.TEXT_FORMAT, 
                            renderData); 
        } 
        public function onPaste(event:Event):void 
        { 
            sourceTextField.text = 
            Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT).toString; 
        } 
        public function renderData():String 
        { 
            trace("Rendering data"); 
            var sourceStr:String = sourceTextField.text; 
            if (sourceTextField.selectionEndIndex > 
                     sourceTextField.selectionBeginIndex) 
            { 
                return sourceStr.substring(sourceTextField.selectionBeginIndex, 
                                    sourceTextField.selectionEndIndex); 
            } 
            else 
            { 
                return sourceStr; 
            } 
        } 
    } 
}

<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" width="326" height="330" applicationComplete="init()"> 
    <mx:Script> 
    <![CDATA[ 
    import flash.desktop.Clipboard; 
    import flash.desktop.ClipboardFormats; 
     
    public function init():void 
    { 
        destination.addEventListener("paste", doPaste); 
    } 
 
    public function doCopy():void 
    { 
        Clipboard.generalClipboard.clear(); 
        Clipboard.generalClipboard.setDataHandler(ClipboardFormats.TEXT_FORMAT, renderData); 
    } 
    public function doPaste(event:Event):void 
    { 
        destination.text = Clipboard.generalClipboard.getData(ClipboardFormats.TEXT_FORMAT).toString; 
    } 
     
    public function renderData():String{ 
        trace("Rendering data"); 
        return source.text; 
    } 
    ]]> 
    </mx:Script> 
    <mx:Label x="10" y="10" text="Source"/> 
    <mx:TextArea id="source" x="10" y="36" width="300" height="100"> 
        <mx:text>Neque porro quisquam est qui dolorem ipsum quia dolor sit amet, consectetur, adipisci velit.</mx:text> 
    </mx:TextArea> 
    <mx:Label x="10" y="181" text="Destination"/> 
    <mx:TextArea id="destination"  x="12" y="207" width="300" height="100"/> 
    <mx:Button click="doCopy();" x="91" y="156" label="Copy"/> 
</mx:Application>