Использование компонента DataGrid

Использование локального поставщика данных с компонентом DataGrid

В этом примере создается экземпляр DataGrid для отображения состава футбольной команды. Список футболистов определяется в объекте Array ( aRoster ) и назначается свойству dataProvider экземпляра DataGrid.

1. В Flash выберите «Файл» > «Создать», затем выберите «Файл Flash (ActionScript 3.0)».

2. Перетащите компонент DataGrid с панели «Компоненты» в рабочую область.

3. В Инспекторе свойств введите aDg в качестве имени экземпляра.

4. Откройте панель «Действия», выберите «Кадр 1» на главной временной шкале и введите следующий код ActionScript.

   import fl.data.DataProvider; 
    
   bldRosterGrid(aDg); 
   var aRoster:Array = new Array(); 
   aRoster = [ 
           {Name:"Wilma Carter", Bats:"R", Throws:"R", Year:"So", Home: "Redlands, CA"},  
           {Name:"Sue Pennypacker", Bats:"L", Throws:"R", Year:"Fr", Home: "Athens, GA"}, 
           {Name:"Jill Smithfield", Bats:"R", Throws:"L", Year:"Sr", Home: "Spokane, WA"}, 
           {Name:"Shirley Goth", Bats:"R", Throws:"R", Year:"Sr", Home: "Carson, NV"}, 
           {Name:"Jennifer Dunbar", Bats:"R", Throws:"R", Year:"Fr", Home: "Seaside, CA"}, 
           {Name:"Patty Crawford", Bats:"L", Throws:"L", Year:"Jr", Home: "Whittier, CA"}, 
           {Name:"Angelina Davis", Bats:"R", Throws:"R", Year:"So", Home: "Odessa, TX"}, 
           {Name:"Maria Santiago", Bats:"L", Throws:"L", Year:"Sr", Home: "Tacoma, WA"}, 
           {Name:"Debbie Ferguson", Bats:"R", Throws:"R", Year: "Jr", Home: "Bend, OR"}, 
           {Name:"Karen Bronson", Bats:"R", Throws:"R", Year: "Sr", Home: "Billings, MO"}, 
           {Name:"Sylvia Munson", Bats:"R", Throws:"R", Year: "Jr", Home: "Pasadena, CA"}, 
           {Name:"Carla Gomez", Bats:"R", Throws:"L", Year: "Sr", Home: "Corona, CA"}, 
           {Name:"Betty Kay", Bats:"R", Throws:"R", Year: "Fr", Home: "Palo Alto, CA"}, 
   ]; 
   aDg.dataProvider = new DataProvider(aRoster); 
   aDg.rowCount = aDg.length; 
    
   function bldRosterGrid(dg:DataGrid){ 
       dg.setSize(400, 300); 
       dg.columns = ["Name", "Bats", "Throws", "Year", "Home"]; 
       dg.columns[0].width = 120; 
       dg.columns[1].width = 50; 
       dg.columns[2].width = 50; 
       dg.columns[3].width = 40; 
       dg.columns[4].width = 120; 
       dg.move(50,50); 
   };

   Функция bldRosterGrid() задает размер экземпляра DataGrid, а также порядок и размеры столбцов.

5. Выберите «Управление» > «Тестировать ролик».

Определение столбцов и добавление сортировки для компонента DataGrid в приложении

Обратите внимание, что для сортировки содержимого столбца DataGrid в нисходящем порядке значений, нужно щелкнуть заголовок нужного столбца.

В следующем примере метод addColumn() используется для добавления экземпляров DataGridColumn в компонент DataGrid. В столбцах содержатся имена футболистов и набранные ими очки. В примере также задается свойство sortOptions , чтобы определить параметры сортировки для каждого столбца: Array.CASEINSENSITIVE для столбца «Имя» и Array.NUMERIC для столбца «Очки». Чтобы задать соответствующий размер экземпляру DataGrid, длина определяется по количеству строк, а ширина равна 200.

1. В Flash выберите «Файл» > «Создать», затем выберите «Файл Flash (ActionScript 3.0)».

2. Перетащите компонент DataGrid с панели «Компоненты» в рабочую область.

3. В Инспекторе свойств введите aDg в качестве имени экземпляра.

4. Откройте панель «Действия», выберите «Кадр 1» на главной временной шкале и введите следующий код ActionScript.

   import fl.controls.dataGridClasses.DataGridColumn; 
   import fl.events.DataGridEvent; 
   import fl.data.DataProvider; 
   // Create columns to enable sorting of data. 
   var nameDGC:DataGridColumn = new DataGridColumn("name"); 
   nameDGC.sortOptions = Array.CASEINSENSITIVE; 
   var scoreDGC:DataGridColumn = new DataGridColumn("score"); 
   scoreDGC.sortOptions = Array.NUMERIC; 
   aDg.addColumn(nameDGC); 
   aDg.addColumn(scoreDGC); 
   var aDP_array:Array = new Array({name:"clark", score:3135}, {name:"Bruce", score:403}, {name:"Peter", score:25}) 
   aDg.dataProvider = new DataProvider(aDP_array); 
   aDg.rowCount = aDg.length; 
   aDg.width = 200;

5. Выберите «Управление» > «Тестировать ролик».

Создание экземпляра компонента DataGrid с помощью ActionScript

В этом примере создается экземпляр DataGrid с помощью ActionScript и заполняется объектом Array с именами и очками футболистов.

1. Создайте новый документ Flash (ActionScript 3.0).

2. Перетащите компонент DataGrid с панели «Компоненты» на панель «Библиотека» текущего документа.

   В результате этого компонент добавляется в библиотеку, но остается невидимым в приложении.

3. Откройте панель «Действия», выберите «Кадр 1» на главной временной шкале и введите следующий код ActionScript.

   import fl.controls.DataGrid; 
   import fl.data.DataProvider; 
    
   var aDg:DataGrid = new DataGrid(); 
   addChild(aDg); 
   aDg.columns = [ "Name", "Score" ]; 
   aDg.setSize(140, 100); 
   aDg.move(10, 40);

   Этот код создает экземпляр DataGrid, после чего задает размер и местоположение сетки.

4. Создайте массив, добавьте в него данные и укажите его в качестве поставщика данных для экземпляра DataGrid.

   var aDP_array:Array = new Array(); 
   aDP_array.push({Name:"Clark", Score:3135}); 
   aDP_array.push({Name:"Bruce", Score:403}); 
   aDP_array.push({Name:"Peter", Score:25}); 
   aDg.dataProvider = new DataProvider(aDP_array); 
   aDg.rowCount = aDg.length;

5. Выберите «Управление» > «Тестировать ролик».

Заполнение экземпляра DataGrid XML-файлом

В следующем примере используется класс DataGridColumn для создания столбцов DataGrid. Экземпляр DataGrid заполняется путем передачи объекта XML в качестве параметра value конструктора DataProvider() .

1. В текстовом редакторе создайте файл XML со следующими данными и сохраните его как файл team.xml в той же папке, в которой сохранен FLA-файл.

   <team> 
       <player name="Player A" avg="0.293" /> 
       <player name="Player B" avg="0.214" /> 
       <player name="Player C" avg="0.317" /> 
   </team>

2. Создайте новый документ Flash (ActionScript 3.0).

3. На панели «Компоненты» дважды щелкните DataGrid, чтобы добавить экземпляр в рабочую область.

4. В Инспекторе свойств введите aDg в качестве имени экземпляра.

5. Откройте панель «Действия», выберите «Кадр 1» на главной временной шкале и введите следующий код ActionScript.

   import fl.controls.dataGridClasses.DataGridColumn; 
   import fl.data.DataProvider; 
   import flash.net.*; 
   import flash.events.*; 
    
   var request:URLRequest = new URLRequest("team.xml"); 
   var loader:URLLoader = new URLLoader; 
    
    
   loader.load(request); 
   loader.addEventListener(Event.COMPLETE, loaderCompleteHandler); 
    
   function loaderCompleteHandler(event:Event):void { 
    
       var teamXML:XML = new XML(loader.data); 
    
       var nameCol:DataGridColumn = new DataGridColumn("name"); 
       nameCol.headerText = "Name"; 
       nameCol.width = 120; 
       var avgCol:DataGridColumn = new DataGridColumn("avg"); 
       avgCol.headerText = "Average"; 
       avgCol.width = 60; 
        
       var myDP:DataProvider = new DataProvider(teamXML); 
        
       aDg.columns = [nameCol, avgCol]; 
       aDg.width = 200; 
       aDg.dataProvider = myDP; 
       aDg.rowCount = aDg.length; 
   }

6. Выберите «Управление» > «Тестировать ролик».