API no navegador AIR.SWF

Além de usar o arquivo badge.swf fornecido com o SDK, você pode criar seu próprio arquivo SWF para usar em uma página do navegador. Seu arquivo SWF personalizado pode interagir com o runtime das seguintes maneiras:

• Ele pode instalar um aplicativo do AIR. Consulte Instalação de um aplicativo do AIR do navegador .

• Ele pode verificar se um aplicativo do AIR específico está instalado. Consulte Verificar por uma página da Web se um aplicativo do AIR está instalado .

• Ele pode verificar se o runtime está instalado. Consulte Verificar se o runtime está instalado .

• Ele pode iniciar um aplicativo do AIR instalado no sistema do usuário. Consulte Inicialização de um aplicativo do AIR instalado do navegador .

Esses recursos são todos fornecidos ao chamar as APIs em um arquivo SWF hospedado em adobe.com: air.swf. Você pode personalizar o arquivo badge.swf e chamar as APIs air.swf a partir do seu próprio arquivo SWF.

Além disso, um arquivo SWF em execução no navegador pode se comunicar com um aplicativo do AIR em execução usando a classe LocalConnection. Para mais informações, consulte Comunicação com outras instâncias do Flash Player e AIR (para desenvolvedores em ActionScript) ou Communicating with other Flash Player and AIR instances (para desenvolvedores em HTML).

Incluído no SDK do AIR e no SDK do Flex está um arquivo badge.swf, que permite usar facilmente o recurso de instalação direta. O badge.swf pode instalar o runtime e um aplicativo do AIR de um link em uma página da Web. O arquivo badge.swf e seu código-fonte são fornecidos a você para distribuição no seu site da Web.

Você pode criar seu próprio arquivo do SWF que usa as APIs no arquivo air.swf para interagir com o runtime e aplicativos do AIR de uma página da Web em um navegador. O arquivo air.swf é hospedado em http://airdownload.adobe.com/air/browserapi/air.swf. Para se referir às APIs do air.swf do seu arquivo SWF, carregue o arquivo air.swf no mesmo domínio de aplicativo do seu arquivo SWF. O código a seguir mostra um exemplo de como carregar o arquivo air.swf no domínio do aplicativo do arquivo SWF que está sendo carregado:

var airSWF:Object; // This is the reference to the main class of air.swf 
var airSWFLoader:Loader = new Loader(); // Used to load the SWF 
var loaderContext:LoaderContext = new LoaderContext();  
                                // Used to set the application domain  
 
loaderContext.applicationDomain = ApplicationDomain.currentDomain; 
 
airSWFLoader.contentLoaderInfo.addEventListener(Event.INIT, onInit); 
airSWFLoader.load(new URLRequest("http://airdownload.adobe.com/air/browserapi/air.swf"),  
                    loaderContext); 
 
function onInit(e:Event):void  
{ 
    airSWF = e.target.content; 
}

Depois que o arquivo air.swf estiver carregado (quando o objeto Loader do objeto contentLoaderInfo enviar o evento init ), você pode chamar APIs air.swf, descritas nas seções que seguem.

Um arquivo SWF pode verificar se o runtime está instalado chamando o método getStatus( ) no arquivo air.swf carregado de http://airdownload.adobe.com/air/browserapi/air.swf. Para obter detalhes, consulte Carregar o arquivo air.swf .

Depois que o arquivo air.swf for carregado, o arquivo SWF poderá chamar o método getStatus( ) do arquivo air.swf como a seguir:

var status:String = airSWF.getStatus();

O método getStatus() retorna um dos seguintes valores de sequências de caracteres, com base no status do runtime no computador:

O método getStatus() lança um erro se a versão necessária do Flash Player (versão 9 atualização 3 ou posterior no Windows e Mac OS ou versão 10 no Linux) não estiver instalada no navegador.

Um arquivo SWF pode verificar se um aplicativo do AIR (com um ID de aplicativo e um ID de editor correspondentes) está instalado chamando o método getApplicationVersion( ) no arquivo air.swf carregado de http://airdownload.adobe.com/air/browserapi/air.swf. Para obter detalhes, consulte Carregar o arquivo air.swf .

Depois que o arquivo air.swf for carregado, o arquivo SWF poderá chamar o método getApplicationVersion( ) do arquivo air.swf como a seguir:

var appID:String = "com.example.air.myTestApplication"; 
var pubID:String = "02D88EEED35F84C264A183921344EEA353A629FD.1"; 
airSWF.getApplicationVersion(appID, pubID, versionDetectCallback); 
 
function versionDetectCallback(version:String):void 
{ 
    if (version == null) 
    { 
        trace("Not installed."); 
        // Take appropriate actions. For instance, present the user with 
        // an option to install the application. 
    } 
    else 
    { 
        trace("Version", version, "installed."); 
        // Take appropriate actions. For instance, enable the 
        // user interface to launch the application. 
    } 
}

O método getApplicationVersion() possui os seguintes parâmetros:

O método getApplicationVersion() lança um erro se a versão necessária do Flash Player (versão 9 atualização 3 ou posterior no Windows e Mac OS ou versão 10 no Linux) não estiver instalada no navegador.

Um arquivo SWF pode instalar um aplicativo do AIR chamando o método installApplication( ) no arquivo air.swf carregado de http://airdownload.adobe.com/air/browserapi/air.swf . Para obter detalhes, consulte Carregar o arquivo air.swf .

Depois que o arquivo air.swf for carregado, o arquivo SWF poderá chamar o método installApplication( ) do arquivo air.swf como no código a seguir:

var url:String = "http://www.example.com/myApplication.air"; 
var runtimeVersion:String = "1.0"; 
var arguments:Array = ["launchFromBrowser"]; // Optional 
airSWF.installApplication(url, runtimeVersion, arguments); 

O método installApplication() instala o aplicativo especificado na máquina do usuário. Esse método possui os seguintes parâmetros:

O método installApplication() pode operar apenas quando chamado no manipulador de eventos para um evento do usuário, como um clique do mouse.

O método installApplication() lança um erro se a versão necessária do Flash Player (versão 9 atualização 3 ou posterior no Windows e Mac OS ou versão 10 no Linux) não estiver instalada no navegador.

No Mac OS, para instalar uma versão atualizada de um aplicativo, o usuário precisa ter privilégios adequados do sistema para instalar no diretório do aplicativo (e privilégios administrativos se o aplicativo atualizar o runtime). No Windows, o usuário deve ter privilégios administrativos.

Você também pode chamar o método getApplicationVersion() do arquivo air.swf para verificar se um aplicativo já está instalado. Você pode chamar esse método antes que o processo de instalação do aplicativo seja iniciado ou após a instalação ser iniciada. Para obter detalhes, consulte Verificar por uma página da Web se um aplicativo do AIR está instalado . Depois que o aplicativo estiver em execução, ele pode se comunicar com o conteúdo do SWF no navegador usando a classe LocalConnection. Para mais informações, consulte Comunicação com outras instâncias do Flash Player e AIR (para desenvolvedores em ActionScript) ou Communicating with other Flash Player and AIR instances (para desenvolvedores em HTML).

Para usar o recurso de invocação do navegador (permitindo que ele seja iniciado do navegador), o arquivo do descritor do aplicativo de destino deve incluir a seguinte configuração:

<allowBrowserInvocation>true</allowBrowserInvocation>

Para obter mais informações sobre o arquivo do descritor do aplicativo, consulte Arquivos descritores do aplicativo do AIR .

Um arquivo SWF no navegador pode iniciar um aplicativo do AIR chamando o método launchApplication( ) no arquivo air.swf carregado de http://airdownload.adobe.com/air/browserapi/air.swf. Para obter detalhes, consulte Carregar o arquivo air.swf .

Depois que o arquivo air.swf for carregado, o arquivo SWF poderá chamar o método launchApplication( ) do arquivo air.swf como no código a seguir:

var appID:String = "com.example.air.myTestApplication"; 
var pubID:String = "02D88EEED35F84C264A183921344EEA353A629FD.1"; 
var arguments:Array = ["launchFromBrowser"]; // Optional 
airSWF.launchApplication(appID, pubID, arguments);

O método launchApplication() é definido no nível superior do arquivo air.swf (carregado no domínio do aplicativo do arquivo SWF da interface do usuário). Chamar esse método faz com que o AIR inicie o aplicativo especificado (se ele for instalado e a invocação do navegador for permitida, pela configuração allowBrowserInvocation no arquivo do descritor do aplicativo). O método tem os seguintes parâmetros:

O método launchApplication() pode operar apenas quando chamado no manipulador de eventos para um evento do usuário, como um clique do mouse.

O método launchApplication() lança um erro se a versão necessária do Flash Player (versão 9 atualização 3 ou posterior no Windows e Mac OS ou versão 10 no Linux) não estiver instalada no navegador.

Se o elemento allowBrowserInvocation for definido como false no arquivo do descritor do aplicativo, chamar o método launchApplication() não terá efeito.

Antes de apresentar a interface do usuário para iniciar o aplicativo, você pode desejar chamar o método getApplicationVersion( ) no arquivo air.swf. Para obter detalhes, consulte Verificar por uma página da Web se um aplicativo do AIR está instalado .

Quando o aplicativo é invocado pelo recurso de invocação do navegador, o objeto NativeApplication do aplicativo despacha um objeto BrowserInvokeEvent. Para obter detalhes, consulte Invocação de um aplicativo do AIR do navegador (para desenvolvedores em ActionScript) ou Invoking an AIR application from the browser (para desenvolvedores em HTML).

Se você usa o recurso de invocação do navegador, certifique-se de considerar implicações de segurança. Estas implicações são descrita em Invocação de um aplicativo do AIR do navegador (para desenvolvedores em ActionScript) e Invoking an AIR application from the browser (para desenvolvedores em HTML).

Depois que o aplicativo estiver em execução, ele pode se comunicar com o conteúdo do SWF no navegador usando a classe LocalConnection. Para mais informações, consulte Comunicação com outras instâncias do Flash Player e AIR (para desenvolvedores em ActionScript) ou Communicating with other Flash Player and AIR instances (para desenvolvedores em HTML).