FocusEvent  - AS3

Specificerar fokusets riktning i en focusIn-händelse.

Relaterade API-element

Om true, är egenskapen relatedObject satt till null av orsaker som är relaterade till säkerhetssandlådor. Om det nominella värdet för relatedObject är en referens till ett DisplayObject i en annan sandlåda, är relatedObject satt till null om det inte finns behörighet i båda riktningar över den här sandlådegränsen. Behörighet etableras genom att anropa Security.allowDomain() från en SWF-fil, eller genom att tillhandahålla en principfil för en server för en bildfil och ställa in egenskapen LoaderContext.checkPolicyFile under inläsning av bilden.

Relaterade API-element

Teckenkodsvärdet för tangenten som trycktes ned för att aktivera en keyFocusChange-händelse.

En referens till den kompletterande InteractiveObject-instansen som påverkas av fokusändringen. När exempelvis en focusOut-händelse inträffar motsvarar relatedObject det InteractiveObject-objekt som har hamnat i fokus.

Värdet för den här egenskapen kan vara null under två förhållanden: om det inte finns något relaterat objekt, eller om det finns ett relaterat objekt, men i en säkerhetssandlåda som du inte har tillgång till. Använd egenskapen isRelatedObjectInaccessible() för att avgöra vilken av dessa orsaker det är som gäller.

Relaterade API-element

Indikerar om skifttangentsmodifieringen är aktiverad. I så fall är värdet true. Annars är värdet false. Egenskapen används bara om FocusEvent är av typen keyFocusChange.

Skapar ett nytt Event-objekt med information som är relevant för fokushändelser. Event-objekt skickas som parametrar till händelseavlyssnare.

Relaterade API-element

Skapar en kopia av FocusEvent-objektet och ställer in värdet för alla egenskaper så att de matchar originalets egenskaper.

Returnerar en sträng som innehåller alla egenskaper i FocusEvent-objektet. Strängen är i följande format:

[FocusEvent type=värde bubbles=värde cancelable=värde relatedObject=värde shiftKey=värde] keyCode=värde]

Definierar värdet för ett focusIn-händelseobjekts type-egenskap.

Den här händelsen har följande egenskaper:

Relaterade API-element

Definierar värdet för ett focusOut-händelseobjekts type-egenskap.

Den här händelsen har följande egenskaper:

Relaterade API-element

Definierar värdet för ett keyFocusChange-händelseobjekts type-egenskap.

Den här händelsen har följande egenskaper:

Relaterade API-element

Definierar värdet för ett mouseFocusChange-händelseobjekts type-egenskap.

Den här händelsen har följande egenskaper:

Relaterade API-element

1. Det deklarerar egenskaperna child (av typen Sprite) och childCount (av typen uint).
2. En for-slinga skapar fem ljusblåa fyrkanter på (0,0). Den börjar med att tilldela child till en ny CustomSprite-instans. Varje gång ett CustomSprite-objekt skapas händer följande:
   • size-egenskapen av typen uint är inställd på 50 pixlar och bgColor är inställd på ljusblå.
   • Egenskaperna buttonMode och useHandCursor för klassen Sprite är inställda på true inom konstruktorn.
   • En händelseavlyssnare av typen click skapas, tillsammans med den kopplade mottagaren clickHandler(). Mottagarmetoden skapar en lokal variabel target för typen Sprite och tilldelar den den ruta som användaren klickar på. Scenfokus tilldelas sedan till target.
   • draw()-metoden anropas, vilket skapar en fyrkant om 50 × 50 pixlar genom att anropa metoderna beginFill(), drawRect() och endFill() för klassen Graphics och instansernas egenskaper.
3. I slingan for anropas metoden configureListeners()som startar tre händelseavlyssnare/mottagare:
   • focusIn/focusInHandler() skickas efter att användaren har klickat på click-händelsen för ett visningslisteobjekt (ruta).
   • focusOut/focusOutHandler() skickas när användaren klickar på en annan ruta eller om fokus lämnar scenen (t.ex. om användaren klickar utanför Flash Player).
   • keyFocusChange/keyFocusChangeHandler() skickas om du använder tabbtangenten eller tangenterna vänsterpil och högerpil för att välja ett visningslisteobjekt. Med metoden keyFocusChangeHandler() svälls dock tangenterna vänsterpil och högerpil, och metoden preventDefault() anropas för att inaktivera dem.
4. I for-slingan läggs varje fyrkant till i visningslistan och visas (alla i samma område) med addChild().
5. Konstruktorn anropar sedan refreshLayout() som distribuerar den orange fyrkanten över överkanten (y = 0) av visningen med 5 pixlar mellan varje fyrkant.

package {
    import flash.display.Sprite;
    import flash.display.DisplayObject;
    import flash.events.FocusEvent;
    import flash.events.IEventDispatcher;

    public class FocusEventExample extends Sprite {
        private var gutter:uint = 5;
        private var childCount:uint = 5;

        public function FocusEventExample() {
            var child:Sprite;
            for(var i:uint; i < childCount; i++) {
                child = new CustomSprite();
                configureListeners(child);
                addChild(child);
            }
            refreshLayout();
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(FocusEvent.FOCUS_IN, focusInHandler);
            dispatcher.addEventListener(FocusEvent.FOCUS_OUT, focusOutHandler);
            dispatcher.addEventListener(FocusEvent.KEY_FOCUS_CHANGE, keyFocusChangeHandler);
            dispatcher.addEventListener(FocusEvent.MOUSE_FOCUS_CHANGE, mouseFocusChangeHandler);
        }

        private function refreshLayout():void {
            var ln:uint = numChildren;
            var child:DisplayObject = getChildAt(0);
            var lastChild:DisplayObject = child;
            for(var i:uint = 1; i < ln; i++) {
                child = getChildAt(i);
                child.x = lastChild.x + lastChild.width + gutter;
                lastChild = child;
            }
        }

        private function focusInHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("focusInHandler: " + target.name);
        }

        private function focusOutHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("focusOutHandler: " + target.name);
        }

        private function keyFocusChangeHandler(event:FocusEvent):void {
            if(event.keyCode == 39 || event.keyCode == 37){
                event.preventDefault()
            }
            var target:CustomSprite = CustomSprite(event.target);
            trace("keyFocusChangeHandler: " + target.name);
        }
        private function mouseFocusChangeHandler(event:FocusEvent):void {
            var target:CustomSprite = CustomSprite(event.target);
            trace("mouseFocusChangeHandler: " + target.name);
        }
    }
}

import flash.display.Sprite;
import flash.events.MouseEvent;

class CustomSprite extends Sprite {
    private var size:uint = 50;
    private var bgColor:uint = 0x00CCFF;

    public function CustomSprite() {
        buttonMode = true;
        useHandCursor = true;
        addEventListener(MouseEvent.CLICK, clickHandler);
        draw(size, size);
    }

    private function draw(w:uint, h:uint):void {
        graphics.beginFill(bgColor);
        graphics.drawRect(0, 0, w, h);
        graphics.endFill();
    }

    private function clickHandler(event:MouseEvent):void {
        var target:Sprite = Sprite(event.target);
        trace("clickHandler: " + target.name);
        stage.focus = target;
    }
}