NetStatusEvent  - AS3

Ett objekt med egenskaper som beskriver objektets status eller feltillstånd.

Informationsobjektet kan ha en code-egenskap med en sträng som representerar en specifik händelse eller en level-egenskap med en sträng som antingen är "status" eller "error".

Informationsobjektet kan också vara något helt annat. Egenskaperna code och level fungerar kanske inte för alla implementeringar, och vissa servrar kan skicka olika objekt.

P2P-anslutningar skickar meddelanden till en NetConnection med en stream-parameter i informationsobjektet som anger vilken NetStream som meddelandet tillhör.

Flex Data Services skickar till exempel Message-objekt som orsakar tvångsfel om du försöker att komma åt egenskapen code eller level.

I följande tabell beskrivs de möjliga strängvärdena för egenskaperna code och level.

Om du får flera felmeddelanden om bufferten kan du pröva med att ändra den med egenskapen NetStream.bufferTime

Relaterade API-element

function videoStatus(eventObj:NetStatusEvent):Void
{
    switch(eventObj.info.code)
    {
        case "NetStream.Seek.InvalidTime":
        {
            var validSeekTime:Number = eventObj.info.details;
            nStream.seek(validSeekTime);
            break;
        }
    }
}

Skapar ett nytt Event-objekt som innehåller information om netStatus-händelser. Event-objekt skickas som parametrar till händelseavlyssnare.

Relaterade API-element

Skapar en kopia av NetStatusEvent-objektet och ställer in värdet för alla egenskaper så att de matchar originalets egenskaper.

Returnerar en sträng som innehåller alla egenskaper i NetStatusEvent-objektet. Strängen är i följande format:

[NetStatusEvent type=värde bubbles=värde cancelable=värde info=värde]

Definierar värdet för ett netStatus-händelseobjekts type-egenskap.

Den här händelsen har följande egenskaper:

Relaterade API-element

I det här exemplet är netStatusHandler-metoden registrerad som avlyssnare för NetStatusEvent-händelsen NetConnection.netStatus. När status (lyckad eller misslyckad) för NetConnection.connect()-försöket fastställs så utlöser netStatus-händelsen den här metoden. Om försöket att ansluta till NetConnection-objektet lyckas (dvs. om info-egenskapen för NetStatusEvent-objektet skickas av netStatus-händelsen med en code-egenskap som anger att den lyckats) så skapar koden Video- och NetStream-objekt och anropar metoderna Video.attachNetStream() och NetStream.play().

Obs: Om du vill köra det här exemplet behöver du en FLV-fil vars namn och plats matchar den variabel som skickades till videoURL, i det här fallet en FLV-fil med namnet Video.flv som ligger i samma katalog som SWF-filen.

 package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.media.Video;
    import flash.net.NetConnection;
    import flash.net.NetStream;

    public class NetStatusEventExample extends Sprite {
        private var videoURL:String = "Video.flv";
        private var connection:NetConnection;
        private var stream:NetStream;

        public function NetStatusEventExample() {
            connection = new NetConnection();
            connection.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            connection.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
            connection.connect(null);
        }

        private function netStatusHandler(event:NetStatusEvent):void {
            switch (event.info.code) {
                case "NetConnection.Connect.Success":
                    connectStream();
                    break;
                case "NetStream.Play.StreamNotFound":
                    trace("Unable to locate video: " + videoURL);
                    break;
            }
        }

        private function connectStream():void {
            var stream:NetStream = new NetStream(connection);
            stream.addEventListener(NetStatusEvent.NET_STATUS, netStatusHandler);
            stream.addEventListener(AsyncErrorEvent.ASYNC_ERROR, asyncErrorHandler);
            var video:Video = new Video();
            video.attachNetStream(stream);
            stream.play(videoURL);
            addChild(video);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
        
        private function asyncErrorHandler(event:AsyncErrorEvent):void {
            // ignore AsyncErrorEvent events.
        }

    }
 }