Инициализация переменных XML

Flash Player 9 и более поздних версий, Adobe AIR 1.0 и более поздних версий

Присвоить литерал XML объекту XML можно следующим образом:

var myXML:XML =  
    <order> 
        <item id='1'> 
            <menuName>burger</menuName> 
            <price>3.95</price> 
        </item> 
        <item id='2'> 
            <menuName>fries</menuName> 
            <price>1.45</price> 
        </item> 
    </order>

Как показано в следующем фрагменте, для создания экземпляра объекта XML из строки, содержащей XML-данные, можно также использовать конструктор new :

var str:String = "<order><item id='1'><menuName>burger</menuName>" 
                            + "<price>3.95</price></item></order>"; 
var myXML:XML = new XML(str);

Если XML-данные плохо сформированы в строке (например, если отсутствует закрывающий тег), появится ошибка периода исполнения.

Передавать данные в объект XML можно также по ссылке (из других переменных), как это показано в следующем примере:

var tagname:String = "item";  
var attributename:String = "id";  
var attributevalue:String = "5";  
var content:String = "Chicken";  
var x:XML = <{tagname} {attributename}={attributevalue}>{content}</{tagname}>;  
trace(x.toXMLString()) 
    // Output: <item id="5">Chicken</item>

Чтобы загрузить XML-данные из URL-адреса, используйте класс URLLoader, как показано в следующем примере:

import flash.events.Event; 
import flash.net.URLLoader; 
import flash.net.URLRequest; 
 
var externalXML:XML; 
var loader:URLLoader = new URLLoader(); 
var request:URLRequest = new URLRequest("xmlFile.xml"); 
loader.load(request); 
loader.addEventListener(Event.COMPLETE, onComplete); 
 
function onComplete(event:Event):void 
{ 
    var loader:URLLoader = event.target as URLLoader; 
    if (loader != null) 
    { 
        externalXML = new XML(loader.data); 
        trace(externalXML.toXMLString()); 
    } 
    else 
    { 
        trace("loader is not a URLLoader!"); 
    } 
}

Для считывания XML-данных из соединения гнезд используйте класс XMLSocket. Дополнительные сведения см. в описании класса XMLSocket в cправочнике ActionScript® 3.0 для платформы Adobe® Flash® Platform .