Criação de métodos de retorno de chamada para metadados e pontos de sinalização

Ao definir a propriedade client como Object ou uma subclasse de NetStream, você pode redirecionar os métodos de retorno de chamada onMetaData e onCuePoint ou ignorá-los completamente. O exemplo a seguir demonstra como usar um Object vazio para ignorar os métodos de retorno de chamada sem monitorar o evento asyncError :

var nc:NetConnection = new NetConnection(); 
nc.connect(null); 
 
var customClient:Object = new Object(); 
 
var ns:NetStream = new NetStream(nc); 
ns.client = customClient; 
ns.play("video.flv"); 
 
var vid:Video = new Video(); 
vid.attachNetStream(ns); 
addChild(vid);

Para monitorar os métodos de retorno de chamada onMetaData ou onCuePoint , seria preciso definir métodos para manipular esses métodos de retorno de chamada, conforme mostrado no seguinte snippet:

var customClient:Object = new Object(); 
customClient.onMetaData = metaDataHandler; 
function metaDataHandler(infoObject:Object):void 
{ 
    trace("metadata"); 
}

O código anterior monitora o método de retorno de chamada onMetaData e chama o método metaDataHandler() , que rastreia uma string. Se o tempo de execução do Flash encontrasse um ponto de sinalização, nenhum erro seria gerado, mesmo que não tenha sido definido um método de retorno de chamada onCuePoint .

O seguinte código define a propriedade client do objeto NetStream como uma classe personalizada, CustomClient, que define manipuladores para os métodos de retorno de chamada:

var nc:NetConnection = new NetConnection(); 
nc.connect(null); 
 
var ns:NetStream = new NetStream(nc); 
ns.client = new CustomClient(); 
ns.play("video.flv"); 
 
var vid:Video = new Video(); 
vid.attachNetStream(ns); 
addChild(vid);

Esta é a classe CustomClient:

package 
{ 
    public class CustomClient 
    { 
        public function onMetaData(infoObject:Object):void 
        { 
            trace("metadata"); 
        } 
    } 
}

A classe CustomClient define um manipulador para o manipulador de retorno de chamada onMetaData . Se fosse encontrado um ponto de sinalização e o manipulador de retorno de chamada onCuePoint fosse chamado, seria despachado um evento asyncError ( AsyncErrorEvent.ASYNC_ERROR ) informando que flash.net.NetStream não pôde chamar o manipulador de retorno de chamada onCuePoint. Para evitar esse erro, seria necessário definir um método de retorno de chamada onCuePoint na classe CustomClient ou definir um manipulador de eventos para o evento asyncError .

O código abaixo cria uma ocorrência da classe CustomNetStream, que é definida em uma listagem de código mais adiante:

var ns:CustomNetStream = new CustomNetStream(); 
ns.play("video.flv"); 
 
var vid:Video = new Video(); 
vid.attachNetStream(ns); 
addChild(vid);

A seguinte listagem de código define a classe CustomNetStream que estende a classe NetStream, manipula a criação do objeto NetConnection necessário e manipula os métodos de manipulador de retorno de chamada onMetaData e onCuePoint :

package 
{ 
    import flash.net.NetConnection; 
    import flash.net.NetStream; 
    public class CustomNetStream extends NetStream 
    { 
        private var nc:NetConnection; 
        public function CustomNetStream() 
        { 
            nc = new NetConnection(); 
            nc.connect(null); 
            super(nc); 
        } 
        public function onMetaData(infoObject:Object):void 
        { 
            trace("metadata"); 
        } 
        public function onCuePoint(infoObject:Object):void 
        { 
            trace("cue point"); 
        } 
    } 
}

Para renomear os métodos onMetaData() e onCuePoint() na classe CustomNetStream, use o seguinte código:

package 
{ 
    import flash.net.NetConnection; 
    import flash.net.NetStream; 
    public class CustomNetStream extends NetStream 
    { 
        private var nc:NetConnection; 
        public var onMetaData:Function; 
        public var onCuePoint:Function; 
        public function CustomNetStream() 
        { 
            onMetaData = metaDataHandler; 
            onCuePoint = cuePointHandler; 
            nc = new NetConnection(); 
            nc.connect(null); 
            super(nc); 
        } 
        private function metaDataHandler(infoObject:Object):void 
        { 
            trace("metadata"); 
        } 
        private function cuePointHandler(infoObject:Object):void 
        { 
            trace("cue point"); 
        } 
    } 
}

É possível estender a classe NetStream e tornar a subclasse dinâmica para que os manipuladores de retorno de chamada onCuePoint e onMetaData possam ser adicionados dinamicamente. Isso é demonstrado na listagem a seguir:

var ns:DynamicCustomNetStream = new DynamicCustomNetStream(); 
ns.play("video.flv"); 
 
var vid:Video = new Video(); 
vid.attachNetStream(ns); 
addChild(vid);

Esta é a classe DynamicCustomNetStream:

package 
{ 
    import flash.net.NetConnection; 
    import flash.net.NetStream; 
    public dynamic class DynamicCustomNetStream extends NetStream 
    { 
        private var nc:NetConnection; 
        public function DynamicCustomNetStream() 
        { 
            nc = new NetConnection(); 
            nc.connect(null); 
            super(nc); 
        } 
    } 
}

Mesmo sem manipuladores para os manipuladores de retorno de chamada onMetaData e onCuePoint , não são gerados erros porque a classe DynamicCustomNetStream é dinâmica. Para definir métodos para os manipuladores de retorno de chamada onMetaData e onCuePoint , use o seguinte código:

var ns:DynamicCustomNetStream = new DynamicCustomNetStream(); 
ns.onMetaData = metaDataHandler; 
ns.onCuePoint = cuePointHandler; 
ns.play("http://www.helpexamples.com/flash/video/cuepoints.flv"); 
 
var vid:Video = new Video(); 
vid.attachNetStream(ns); 
addChild(vid); 
 
function metaDataHandler(infoObject:Object):void 
{ 
    trace("metadata"); 
} 
function cuePointHandler(infoObject:Object):void 
{ 
    trace("cue point"); 
}

Quando se define a propriedade client como this , o aplicativo procura os métodos onMetaData() e onCuePoint() no escopo atual. Este exemplo demonstra isso:

var nc:NetConnection = new NetConnection(); 
nc.connect(null); 
 
var ns:NetStream = new NetStream(nc); 
ns.client = this; 
ns.play("video.flv"); 
 
var vid:Video = new Video(); 
vid.attachNetStream(ns); 
addChild(vid);

Se os manipuladores de retorno de chamada onMetaData ou onCuePoint são chamados e não existem métodos para manipular o retorno de chamada, nenhum erro é gerado. Para manipular esses manipuladores de retorno de chamada, crie um método onMetaData() e onCuePoint() no seu código, como visto no snippet abaixo:

function onMetaData(infoObject:Object):void 
{ 
    trace("metadata"); 
} 
function onCuePoint(infoObject:Object):void 
{ 
    trace("cue point"); 
}