Описание технологического процесса защищенного содержимого

Следующие действия описывают технологический процесс предварительной загрузки ваучера для защищенного файла мультимедиа с использованием объекта DRMContentData.

1. Получите бинарные метаданные для упакованного содержимого. При использовании базового средства упаковки Java Flash Access этот файл метаданных автоматически создается с расширением .metadata. Эти метаданные можно загрузить, к примеру, с помощью класса URLLoader.

2. Создайте объект DRMContentData, передав метаданные функции конструктора:

   var drmData:DRMContentData = new DRMContentData( metadata );

3. Остальные действия аналогичны действиям в технологическом процессе, описанном в разделе «Описание технологического процесса защищенного содержимого».

Следующие действия описывают технологический процесс предварительной загрузки ваучера для DRM-защищенного файла мультимедиа с использованием метода preloadEmbeddedMetadata():

1. Загрузите и сохраните мультимедийный файл. (Метаданные DRM могут быть предварительно загружены только из локально сохраненных файлов.)

2. Создайте объекты NetConnection и NetStream, обеспечив реализацию функций обратного вызова onDRMContentData() и onPlayStatus() в клиентском объекте NetStream.

3. Создайте объект NetStreamPlayOptions и установите в свойстве stream адрес URL для локального мультимедийного файла.

4. Вызовите метод preloadEmbeddedMetadata() класса NetStream, передав ему объект NetStreamPlayOptions, идентифицирующий мультимедийный файл для разбора.

5. Если мультимедийный файл содержит метаданные DRM, то вызывается функция onDRMContentData(). Метаданные передаются этой функции в виде объекта DRMContentData.

6. Используйте объект DRMContentData для получения ваучера с помощью метода loadVoucher() класса DRMManager.

   Если значением свойства authenticationMethod объекта DRMContentData является userNameAndPassword, то перед загрузкой ваучера выполните проверку подлинности пользователя на сервере управления правами на мультимедийное содержимое. Свойства serverURL и domain объекта DRMContentData могут быть переданы методу authenticate() класса DRMManager вместе с учетными данными пользователя.

7. Функция обратного вызова onPlayStatus() вызывается, когда выполнен разбор файла. Если функция onDRMContentData() не была вызвана, то файл не содержит метаданных, требуемых для получения ваучера. То, что функция не была вызвана, также может означать, что этот файл не защищен Flash Access.

Следующий пример кода для среды AIR показывает способ начальной загрузки ваучера для локального файла мультимедиа:

package 
{ 
import flash.display.Sprite; 
import flash.events.DRMAuthenticationCompleteEvent; 
import flash.events.DRMAuthenticationErrorEvent; 
import flash.events.DRMErrorEvent;   
import flash.ev ents.DRMStatusEvent; 
import flash.events.NetStatusEvent; 
import flash.net.NetConnection; 
import flash.net.NetStream; 
import flash.net.NetStreamPlayOptions; 
import flash.net.drm.AuthenticationMethod; 
import flash.net.drm.DRMContentData; 
import flash.net.drm.DRMManager; 
import flash.net.drm.LoadVoucherSetting;   
public class DRMPreloader extends Sprite  
{ 
     private var videoURL:String = "app-storage:/video.flv"; 
    private var userName:String = "user"; 
    private var password:String = "password";  
    private var preloadConnection:NetConnection; 
    private var preloadStream:NetStream; 
    private var drmManager:DRMManager = DRMManager.getDRMManager(); 
    private var drmContentData:DRMContentData; 
    public function DRMPreloader():void { 
        drmManager.addEventListener( 
            DRMAuthenticationCompleteEvent.AUTHENTICATION_COMPLETE, 
            onAuthenticationComplete); 
        drmManager.addEventListener(DRMAuthenticationErrorEvent.AUTHENTICATION_ERROR, 
            onAuthenticationError);             
        drmManager.addEventListener(DRMStatusEvent.DRM_STATUS, onDRMStatus); 
        drmManager.addEventListener(DRMErrorEvent.DRM_ERROR, onDRMError); 
        preloadConnection = new NetConnection(); 
        preloadConnection.addEventListener(NetStatusEvent.NET_STATUS, onConnect); 
        preloadConnection.connect(null);            
    } 
 
    private function onConnect( event:NetStatusEvent ):void 
    { 
        preloadMetadata(); 
    } 
    private function preloadMetadata():void 
    { 
        preloadStream = new NetStream( preloadConnection ); 
        preloadStream.client = this; 
        var options:NetStreamPlayOptions = new NetStreamPlayOptions(); 
        options.streamName = videoURL; 
        preloadStream.preloadEmbeddedData( options );                         
    }     
    public function onDRMContentData( drmMetadata:DRMContentData ):void 
    { 
        drmContentData = drmMetadata; 
        if ( drmMetadata.authenticationMethod == AuthenticationMethod.USERNAME_AND_PASSWORD ) 
        { 
            authenticateUser(); 
        } 
        else 
            { 
                getVoucher(); 
            } 
    } 
    private function getVoucher():void 
    { 
        drmManager.loadVoucher( drmContentData, LoadVoucherSetting.ALLOW_SERVER ); 
    } 
 
    private function authenticateUser():void 
    { 
        drmManager.authenticate( drmContentData.serverURL, drmContentData.domain, userName, password ); 
    } 
    private function onAuthenticationError( event:DRMAuthenticationErrorEvent ):void 
    { 
        trace( "Authentication error: " + event.errorID + ", " + event.subErrorID ); 
    } 
 
    private function onAuthenticationComplete( event:DRMAuthenticationCompleteEvent ):void 
    { 
        trace( "Authenticated to: " + event.serverURL + ", domain: " + event.domain ); 
        getVoucher(); 
    } 
    private function onDRMStatus( event:DRMStatusEvent ):void 
    { 
        trace( "DRM Status: " + event.detail); 
        trace("--Voucher allows offline playback = " + event.isAvailableOffline ); 
        trace("--Voucher already cached          = " + event.isLocal ); 
        trace("--Voucher required authentication = " + !event.isAnonymous ); 
    } 
    private function onDRMError( event:DRMErrorEvent ):void 
    { 
        trace( "DRM error event: " + event.errorID + ", " + event.subErrorID + ", " + event.text ); 
    } 
    public function onPlayStatus( info:Object ):void 
    { 
        preloadStream.close(); 
    } 
} 
}