Использование компонента ComboBox

В следующем примере создается компонент ComboBox с помощью ActionScript и заполняется списком университетов в области Сан-Франциско, Калифорния. Для свойства width экземпляра ComboBox задается достаточное значение, чтобы вместить текст запроса, а свойству dropdownWidth задается значение побольше, чтобы вместить самое длинное название университета.

В примере создается список университетов в экземпляре Array с использованием свойства label для хранения названий учебных заведений и свойства data для хранения URL-адресов их веб-сайтов. Экземпляр Array назначается компоненту ComboBox путем определения его свойства dataProvider .

Когда пользователь выбирает университет из списка, запускается событие Event. CHANGE и функция changeHandler() , которая загружает свойство data в URL-запрос, чтобы открыть веб-сайт учебного заведения.

Обратите внимание на то, что в последней строке свойству selectedIndex экземпляра ComboBox задается значение -1, чтобы после закрытия списка повторно отображался запрос. В противном случае вместо запроса отображалось бы название выбранного учебного заведения.

1. Создайте новый документ Flash (ActionScript 3.0).

2. Перетащите компонент ComboBox с панели «Компоненты» на панель «Библиотека».

3. Откройте панель «Действия», выберите «Кадр 1» на главной временной шкале и введите следующий код ActionScript.

   import fl.controls.ComboBox; 
   import fl.data.DataProvider; 
   import flash.net.navigateToURL; 
    
   var sfUniversities:Array = new Array( 
       {label:"University of California, Berkeley",  
                   data:"http://www.berkeley.edu/"}, 
       {label:"University of San Francisco",  
                   data:"http://www.usfca.edu/"}, 
       {label:"San Francisco State University",  
                   data:"http://www.sfsu.edu/"}, 
       {label:"California State University, East Bay",  
                   data:"http://www.csuhayward.edu/"}, 
       {label:"Stanford University", data:"http://www.stanford.edu/"}, 
       {label:"University of Santa Clara", data:"http://www.scu.edu/"}, 
       {label:"San Jose State University", data:"http://www.sjsu.edu/"} 
   ); 
    
   var aCb:ComboBox = new ComboBox(); 
   aCb.dropdownWidth = 210; 
   aCb.width = 200;  
   aCb.move(150, 50); 
   aCb.prompt = "San Francisco Area Universities"; 
   aCb.dataProvider = new DataProvider(sfUniversities); 
   aCb.addEventListener(Event.CHANGE, changeHandler); 
    
   addChild(aCb); 
    
   function changeHandler(event:Event):void { 
       var request:URLRequest = new URLRequest(); 
       request.url = ComboBox(event.target).selectedItem.data; 
       navigateToURL(request); 
       aCb.selectedIndex = -1; 
   }

4. Выберите «Управление» > «Тестировать ролик».

Этот пример можно реализовать и выполнить в среде разработки Flash, но при попытке открыть веб-сайты университетов щелчком по элементам в экземпляре ComboBox будут появляться предупреждения. Чтобы открыть полностью функциональный компонент ComboBox в Интернете, введите следующий URL-адрес:

http://www.helpexamples.com/peter/bayAreaColleges/bayAreaColleges.html