| Paket | fl.controls.dataGridClasses |
| Klass | public class DataGridColumn |
| Arv | DataGridColumn  Object |
| Språkversion: | ActionScript 3.0 |
| Produktversion: | Flash CS3 |
| Körningsmiljöversioner: | Flash Player 9.0.28.0, AIR 1.0 |
Du kan ange vilken typ av komponent som visar data för en DataGridColumn. I egenskaperna som kan anges inkluderas texten som visas i kolumnrubriken och om kolumnen går att redigera, sortera eller ändra storlek på.
Relaterade API-element
Dölj ärvda publika egenskaper
Visa ärvda publika egenskaper| Egenskap | Definieras med | ||
|---|---|---|---|
| cellRenderer : Object
Klassen som används för att rendera objekten i den här kolumnen. | DataGridColumn | ||
 | constructor : Object
En referens till klassobjektet eller konstruktorfunktionen för en given objektinstans. | Object | |
| dataField : String
Identifierar namnet på fältet eller egenskapen i DataProvider-objektet som associeras med kolumnen. | DataGridColumn | ||
| editable : Boolean = true
Anger om det går att redigera objekten i kolumnen. | DataGridColumn | ||
| editorDataField : String = "text"
Identifierar namnet på egenskapen i objektredigeraren som innehåller nya data för listobjektet. | DataGridColumn | ||
| headerRenderer : Object
Klassen som används för att rendera rubriken i den här kolumnen. | DataGridColumn | ||
| headerText : String
Kolumnnamnet som ska visas i kolumnrubriken. | DataGridColumn | ||
| imeMode : String
Läget för IME (Input Method Editor). | DataGridColumn | ||
| itemEditor : Object = fl.controls.dataGridClasses.DataGridCellEditor
Anger klassen för instanserna av objektredigeraren som ska användas för kolumnen när den går att redigera. | DataGridColumn | ||
| labelFunction : Function
En funktion som bestämmer vilken text som ska visas i den här kolumnen. | DataGridColumn | ||
| minWidth : Number
Minsta bredden för kolumnen, i pixlar. | DataGridColumn | ||
| resizable : Boolean = true
Anger om användaren får ändra på bredden på kolumnen. | DataGridColumn | ||
| sortable : Boolean = true
Anger om användaren kan klicka på kolumnrubriken för den aktuella kolumnen för att sortera DataProvider. | DataGridColumn | ||
| sortCompareFunction : Function
En callback-funktion anropas när data sorteras i kolumnen. | DataGridColumn | ||
| sortDescending : Boolean = false
Identifierar om DataGridColumn ska sorteras i stigande eller fallande ordning. | DataGridColumn | ||
| sortOptions : uint = 0
En eller flera definierade konstanter, identifierade efter namn eller nummer och separerade med operatorn OR (|) i bitform. | DataGridColumn | ||
| visible : Boolean
Anger om kolumnen ska synas. | DataGridColumn | ||
| width : Number
Kolumnens bredd i pixlar. | DataGridColumn | ||
| Metod | Definieras med | ||
|---|---|---|---|
DataGridColumn(columnName:String = null)
Skapar en ny DataGridColumn-instans. | DataGridColumn | ||
|
Anger om det finns en egenskap angiven för ett objekt. | Object | |
|
Anger om en instans av klassen Object finns i prototypkedjan för objektet som anges som parameter. | Object | |
Returnerar strängen som visas i objektrenderaren för det angivna dataobjektet. | DataGridColumn | ||
|
Anger om den angivna egenskapen finns och är uppräkningsbar. | Object | |
|
Anger tillgänglighet för en dynamisk egenskap för slingåtgärder. | Object | |
|
Returnerar det här objektets strängrepresentation, formaterad i enlighet med språkspecifika konventioner. | Object | |
Returnerar DataGridColum-objektets strängbeteckning. | DataGridColumn | ||
|
Returnerar det angivna objektets primitiva värde. | Object | |
cellRenderer | egenskap |
cellRenderer:Object| Språkversion: | ActionScript 3.0 |
| Produktversion: | Flash CS3 |
| Körningsmiljöversioner: | Flash Player 9.0.28.0, AIR 1.0 |
Klassen som används för att rendera objekten i den här kolumnen. Typen för den här egenskapen kan vara Class, Sprite eller String. Om egenskapstypen är String måste strängvärdet vara ett fullständigt kvalificerat klassnamn.
Standardvärdet är null.
Implementering
public function get cellRenderer():Object public function set cellRenderer(value:Object):voidRelaterade API-element
Exempel ( Så här använder du exemplet )
import fl.controls.dataGridClasses.DataGridColumn;
var dgc:DataGridColumn = new DataGridColumn("Field");
dgc.cellRenderer = "MyCustomCellRendererClass";
dg.addColumn(dgc);
dataField | egenskap |
public var dataField:String| Språkversion: | ActionScript 3.0 |
| Produktversion: | Flash CS3 |
| Körningsmiljöversioner: | Flash Player 9.0.28.0, AIR 1.0 |
Identifierar namnet på fältet eller egenskapen i DataProvider-objektet som associeras med kolumnen.
editable | egenskap |
public var editable:Boolean = true| Språkversion: | ActionScript 3.0 |
| Produktversion: | Flash CS3 |
| Körningsmiljöversioner: | Flash Player 9.0.28.0, AIR 1.0 |
Anger om det går att redigera objekten i kolumnen. Värdet true anger att det går att redigera objekten i kolumnen. Värdet false anger att de inte går att redigera.
Om den här egenskapen ställs in på true och editable-egenskapen i DataGrid också är true går det att redigera objekten i en kolumn och de kan redigeras individuellt genom att du klickar på ett objekt eller flyttar till objektet med tabb- och piltangenterna.
Standardvärdet är true.
editorDataField | egenskap |
public var editorDataField:String = "text"| Språkversion: | ActionScript 3.0 |
| Produktversion: | Flash CS3 |
| Körningsmiljöversioner: | Flash Player 9.0.28.0, AIR 1.0 |
Identifierar namnet på egenskapen i objektredigeraren som innehåller nya data för listobjektet.
Om t.ex. itemEditor som standard är TextInput är standardvärdet för editorDataField-egenskapen "text". Det här värdet anger text-egenskapen för TextInput-komponenten.
Standardvärdet är "text".
headerRenderer | egenskap |
headerRenderer:Object| Språkversion: | ActionScript 3.0 |
| Produktversion: | Flash CS3 |
| Körningsmiljöversioner: | Flash Player 9.0.28.0, AIR 1.0 |
Klassen som används för att rendera rubriken i den här kolumnen.
Typen för den här egenskapen kan vara Class, Sprite eller String. Om egenskapstypen är String måste strängvärdet vara ett fullständigt kvalificerat klassnamn.
Standardvärdet är null.
Implementering
public function get headerRenderer():Object public function set headerRenderer(value:Object):voidRelaterade API-element
headerText | egenskap |
headerText:String| Språkversion: | ActionScript 3.0 |
| Produktversion: | Flash CS3 |
| Körningsmiljöversioner: | Flash Player 9.0.28.0, AIR 1.0 |
Kolumnnamnet som ska visas i kolumnrubriken. DataGrid-komponenten använder som standard värdet för dataField-egenskapen som kolumnnamn.
Implementering
public function get headerText():String public function set headerText(value:String):voidExempel ( Så här använder du exemplet )
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
var dp:DataProvider = new DataProvider();
dp.addItem({name:"Person A", sales:13453});
dp.addItem({name:"Person B", sales:23432});
dp.addItem({name:"Person C", sales:9454});
var nameCol:DataGridColumn = new DataGridColumn("name");
nameCol.headerText = "Employee:";
var salesCol:DataGridColumn = new DataGridColumn("sales");
salesCol.headerText = "Sales:";
salesCol.labelFunction = currencyFormatter;
salesCol.sortOptions = Array.NUMERIC;
var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn(nameCol);
myDataGrid.addColumn(salesCol);
myDataGrid.dataProvider = dp;
myDataGrid.move(10, 10);
myDataGrid.setSize(320, 240);
addChild(myDataGrid);
function currencyFormatter(item:Object):String {
return "$" + item.sales.toFixed(0);
}
imeMode | egenskap |
imeMode:String| Språkversion: | ActionScript 3.0 |
| Produktversion: | Flash CS3 |
| Körningsmiljöversioner: | Flash Player 9.0.28.0, AIR 1.0 |
Läget för IME (Input Method Editor). IME gör att användare kan ange text på kinesiska, japanska eller koreanska. Klassen flash.system.IMEConversionMode definierar konstanter som ska användas som de giltiga värdena för den här egenskapen.
Om den här egenskapen är null ställs läget för IME in på imeMode-egenskapens värde för DataGrid-komponenten.
Standardvärdet är null.
Implementering
public function get imeMode():String public function set imeMode(value:String):voidRelaterade API-element
itemEditor | egenskap |
public var itemEditor:Object = fl.controls.dataGridClasses.DataGridCellEditor| Språkversion: | ActionScript 3.0 |
| Produktversion: | Flash CS3 |
| Körningsmiljöversioner: | Flash Player 9.0.28.0, AIR 1.0 |
Anger klassen för instanserna av objektredigeraren som ska användas för kolumnen när den går att redigera. Typen för den här egenskapen kan vara Class, Sprite eller String. Om egenskapstypen är String måste strängvärdet vara ett fullständigt kvalificerat klassnamn.
Standardvärdet är "fl.controls.dataGridClasses.DataGridCellEditor".
Exempel ( Så här använder du exemplet )
import fl.controls.dataGridClasses.DataGridColumn;
var dgc:DataGridColumn = new DataGridColumn("Field");
dgc.itemEditor = "MyCustomItemEditorClass";
dg.addColumn(dgc);
labelFunction | egenskap |
labelFunction:Function| Språkversion: | ActionScript 3.0 |
| Produktversion: | Flash CS3 |
| Körningsmiljöversioner: | Flash Player 9.0.28.0, AIR 1.0 |
En funktion som bestämmer vilken text som ska visas i den här kolumnen. Som standard visas texten för datafältet som matchar kolumnnamnet i kolumnen. I en kolumn kan även text för mer än ett datafält visas, eller så kan innehåll med felaktigt format visas. Detta kan göras med hjälp av labelFunction-egenskapen för att ange en återkopplingsfunktion.
Om båda egenskaperna labelFunction och labelField definieras prioriteras labelFunction.
Standardvärdet är null.
Implementering
public function get labelFunction():Function public function set labelFunction(value:Function):voidExempel ( Så här använder du exemplet )
import fl.controls.DataGrid;
import fl.controls.ScrollPolicy;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
var i:uint;
var totalRows:uint = 16;
var dp:DataProvider = new DataProvider();
for (i = 0; i < totalRows; i++) {
dp.addItem({col1:getRandomNumber(), col2:getRandomNumber(), col3:getRandomNumber(), col4:getRandomNumber()});
}
var c1:DataGridColumn = new DataGridColumn("col1");
c1.sortOptions = Array.NUMERIC;
var c2:DataGridColumn = new DataGridColumn("col2");
c2.sortOptions = Array.NUMERIC;
var c3:DataGridColumn = new DataGridColumn("col3");
c3.sortOptions = Array.NUMERIC;
c3.labelFunction = currencyFormatter;
var dg:DataGrid = new DataGrid();
dg.setSize(200, 300);
dg.addColumn(c1);
dg.addColumn(c2);
dg.addColumn(c3);
dg.dataProvider = dp;
addChild(dg);
function getRandomNumber():Number {
return Math.random() * 100;
}
function currencyFormatter(data:Object):String {
var value:Number = Number(data.col3);
return "$" + value.toFixed(2);
}
labelFunction och en sortCompareFunction anges:
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
var data:XML = <data>
<item name="Employee A" isManager="1" />
<item name="Employee B" isManager="0" />
<item name="Employee C" isManager="1" />
</data>;
var dp:DataProvider = new DataProvider(data);
var nameDGC:DataGridColumn = new DataGridColumn("name");
nameDGC.sortCompareFunction = isManager;
nameDGC.labelFunction = nameLabelFunction;
var myDataGrid:DataGrid = new DataGrid()
myDataGrid.addColumn(nameDGC);
myDataGrid.dataProvider = dp;
myDataGrid.width = 200;
myDataGrid.rowCount = myDataGrid.length;
myDataGrid.move(10, 10);
addChild(myDataGrid);
function nameLabelFunction(item:Object):String {
var managerString:String = "";
if (item.isManager == "1") {
managerString = " (Manager)";
}
return item.name + managerString;
}
function isManager(itemA:Object, itemB:Object):int {
if (itemA.isManager > itemB.isManager) {
return -1;
} else if (itemA.isManager < itemB.isManager) {
return 1;
} else {
return 0;
}
}
minWidth | egenskap |
minWidth:Number| Språkversion: | ActionScript 3.0 |
| Produktversion: | Flash CS3 |
| Körningsmiljöversioner: | Flash Player 9.0.28.0, AIR 1.0 |
Minsta bredden för kolumnen, i pixlar.
Standardvärdet är 20.
Implementering
public function get minWidth():Number public function set minWidth(value:Number):voidRelaterade API-element
Exempel ( Så här använder du exemplet )
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;
var data:XML = <data>
<row col1="item 1.A" col2="item 1.B" col3="item 1.C" />
<row col1="item 2.A" col2="item 2.B" col3="item 2.C" />
<row col1="item 3.A" col2="item 3.B" col3="item 3.C" />
</data>;
var dp:DataProvider = new DataProvider(data);
var c1:DataGridColumn = new DataGridColumn("col1");
c1.minWidth = 100;
var c2:DataGridColumn = new DataGridColumn("col2");
var c3:DataGridColumn = new DataGridColumn("col3");
var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn(c1);
myDataGrid.addColumn(c2);
myDataGrid.addColumn(c3);
myDataGrid.dataProvider = dp;
myDataGrid.move(10, 10);
myDataGrid.setSize(300, 200);
myDataGrid.addEventListener(DataGridEvent.COLUMN_STRETCH, columnStretchHandler);
addChild(myDataGrid);
function columnStretchHandler(event:DataGridEvent):void {
var column:DataGridColumn;
for each (column in myDataGrid.columns) {
trace(column.dataField, "width:" + column.width, "minWidth:" + column.minWidth);
}
trace("---");
}
resizable | egenskap |
public var resizable:Boolean = true| Språkversion: | ActionScript 3.0 |
| Produktversion: | Flash CS3 |
| Körningsmiljöversioner: | Flash Player 9.0.28.0, AIR 1.0 |
Anger om användaren får ändra på bredden på kolumnen. Värdet true anger att användaren får ändra på bredden på kolumnen. Värdet false anger att användaren inte får ändra på bredden på kolumnen.
Standardvärdet är true.
sortable | egenskap |
public var sortable:Boolean = true| Språkversion: | ActionScript 3.0 |
| Produktversion: | Flash CS3 |
| Körningsmiljöversioner: | Flash Player 9.0.28.0, AIR 1.0 |
Anger om användaren kan klicka på kolumnrubriken för den aktuella kolumnen för att sortera DataProvider. Värdet true anger att kolumnen kan sorteras genom att du klickar på rubriken. Värdet false anger att den inte kan sorteras genom att du klickar på rubriken.
Standardvärdet är true.
Exempel ( Så här använder du exemplet )
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;
var data:XML = <dataProvider>
<data col1="Person A" col2="11.383" />
<data col1="Person B" col2="3.399" />
<data col1="Person C" col2="25.624" />
</dataProvider>
var dp:DataProvider = new DataProvider(data);
var c1:DataGridColumn = new DataGridColumn("col1");
var c2:DataGridColumn = new DataGridColumn("col2");
c2.sortable = false;
var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn(c1);
myDataGrid.addColumn(c2);
myDataGrid.dataProvider = dp;
myDataGrid.move(10, 10);
myDataGrid.setSize(160, 120);
addChild(myDataGrid);
sortable-egenskap ställs in på false:
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
import fl.events.DataGridEvent;
var xmlDP:XML = <items>
<item name="Person 1" bio="Person 1 bio" />
<item name="Person 2" bio="Person 2 bio" />
</items>;
var dp:DataProvider = new DataProvider(xmlDP);
var nameCol:DataGridColumn = new DataGridColumn("name");
nameCol.headerText = "Name:";
var bioCol:DataGridColumn = new DataGridColumn("bio");
bioCol.headerText = "Bio:";
bioCol.sortable = false;
var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn(nameCol);
myDataGrid.addColumn(bioCol);
myDataGrid.dataProvider = dp;
myDataGrid.rowCount = dp.length;
myDataGrid.width = 200;
myDataGrid.move(10, 10);
myDataGrid.addEventListener(DataGridEvent.HEADER_RELEASE, headerReleaseHandler);
addChild(myDataGrid);
function headerReleaseHandler(event:DataGridEvent):void {
var myDG:DataGrid = event.currentTarget as DataGrid;
trace("dataField:" + event.dataField);
trace("columnIndex:" + event.columnIndex);
trace("{DataGrid}.sortDescending:" + myDG.sortDescending);
trace("{DataGridColumn}.sortDescending:" + myDG.getColumnAt(event.columnIndex).sortDescending);
trace("");
}
sortCompareFunction | egenskap |
sortCompareFunction:Function| Språkversion: | ActionScript 3.0 |
| Produktversion: | Flash CS3 |
| Körningsmiljöversioner: | Flash Player 9.0.28.0, AIR 1.0 |
En callback-funktion anropas när data sorteras i kolumnen. Om den här egenskapen inte anges sorteras data efter sträng eller nummer beroende på sortOptions-egenskapen. Om den anges kan du skapa en egen sorteringsmetod för den aktuella datarutnätskolumnen med egenskapen sortCompareFunction.
Standardvärdet är null.
Implementering
public function get sortCompareFunction():Function public function set sortCompareFunction(value:Function):voidRelaterade API-element
Exempel ( Så här använder du exemplet )
labelFunction och en sortCompareFunction anges:
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
var data:XML = <data>
<item name="Employee A" isManager="1" />
<item name="Employee B" isManager="0" />
<item name="Employee C" isManager="1" />
</data>;
var dp:DataProvider = new DataProvider(data);
var nameDGC:DataGridColumn = new DataGridColumn("name");
nameDGC.sortCompareFunction = isManager;
nameDGC.labelFunction = nameLabelFunction;
var myDataGrid:DataGrid = new DataGrid()
myDataGrid.addColumn(nameDGC);
myDataGrid.dataProvider = dp;
myDataGrid.width = 200;
myDataGrid.rowCount = myDataGrid.length;
myDataGrid.move(10, 10);
addChild(myDataGrid);
function nameLabelFunction(item:Object):String {
var managerString:String = "";
if (item.isManager == "1") {
managerString = " (Manager)";
}
return item.name + managerString;
}
function isManager(itemA:Object, itemB:Object):int {
if (itemA.isManager > itemB.isManager) {
return -1;
} else if (itemA.isManager < itemB.isManager) {
return 1;
} else {
return 0;
}
}
sortDescending | egenskap |
public var sortDescending:Boolean = false| Språkversion: | ActionScript 3.0 |
| Produktversion: | Flash CS3 |
| Körningsmiljöversioner: | Flash Player 9.0.28.0, AIR 1.0 |
Identifierar om DataGridColumn ska sorteras i stigande eller fallande ordning. Värdet true anger att DataGridColumn sorteras i fallande ordning. Värdet false anger att DataGridColumn sorteras i stigande ordning.
Standardvärdet är false.
sortOptions | egenskap |
public var sortOptions:uint = 0| Språkversion: | ActionScript 3.0 |
| Produktversion: | Flash CS3 |
| Körningsmiljöversioner: | Flash Player 9.0.28.0, AIR 1.0 |
En eller flera definierade konstanter, identifierade efter namn eller nummer och separerade med operatorn OR (|) i bitform. Dessa konstanter används för att ange sorteringsåtgärden.
Standardvärdet är 0.
Relaterade API-element
Exempel ( Så här använder du exemplet )
sortOptions för att ange att en datarutnätskolumn ska sorteras numeriskt:
import fl.data.DataProvider;
import fl.controls.dataGridClasses.DataGridColumn;
var data:XML = <players>
<player name="Player 1" score="1234" />
<player name="Player 2" score="198" />
<player name="Player 3" score="987" />
</players>;
var dp:DataProvider = new DataProvider(data);
var nameDGC:DataGridColumn = new DataGridColumn("name");
var scoreDGC:DataGridColumn = new DataGridColumn("score");
scoreDGC.sortOptions = Array.NUMERIC;
dg.addColumn(nameDGC);
dg.addColumn(scoreDGC);
dg.dataProvider = dp;
visible | egenskap |
visible:Boolean| Språkversion: | ActionScript 3.0 |
| Produktversion: | Flash CS3 |
| Körningsmiljöversioner: | Flash Player 9.0.28.0, AIR 1.0 |
Anger om kolumnen ska synas. Värdet true anger att kolumnen ska synas. Värdet false anger att kolumnen inte ska synas.
Standardvärdet är true.
Implementering
public function get visible():Boolean public function set visible(value:Boolean):voidExempel ( Så här använder du exemplet )
visible-egenskapen i dessa kolumner genom att klicka på motsvarande Button-instans på scenen.
import fl.controls.Button;
import fl.controls.DataGrid;
import fl.controls.dataGridClasses.DataGridColumn;
import fl.data.DataProvider;
var dp:DataProvider = new DataProvider();
dp.addItem({name:"Person A", average:0.297});
dp.addItem({name:"Person B", average:0.288});
dp.addItem({name:"Person C", average:0.310});
var nameCol:DataGridColumn = new DataGridColumn("name");
nameCol.headerText = "Name:";
var averageCol:DataGridColumn = new DataGridColumn("average");
averageCol.headerText = "Average:";
averageCol.labelFunction = numberFormatter;
averageCol.sortOptions = Array.NUMERIC;
averageCol.visible = false;
var myDataGrid:DataGrid = new DataGrid();
myDataGrid.addColumn(nameCol);
myDataGrid.addColumn(averageCol);
myDataGrid.dataProvider = dp;
myDataGrid.rowCount = dp.length;
myDataGrid.width = 320;
myDataGrid.move(10, 10);
addChild(myDataGrid);
var nameButton:Button = new Button();
nameButton.label = "Toggle name";
nameButton.toggle = true;
nameButton.selected = nameCol.visible;
nameButton.move(myDataGrid.x, myDataGrid.y + myDataGrid.height + 10);
nameButton.addEventListener(Event.CHANGE, changeHandler);
addChild(nameButton);
var averageButton:Button = new Button();
averageButton.label = "Toggle average";
averageButton.toggle = true;
averageButton.selected = averageCol.visible;
averageButton.move(nameButton.x + nameButton.width + 10, nameButton.y);
averageButton.addEventListener(Event.CHANGE, changeHandler);
addChild(averageButton);
function numberFormatter(item:Object):String {
return Number(item.average).toFixed(3);
}
function changeHandler(event:Event):void {
var colIndex:int = -2;
var col:DataGridColumn;
switch (event.currentTarget) {
case nameButton:
colIndex = myDataGrid.getColumnIndex("name");
break;
case averageButton:
colIndex = myDataGrid.getColumnIndex("average");
break;
default:
return;
}
if (colIndex > -1) {
col = myDataGrid.getColumnAt(colIndex);
col.visible = !col.visible;
myDataGrid.removeColumnAt(colIndex);
myDataGrid.addColumnAt(col, colIndex);
}
myDataGrid.spaceColumnsEqually();
}
width | egenskap |
DataGridColumn | () | Konstruktor |
public function DataGridColumn(columnName:String = null)| Språkversion: | ActionScript 3.0 |
| Produktversion: | Flash CS3 |
| Körningsmiljöversioner: | Flash Player 9.0.28.0, AIR 1.0 |
Skapar en ny DataGridColumn-instans.
ParametrarcolumnName:String (default = null)dataField.
|
Relaterade API-element
itemToLabel | () | metod |
public function itemToLabel(data:Object):String| Språkversion: | ActionScript 3.0 |
| Produktversion: | Flash CS3 |
| Körningsmiljöversioner: | Flash Player 9.0.28.0, AIR 1.0 |
Returnerar strängen som visas i objektrenderaren för det angivna dataobjektet. Om DataGridColumn eller DataGrid-komponenten har en labelFunction-egenskap som inte är null använder den funktionen på dataobjektet. Annars extraherar metoden innehållet i fältet som anges av dataField-egenskapen eller hämtar strängvärdet för dataobjektet. Om metoden inte kan konvertera parametern till en sträng returneras en ett enkelt blanksteg.
Parametrar
data:Object — Objektet som ska renderas.
|
String — Visningsbar sträng baserad på det angivna data-objektet.
|
toString | () | metod |
- Lägg till DataGrid- och Button-komponenterna i biblioteket.
- Spara koden som DataGridColumnExample.as i samma katalog som din FLA-fil.
- Ställ in DataGridColumnExample som DocumentClass i FLA-filen.
package
{
import flash.display.Sprite;
import flash.events.MouseEvent;
import fl.data.DataProvider;
import fl.events.DataChangeEvent;
import fl.controls.DataGrid;
import fl.controls.Button;
import fl.controls.dataGridClasses.DataGridColumn;
public class DataGridColumnExample extends Sprite
{
private var dg:DataGrid;
private var dp:DataProvider;
private var names:Array = [ "Mary", "Bob", "Sue", "Joe" ];
public function DataGridColumnExample() {
dp = new DataProvider();
dp.addEventListener(DataChangeEvent.DATA_CHANGE,dataChanged);
dg = new DataGrid();
addChild(dg);
dg.move(10,45);
dg.setSize(450,300);
dg.addColumn(new DataGridColumn("name"));
dg.addColumn(new DataGridColumn("phone"));
dg.addColumn(new DataGridColumn("email"));
var firstColumn = dg.columns[0];
firstColumn.resizable = false;
var secondColumn = dg.columns[1];
secondColumn.sortable = false;
var thirdColumn = dg.columns[2];
thirdColumn.sortable = false;
var addContactBtn:Button = new Button();
addContactBtn.label = "Add Contact";
addContactBtn.move(10,10);
addContactBtn.addEventListener(MouseEvent.CLICK, addContact);
addChild(addContactBtn);
}
private function getRandomPhone():String {
return randomDigit()+randomDigit()+randomDigit()+"-"+randomDigit()+randomDigit()+randomDigit()+"-"+randomDigit()+randomDigit()+randomDigit()+randomDigit();
}
private function randomDigit():String {
return String(Math.round(Math.random()*10)%10);
}
private function getRandomName():String {
return names[Math.round(Math.random()*names.length)%names.length];
}
private function addContact(e:MouseEvent):void {
var randomName:String = getRandomName()
dp.addItem( { name: randomName, phone: getRandomPhone(), email: randomName + "@fictitious.com" } );
}
private function dataChanged(e:DataChangeEvent):void {
var changedItems:Array = e.items;
dg.addItem(changedItems[0]);
}
}
}
Tue Jun 12 2018, 01:40 PM Z