Inicialização de variáveis XML

Flash Player 9 e posterior, Adobe AIR 1.0 e posterior

Você pode atribuir um literal XML a um objeto XML do seguinte modo:

var myXML:XML =  
    <order> 
        <item id='1'> 
            <menuName>burger</menuName> 
            <price>3.95</price> 
        </item> 
        <item id='2'> 
            <menuName>fries</menuName> 
            <price>1.45</price> 
        </item> 
    </order>

Como mostra o snippet a seguir, também é possível usar o construtor new para criar uma ocorrência de um objeto XML a partir de uma string que contém dados XML:

var str:String = "<order><item id='1'><menuName>burger</menuName>" 
                            + "<price>3.95</price></item></order>"; 
var myXML:XML = new XML(str);

Se os dados XML da string não estiverem bem formados (por exemplo, se estiver faltando uma tag de fechamento), ocorrerá um erro de tempo de execução.

Você também pode transmitir os dados por referência (de outras variáveis) em um objeto XML, como mostra o exemplo a seguir:

var tagname:String = "item";  
var attributename:String = "id";  
var attributevalue:String = "5";  
var content:String = "Chicken";  
var x:XML = <{tagname} {attributename}={attributevalue}>{content}</{tagname}>;  
trace(x.toXMLString()) 
    // Output: <item id="5">Chicken</item>

Para carregar os dados XML a partir de uma URL, use a classe URLLoader, como mostra o exemplo a seguir:

import flash.events.Event; 
import flash.net.URLLoader; 
import flash.net.URLRequest; 
 
var externalXML:XML; 
var loader:URLLoader = new URLLoader(); 
var request:URLRequest = new URLRequest("xmlFile.xml"); 
loader.load(request); 
loader.addEventListener(Event.COMPLETE, onComplete); 
 
function onComplete(event:Event):void 
{ 
    var loader:URLLoader = event.target as URLLoader; 
    if (loader != null) 
    { 
        externalXML = new XML(loader.data); 
        trace(externalXML.toXMLString()); 
    } 
    else 
    { 
        trace("loader is not a URLLoader!"); 
    } 
}

Para ler dados XML a partir de uma conexão de soquete, use a classe XMLSocket. Para obter mais informações, consulte a classe XMLSocket na Referência do ActionScript® 3.0 para Adobe® Flash® Platform .