DockIcon - API-referens för Adobe ActionScript® 3 (AS3 )

Paket	flash.desktop
Klass	public class DockIcon
Arv	DockIcon InteractiveIcon Icon EventDispatcher Object

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0

Klassen DockIcon representerar Mac OS X^®-dockningsikonen.

Stöd för AIR-profiler: Den här funktionen stöds på alla operativsystem för datorer, men inte på mobilenheter eller enheter med AIR for TV. Du kan testa stödet vid körning med egenskapen NativeApplication.supportsDockIcon. På sidan om stöd för AIR-profiler hittar du mer information om API-stöd för flera profiler.

Du kan använda DockIcon-klassen för att ändra utseendet på standardikonen, till exempel om du vill animera ikonen eller lägga till informationsbilder. Du kan också lägga till objekt på dockmenyn. De meny objekt som du lägger visas ovanför standardmenyobjekten.

Det går inte att skapa någon instans av DockIcon-klassen. Hämta det objekt som representerar operativsystemets dockningsikon från NativeApplication.icon.

Alla operativsystem har inte dockningsikoner. Kontrollera NativeApplication.supportsDockIcon för att se om dockningsikoner stöds på det aktuella systemet. Om dockningsikoner stöds har egenskapen NativeApplication.icon typen DockIcon. I annat fall är typen för NativeApplication.icon en annan subklass av InteractiveIcon (vanligtvis SystemTrayIcon).

Viktigt! Försök att anropa en DockIcon-klassmetod i NativeApplication.icon-objektet på ett operativsystem där AIR inte stöder dockikoner genererar ett körningsfel.

Visa exemplen

Relaterade API-element

flash.desktop.NativeApplication.icon
flash.desktop.NativeApplication.supportsDockIcon
flash.desktop.SystemTrayIcon

Publika egenskaper

Dölj ärvda publika egenskaper

Visa ärvda publika egenskaper

	Egenskap		Definieras med
		bitmaps : Array [åsidosätt] Ikonbilden som en array med BitmapData-objekt i olika storlekar.	DockIcon
		constructor : Object En referens till klassobjektet eller konstruktorfunktionen för en given objektinstans.	Object
		height : int [åsidosätt] [skrivskyddad] Ikonens aktuella visningshöjd i pixlar.	DockIcon
		menu : NativeMenu Dockningsikonens meny, som hämtas från systemet.	DockIcon
		width : int [åsidosätt] [skrivskyddad] Ikonens aktuella visningsbredd i pixlar.	DockIcon

Publika metoder

Dölj ärvda publika metoder

Visa ärvda publika metoder

	Metod		Definieras med
		addEventListener(type:String, listener:Function, useCapture:Boolean = false, priority:int = 0, useWeakReference:Boolean = false):void Registrerar ett händelseavlyssnarobjekt för ett EventDispatcher-objekt så att avlyssnaren får meddelanden om händelser.	EventDispatcher
		bounce(priority:String = "informational"):void Meddelar användaren att en händelse som kan behöva åtgärdas har inträffat.	DockIcon
		dispatchEvent(event:Event):Boolean Skickar en händelse till händelseflödet.	EventDispatcher
		hasEventListener(type:String):Boolean Kontrollerar om EventDispatcher-objektet har några avlyssnare registrerade för en viss typ av händelse.	EventDispatcher
		hasOwnProperty(name:String):Boolean Anger om det finns en egenskap angiven för ett objekt.	Object
		isPrototypeOf(theClass:Object):Boolean Anger om en instans av klassen Object finns i prototypkedjan för objektet som anges som parameter.	Object
		propertyIsEnumerable(name:String):Boolean Anger om den angivna egenskapen finns och är uppräkningsbar.	Object
		removeEventListener(type:String, listener:Function, useCapture:Boolean = false):void Tar bort en avlyssnare från EventDispatcher-objektet.	EventDispatcher
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void Anger tillgänglighet för en dynamisk egenskap för slingåtgärder.	Object
		toLocaleString():String Returnerar det här objektets strängrepresentation, formaterad i enlighet med språkspecifika konventioner.	Object
		toString():String Returnerar det angivna objektets strängbeteckning.	Object
		valueOf():Object Returnerar det angivna objektets primitiva värde.	Object
		willTrigger(type:String):Boolean Kontrollerar om en händelseavlyssnare är registrerad för det här EventDispatcher-objektet eller något av dess överordnade objekt för den angivna händelsetypen.	EventDispatcher

Händelser

Klicka för mer information om händelser

Dölj ärvda händelser

Visa ärvda händelser

	Händelse		Sammanfattning	Definieras med
		activate	[utsändningshändelse] Skickas när Flash Player eller AIR får operativsystemfokus och blir aktivt.	EventDispatcher
		deactivate	[utsändningshändelse] Skickas när Flash Player eller AIR förlorar operativsystemfokus och blir inaktivt.	EventDispatcher

Egenskapsdetaljer

bitmaps

egenskap

bitmaps:Array[åsidosätt]

Körningsmiljöversioner:

AIR 1.0

Ikonbilden som en array med BitmapData-objekt i olika storlekar.

När en ikon visas i ett visst operativsystemsammanhang används den bitmap i arrayen som bäst matchar visningsstorleken (bilden skalas vid behov). Vanliga storlekar är 16 x 16, 32 x 32, 48 x 48 och 128 x 128. (Ikoner med 512 x 512 pixlar kan snart komma att användas i vissa operativsystemikoner.)

I vissa fall kan operativsystemet använda en standardsystemikon om inget värde har tilldelats egenskapen bitmaps. I andra fall visas ingen ikon alls.

Om du vill ange eller ändra ikonens utseende tilldelar du en array av BitmapData-objekt till egenskapen bitmaps:

     icon.bitmaps = new Array(icon16x16.bitmapData, icon128x128.bitmapData);

Om du ändrar bitmaps-arrayen direkt har detta ingen effekt.

Om du vill ta bort ikonbilden anger du bitmaps-egenskapen till en tom array.

Obs! När bildfilerna för en ikon läses in ger PNG-formatet oftast bäst alfablandning. GIF-formatet har bara stöd för genomskinlighet eller ingen genomskinlighet (blandning saknas). JPG-formatet saknar helt stöd för genomskinlighet.

Implementering
override public function get bitmaps():Array
override public function set bitmaps(value:Array):void

height

egenskap

height:int [skrivskyddad] [åsidosätt]

Körningsmiljöversioner:

AIR 1.0

Ikonens aktuella visningshöjd i pixlar.

Vissa ikonsammanhang har stöd för dynamiska storlekar. height anger ikonens höjd, som hämtas från bitmaps-matrisen för det aktuella sammanhanget. Den verkliga visningshöjden kan vara en annan, om operativsystemet har skalat ikonen.

Implementering
override public function get height():int

 import flash.desktop.NativeApplication;
 import flash.events.Event;
 
private function createDockIconMenu():void{
    if(NativeApplication.supportsDockIcon){                
        var dockIcon:DockIcon = NativeApplication.nativeApplication.icon as DockIcon;
        
        var dockMenu:NativeMenu = new NativeMenu();
        var command:NativeMenuItem = dockMenu.addItem(new NativeMenuItem("Command"));
        command.addEventListener(Event.SELECT, onCommand);
        
        dockIcon.menu = dockMenu;
    }
}

 private function onCommand(event:Event):void{
     //do command...
 }

width

egenskap

width:int [skrivskyddad] [åsidosätt]

Körningsmiljöversioner:

AIR 1.0

Ikonens aktuella visningsbredd i pixlar.

Vissa ikonsammanhang har stöd för dynamiska storlekar. width anger ikonens bredd, som hämtas från bitmaps-matrisen för det aktuella sammanhanget. Den verkliga visningsbredden kan vara en annan, om operativsystemet har skalat ikonen.

Implementering
override public function get width():int

Metoddetaljer

bounce

()

metod

public function bounce(priority:String = "informational"):void

Språkversion:

ActionScript 3.0

Körningsmiljöversioner:

AIR 1.0

Meddelar användaren att en händelse som kan behöva åtgärdas har inträffat.

Genom att anropa den här metoden studsar dockningsikonen, om - och endast om - programmet ligger i bakgrunden. Om priority är NotificationType.Informational studsar ikonen en gång. När priority är NotificationType.Critical studsar ikonen tills programmet placeras i förgrunden.

Parametrar

priority:String (default = "informational") — Hur snabbt dockan ska studsa.

Relaterade API-element

flash.desktop.NotificationType
flash.display.NativeWindow.notifyUser()

Exempel ( Så här använder du exemplet )

Följande exempel studsar dockningsikonen tills användaren aktiverar programmet:

 import flash.display.DockIcon;
 import flash.display.NotificationType;
 import flash.desktop.NativeApplication;

 if(NativeApplication.supportsDockIcon){
     var dockIcon:DockIcon = NativeApplication.nativeApplication.icon As DockIcon;
     dockIcon.bounce(NotificationType.CRITICAL);
 }

Exempel Så här använder du exemplet

DockIconExample.as

Följande exempel läser in en sekvens med bilder och animerar ikonbilden när tidtagaren startas med dockningsikonens meny. (För att exemplet ska fungera måste du ange en uppsättning med ikonbilder och ändra URL:erna i imageURL:ens array.)


 package {
    import flash.desktop.DockIcon;
    import flash.desktop.NativeApplication;
    import flash.display.Loader;
    import flash.display.NativeMenu;
    import flash.display.NativeMenuItem;
    import flash.display.Sprite;
    import flash.events.Event;
    import flash.events.TimerEvent;
    import flash.net.URLRequest;
    import flash.utils.Timer;

    public class AnimatedDockIcon extends Sprite
    {
        private var imageURLs:Array =  ['gfx/frame01.png',
                                        'gfx/frame02.png',
                                        'gfx/frame03.png',
                                        'gfx/frame04.png'];
        
        private var images:Array = new Array();
        private var animTimer:Timer = new Timer(100);
                                        
        public function AnimatedDockIcon()
        {
            NativeApplication.nativeApplication.autoExit = false;
            
            addEventListener(Event.COMPLETE, loadImages);
            loadImages();
            
            animTimer.addEventListener(TimerEvent.TIMER,advanceFrame);
            addMenu();
            stage.nativeWindow.close();
        }
        
        private function addMenu():void{
            var menu:NativeMenu = new NativeMenu();
            var start:NativeMenuItem = menu.addItem(new NativeMenuItem("Start animation"));
            var stop:NativeMenuItem = menu.addItem(new NativeMenuItem("Stop animation"));
            start.addEventListener(Event.SELECT, startTimer);
            stop.addEventListener(Event.SELECT, stopTimer);
            
            var dockIcon:DockIcon =    NativeApplication.nativeApplication.icon as DockIcon;
            dockIcon.menu = menu;
        }
        
        private function startTimer(event:Event):void{
            animTimer.start();
        }

        private function stopTimer(event:Event):void{
            animTimer.stop();
        }

        private var currentFrame:int = 0;
        private function advanceFrame(event:Event):void{
            if(currentFrame < images.length){
                currentFrame++;
            } else {
                currentFrame = 0;
            }
            NativeApplication.nativeApplication.icon.bitmaps = [images[currentFrame]];
        }
        

        private function loadImages(event:Event = null):void{
            if(event != null){
                images.push(event.target.content.bitmapData);
            }
            if(imageURLs.length > 0){
                var urlString:String = imageURLs.pop();
                var loader:Loader = new Loader();
                loader.contentLoaderInfo.addEventListener(Event.COMPLETE, loadImages, false, 0, true);
                loader.load(new URLRequest(urlString));
            } else {
                var complete:Event = new Event(Event.COMPLETE,false,false);
                dispatchEvent(complete);
            }
        }
    }
}

Juridiska meddelanden | Onlinesekretesspolicy

DockIcon - AS3

Klasser x

bitmaps

height

menu

width

bounce