XMLSocket  - AS3

Определяет, подключен ли в настоящий момент данный объект XMLSocket. Для того чтобы также проверить успешность подключения, можно зарегистрироваться на получение события connect и события ioError.

Связанные элементы API

Указывает время ожидания подключения в миллисекундах.

Если подключение не будет установлено в течение заданного срока, попытка завершается ошибкой. Значение по умолчанию: 20,000 (двадцать секунд).

Создает новый объект XMLSocket. Если не указаны никакие параметры, создается первоначально отключенный сокет. Если параметры указаны, производится попытка подключиться к указанному узлу и порту.

Примечание. Настоятельно рекомендуется использовать форму конструктора без параметров, затем добавить любые прослушиватели событий, после чего вызвать метод connect с параметрами host и port. Эта последовательность гарантирует правильную работу всех приемников событий.

Связанные элементы API

Закрывает подключение, заданное объектом XMLSocket. Событие close отправляется только в тот момент, когда сервер закрывает соединение. Оно не отправляется при вызове метода close().

Связанные элементы API

Создает подключение к заданному узлу в Интернете на указанный порт TCP.

Если для параметра host указать значение null, то обращение производится к тому узлу, на котором размещен файл, вызывающий метод XMLSocket.connect(). Например, если вызывающий файл загружен с www.adobe.com, то использование значения null для параметра host указывает на то, что вы подключаетесь к сайту www.adobe.com.

Можно запретить использование файлом этого метода путем установки параметра allowNetworking для тегов object и embed на странице HTML, содержащей SWF-содержимое.

Для получения дополнительной информации см. раздел центра разработчиков Flash Player Безопасность.

Параметры

Связанные элементы API

Преобразует объект XML или данные, заданные параметром object, в строку, за которой следует нулевой байт (0), и передает ее на сервер. Если в качестве object используется XML-объект, строка является представлением XML-объекта в формате XML-текста. Операция отправки проходит в асинхронном режиме. Результат возвращается сразу же, но сами данные могут передаваться чуть позже. Метод XMLSocket.send() не возвращает значение, определяющее, успешно ли прошла передача данных.

Если вы не подключите объект XMLSocket к серверу с помощью XMLSocket.connect()), произойдет сбой операции XMLSocket.send().

Параметры

Связанные элементы API

Отправляется, когда сервер закрывает подключение к сокету. Событие close отправляется только в тот момент, когда сервер закрывает соединение. Оно не отправляется при вызове метода XMLSocket.close().

Это событие имеет следующие свойства:

Отправляется после успешного вызова метода XMLSocket.connect().

Это событие имеет следующие свойства:

Отправляется после отправки или получения необработанных данных.

Это событие имеет следующие свойства:

Отправляется, когда происходит ошибка ввода-вывода, приводящая к сбою операции отправки или получения.

Это событие имеет следующие свойства:

Отправляется, если вызов метода XMLSocket.connect() инициирует попытку подключения к серверу за пределами изолированной среды вызывающего объекта, или к порту с номером, меньшим чем 1024.

Это событие имеет следующие свойства:

Связанные элементы API

1. Конструктор XMLSocketExample создает экземпляр XMLSocket под именем socket и передает значение socket методу ConfigureListeners() (см. описание ниже), а затем вызывает метод connect() XMLSocket, используя имя узла localhost и номер порта 8080.
2. Затем вызывается метод configureListeners(), добавляющий прослушивателей для каждого поддерживаемого события XMLSocket:
   • closeHandler(): находится в ожидании события close, которое отправляется после закрытия сетевого подключения.
   • connectHandler(): находится в ожидании события connect, отправляется при установке сетевого подключения.
   • dataHandler(): находится в ожидании событий data, отправляется каждый раз, когда XMLSocket получает новые данные.
   • progressHandler(): находится в ожидании событий progress, отправляется после вызова send() и в процессе отправки.
   • securityErrorHandler(): находится в ожидании событий securityError, которые отправляются при выявлении попытки доступа к XMLSocket с применением неправильной настройки безопасности локального воспроизведения или при использовании номера порта ниже 1024.
   • ioErrorHandler(): находится в ожидании событий ioError, которые могут возникнуть только при сбое операции по отправке или получению данных.

Примечания.

• SWF-файл требуется откомпилировать с установленным для параметра «Безопасность локального воспроизведения» режимом «Доступ только к сети».
• Для того чтобы этот пример работал, вам необходим сервер, запущенный в вашем домене и использующий порт 8080.
• Если используется Flash Player 9.0.124.0 или более поздняя версия на сервере необходимо поместить файл политик для сокетов, разрешающий для вашего домена подключения к сокетам через порт 8080. Сведения о размещении файлов политик сокетов см. в разделе Центра разработки Flash Player: Setting up a socket policy file server (Настройка сервера с файлом политик для сокетов).

package {
    import flash.display.Sprite;
    import flash.events.*;
    import flash.net.XMLSocket;

    public class XMLSocketExample extends Sprite {
        private var hostName:String = "localhost";
        private var port:uint = 8080;
        private var socket:XMLSocket;

        public function XMLSocketExample() {
            socket = new XMLSocket();
            configureListeners(socket);
            if (hostName && port) {
                socket.connect(hostName, port);
            }
        }

        public function send(data:Object):void {
            socket.send(data);
        }

        private function configureListeners(dispatcher:IEventDispatcher):void {
            dispatcher.addEventListener(Event.CLOSE, closeHandler);
            dispatcher.addEventListener(Event.CONNECT, connectHandler);
            dispatcher.addEventListener(DataEvent.DATA, dataHandler);
            dispatcher.addEventListener(IOErrorEvent.IO_ERROR, ioErrorHandler);
            dispatcher.addEventListener(ProgressEvent.PROGRESS, progressHandler);
            dispatcher.addEventListener(SecurityErrorEvent.SECURITY_ERROR, securityErrorHandler);
        }

        private function closeHandler(event:Event):void {
            trace("closeHandler: " + event);
        }

        private function connectHandler(event:Event):void {
            trace("connectHandler: " + event);
        }

        private function dataHandler(event:DataEvent):void {
            trace("dataHandler: " + event);
        }

        private function ioErrorHandler(event:IOErrorEvent):void {
            trace("ioErrorHandler: " + event);
        }

        private function progressHandler(event:ProgressEvent):void {
            trace("progressHandler loaded:" + event.bytesLoaded + " total: " + event.bytesTotal);
        }

        private function securityErrorHandler(event:SecurityErrorEvent):void {
            trace("securityErrorHandler: " + event);
        }
    }
}