JSON  - AS3

Godtar en JSON-formaterad sträng och returnerar ett ActionScript-objekt som representerar värdet. JSON-objekt, arrayer, strängar, tal, booleska värden och null-mappning som motsvarar ActionScript-värden, enligt nedan:

Parametern reviver är en funktion som har två parametrar: en nyckel och ett värde. Du kan använda den här funktionen för att omforma eller filtrera varje nyckel/värdepar medan den/det tolkas. Om du levererar en reviver-funktion, returneras ditt omformade eller filtrerade värde för varje par och inte standardtolkningen i parse()-funktionens utdata. Om reviver-funktionen returnerar undefined för något av paren, kommer egenskapen att tas bort från slutresultatet.

När argumentet som skickas till reviverparametern inte är en funktion, kommer ActionScript att generera ett TypeError med fel-ID kJSONInvalidReviver. Dessutom skapas ett anpassat felmeddelande.

Om parse()-funktionen upptäcker dubbla nycklar i ett objekt, kommer den nyckeldubblett som upptäcktes sist att leverera värdet för alla tidigare förekomster av den nyckeln.

Parametrar

Returnerar en sträng, i JSON-format, som representerar ett ActionScript-värde. Metoden stringify kan innehålla tre parametrar.

Parametern value är obligatorisk. Denna parameter är ett ActionScript-värde. Vanligtvis är det ett objekt eller en array, men det kan även vara en sträng, booleskt värde, tal eller null.

Den valfria parametern replacer kan antingen vara en funktion eller en array med strängar eller tal. Om det är en funktion ska funktionen ha två parametrar: en nyckel och ett värde. Du kan använda den här funktionen för att omforma eller filtrera varje nyckel/värdepar medan den/det tolkas. Om du levererar en replacer-funktion, returneras ditt omformade eller filtrerade värde för varje par och inte standardtolkningen i parse()-funktionens utdata. Om replacer-funktionen returnerar undefined för något av paren, kommer egenskapen att tas bort från slutresultatet. Om replacer är en array, används det som ett filter för att bestämma vilka egenskaper som ska inkluderas i utdata.

När argumentet som skickas till parametern replacer varken är en array eller en funktion, kommer ActionScript att generera ett TypeError med fel-ID kJSONInvalidReplacer. Dessutom skapas ett anpassat felmeddelande.

Den valfria parametern space är en sträng eller ett tal som tillåter att tomt utrymme kan infogas i den returnerade strängen för att göra den lättare att läsa. Poster i genererade JSON-objekt och JSON-arrayer separeras med ett mellanrum härlett från parameternspace. Detta mellanrum är alltid 0 till 10 tecken brett. Om space är en sträng kommer det härledda mellanrummet att vara de tio första tecknen för strängen. Om space är ett icke-negativt tal x, kommer mellanrummet att vara x blanksteg, maximalt tio. När argumentet som skickas till space-parametern inte är en sträng eller ett tal, konverteras det till en sträng som ska användas som mellanrum i utdata. Sedan fortsätter körningen.

När metoden stringify() upptäcker en cyklisk struktur, genereras ett TypeError med fel-ID kJSONCyclicStructure. Dessutom skapas ett anpassat felmeddelande.

Parametrar

1. Konstruktorn för JSONExample tilldelar en sträng till superklassens text-medlem och initierar en intern räknare.
2. Klassen definierar dessutom en array som kan innehålla JSONExample-objekt som har exporterats till JSON.
3. JSONExample definierar även en toJSON()-metod och en revive()-metod. Metoden toJSON() anropas av JSON.stringify() för att serialisera JSONExample-objekt till JSON. Metoden revive() kan anropas från JSON.parse()-metoder för att återställa det fullständiga JSONExample-objektet. Denna återställning uppnås genom att ett visst ID används för att hämta originalobjektet från arrayen med återställningsbara objekt.
4. Det skript som använder klassdefinitionen skapar ett objekt som innehåller två TextField-objekt och ett JSONExample-objekt. Det skapar också en array med återställningsbara objekt för lagring av TextField-objekt som har exporterats till JSON.
5. Funktionen replacer för JSON.stringify() filtrerar TextField-objekt från JSON-strängen. På varje borttaget objekts plats tillhandahåller replacer en markör med ett ID som kan användas senare för att hämta objektet. JSONExample-objekt, å andra sidan, skickas i enlighet med deras ursprungliga JSON-kodning.
6. Funktionen reviver för metoden parse() återskapar det ursprungliga objektet genom att hämta alla TextField- och JSONExample-objekt som refereras.

 
 package {
    import flash.text.TextField;
    public class JSONExample extends TextField
    {
        static var nextId = 10000;
        static var revivable_objects:Array = [];
            public var id;

        public function JSONExample(s:String){
            super.text = s;
            id = ++nextId;
        }
        public function toJSON(k):*
        {
            // To be called internally by the JSON.stringify() method.
            // Save the original object internally.
            // Write out only a generated ID and the text value.
            revivable_objects[id] = this;
            return {"classJSONExample":{"reviveId":id,"contents":this.text}};
        }
        public static function revive(id:int):JSONExample
        {
            // For explicit use in the JSON.parse() method.
            // Revives the object using the ID obtained from the JSON string.
            return revivable_objects[id];
        }
    }
}

import flash.text.TextField;

var lastId = 20000;
var tf1:TextField = new TextField();
tf1.text = "Lorem ipsum";
var tf2:TextField = new TextField();
tf2.text = "Laughing cows";
var nt:JSONExample = new JSONExample("It was the best of times; it was the worst of times.");

var obj:Object = {a:tf1, b:nt, c:tf2};
var revivable_objects:Array = new Array();

var json_out = JSON.stringify(obj, function(k,v){
        if (v is JSONExample)
        {
            // Send JSONExample objects to the JSON output.
            // Note that stringify() calls JSONExample.toJSON() to serialize this object.
            return v;
        }
        if (v is TextField)
        {
            // Remove TextField objects from the JSON output.
            // Save the original object for reviving later.
            // Return a new object containing an identification marker
            // and the original object's revival ID.
            revivable_objects[++lastId] = v;
            return {"classTextField":{"reviveId":lastId}};
        }
        return v;
    }
);
               
trace("json_out: " + json_out);

var json_in = JSON.parse(json_out, function(k,v) {
        if ("classTextField" in v) { // special marker tag from stringify() replacer code
            // Retrieve the original object based on the ID stored in the stringify() replacer function.
            var id = v["classTextField"].reviveId;
            return revivable_objects[id];
        } else if ("classJSONExample" in v){
            // Retrieve the original object based on the ID generated in JSONExample.toJSON().
            return JSONExample.revive(v["classJSONExample"].reviveId);
        }
        return v;
    }
);

if (json_in.a)
{
    if (json_in.a.hasOwnProperty("text"))
        {
            trace("json_in.a: " + json_in.a.text);
        }
}
if (json_in.b)
{
    if (json_in.b.hasOwnProperty("text"))
        {
            trace("json_in.b: " + json_in.b.text);
        }
}

if (json_in.c)
{
    if (json_in.c.hasOwnProperty("text"))
        {
            trace("json_in.c: " + json_in.c.text);
        }
}