Entendendo o fluxo de trabalho de conteúdo protegido.

Os passos a seguir descrevem o fluxo de trabalho para pré-carregar o voucher para um arquivo de mídia protegido utilizando um objeto DRMContentData.

1. Obtenha os metadados binários para o conteúdo empacotado. Caso esteja utilizando o Java Reference Packager do Flash Access, este arquivo metadados é automaticamente gerado com uma extensão .metadata. Por exemplo, é possível fazer o download destes metadados utilizando a classe URLLoader.

2. Crie um objeto DRMContentData passando os metadados para a função do construtor:

   var drmData:DRMContentData = new DRMContentData( metadata );

3. O restante dos passos são idênticos ao fluxo de trabalho do Entendendo o fluxo de trabalho de conteúdo protegido..

As etapas a seguir descrevem o fluxo de trabalho para pré-carregar o voucher de um arquivo de mídia protegido por DRM utilizando preloadEmbeddedMetadata():

1. Baixe e armazene o arquivo de mídia. (Metadados DRM só podem ser pré-carregados de arquivos armazenados localmente.)

2. Crie os objetos NetConnection e NetStream, fornecendo implementações para as funções de retorno de chamada onDRMContentData() e onPlayStatus() do objeto cliente NetStream.

3. Crie um objeto NetStreamPlayOptions e defina a propriedade stream para a URL do arquivo de mídia local.

4. Chame o NetStream preloadEmbeddedMetadata(), passando no objeto NetStreamPlayOptions que identifica o arquivo de mídia que será analisado.

5. Se o arquivo de mídia contiver metadados DRM, a função de retorno de chamada onDRMContentData() será chamada. Os metadados são transmitidos a essa função como objeto DRMContentData.

6. Use o objeto DRMContentData para obter o voucher usando o método loadVoucher() do DRMManager.

   Se o valor da propriedade authenticationMethod do objeto DRMContentData for userNameAndPassword, você deverá autenticar o usuário no servidor de direitos de mídia antes de carregar o voucher. As propriedades serverURL e domain do objeto DRMContentData podem ser passadas para o método authenticate() do DRMManager, juntamente com as credenciais do usuário.

7. A função de retorno de chamada onPlayStatus() é chamada após a conclusão da análise do arquivo. Se a função onDRMContentData() não tiver sido chamada, o arquivo não conterá os metadados necessários para obter um voucher. Esta chamada ausente também pode significar que o Flash Access não protege este arquivo.

O exemplo de código para o AIR a seguir ilustra como pré-carregar um voucher para um arquivo de mídia local:

package 
{ 
import flash.display.Sprite; 
import flash.events.DRMAuthenticationCompleteEvent; 
import flash.events.DRMAuthenticationErrorEvent; 
import flash.events.DRMErrorEvent;   
import flash.ev ents.DRMStatusEvent; 
import flash.events.NetStatusEvent; 
import flash.net.NetConnection; 
import flash.net.NetStream; 
import flash.net.NetStreamPlayOptions; 
import flash.net.drm.AuthenticationMethod; 
import flash.net.drm.DRMContentData; 
import flash.net.drm.DRMManager; 
import flash.net.drm.LoadVoucherSetting;   
public class DRMPreloader extends Sprite  
{ 
     private var videoURL:String = "app-storage:/video.flv"; 
    private var userName:String = "user"; 
    private var password:String = "password";  
    private var preloadConnection:NetConnection; 
    private var preloadStream:NetStream; 
    private var drmManager:DRMManager = DRMManager.getDRMManager(); 
    private var drmContentData:DRMContentData; 
    public function DRMPreloader():void { 
        drmManager.addEventListener( 
            DRMAuthenticationCompleteEvent.AUTHENTICATION_COMPLETE, 
            onAuthenticationComplete); 
        drmManager.addEventListener(DRMAuthenticationErrorEvent.AUTHENTICATION_ERROR, 
            onAuthenticationError);             
        drmManager.addEventListener(DRMStatusEvent.DRM_STATUS, onDRMStatus); 
        drmManager.addEventListener(DRMErrorEvent.DRM_ERROR, onDRMError); 
        preloadConnection = new NetConnection(); 
        preloadConnection.addEventListener(NetStatusEvent.NET_STATUS, onConnect); 
        preloadConnection.connect(null);            
    } 
 
    private function onConnect( event:NetStatusEvent ):void 
    { 
        preloadMetadata(); 
    } 
    private function preloadMetadata():void 
    { 
        preloadStream = new NetStream( preloadConnection ); 
        preloadStream.client = this; 
        var options:NetStreamPlayOptions = new NetStreamPlayOptions(); 
        options.streamName = videoURL; 
        preloadStream.preloadEmbeddedData( options );                         
    }     
    public function onDRMContentData( drmMetadata:DRMContentData ):void 
    { 
        drmContentData = drmMetadata; 
        if ( drmMetadata.authenticationMethod == AuthenticationMethod.USERNAME_AND_PASSWORD ) 
        { 
            authenticateUser(); 
        } 
        else 
            { 
                getVoucher(); 
            } 
    } 
    private function getVoucher():void 
    { 
        drmManager.loadVoucher( drmContentData, LoadVoucherSetting.ALLOW_SERVER ); 
    } 
 
    private function authenticateUser():void 
    { 
        drmManager.authenticate( drmContentData.serverURL, drmContentData.domain, userName, password ); 
    } 
    private function onAuthenticationError( event:DRMAuthenticationErrorEvent ):void 
    { 
        trace( "Authentication error: " + event.errorID + ", " + event.subErrorID ); 
    } 
 
    private function onAuthenticationComplete( event:DRMAuthenticationCompleteEvent ):void 
    { 
        trace( "Authenticated to: " + event.serverURL + ", domain: " + event.domain ); 
        getVoucher(); 
    } 
    private function onDRMStatus( event:DRMStatusEvent ):void 
    { 
        trace( "DRM Status: " + event.detail); 
        trace("--Voucher allows offline playback = " + event.isAvailableOffline ); 
        trace("--Voucher already cached          = " + event.isLocal ); 
        trace("--Voucher required authentication = " + !event.isAnonymous ); 
    } 
    private function onDRMError( event:DRMErrorEvent ):void 
    { 
        trace( "DRM error event: " + event.errorID + ", " + event.subErrorID + ", " + event.text ); 
    } 
    public function onPlayStatus( info:Object ):void 
    { 
        preloadStream.close(); 
    } 
} 
}