Wyjaśnienie obiegu pracy chronionych treści

W poniższej procedurze przedstawiono obieg pracy wstępnego ładowania kuponu dla chronionego pliku multimedialnego z wykorzystaniem obiektu DRMContentData.

1. Pobierz binarne metadane dla spakowanych treści. W przypadku korzystania z programu Flash Access Java Reference Packager ten plik zostanie automatycznie wygenerowany z rozszerzeniem .metadata. Metadane można np. pobrać za pomocą klasy URLLoader.

2. Utwórz obiekt DRMContentData, przekazując metadane do konstruktora:

   var drmData:DRMContentData = new DRMContentData( metadata );

3. Pozostałe kroki są takie same, jak te przedstawione w obiegu pracy opisanym w części Wyjaśnienie obiegu pracy chronionych treści.

Poniżej przedstawiono kolejne etapy procedury wstępnego ładowania kuponu dla pliku multimedialnego chronionego mechanizmem DRM z wykorzystaniem obiektu preloadEmbeddedMetadata():

1. Pobierz i zapisz plik multimedialny. (Metadane DRM można wstępnie ładować wyłącznie z plików zapisanych lokalnie).

2. Utwórz obiekty NetConnection i NetStream, tworząc implementacje funkcji wywołania zwrotnego onDRMContentData() i onPlayStatus() w obiekcie klienckim NetStream.

3. Utwórz obiekt NetStreamPlayOptions i przypisz właściwości stream adres URL lokalnego pliku multimedialnego.

4. Wywołaj metodę preloadEmbeddedMetadata() obiektu NetStream, przekazując do niej obiekt NetStreamPlayOptions wskazujący plik multimedialny do przeanalizowania.

5. Jeśli plik multimedialny zawiera metadane DRM, wywoływana jest funkcja wywołania zwrotnego onDRMContentData(). Metadane są przekazywane do tej funkcji jako obiekt DRMContentData.

6. Użyj obiektu DRMContentData do uzyskania kuponu, korzystając z metody loadVoucher() klasy DRMManager.

   Jeśli właściwość authenticationMethod obiektu DRMContentData ma wartość userNameAndPassword, należy uwierzytelnić użytkownika na serwerze zarządzania uprawnieniami przed załadowaniem kuponu. Właściwości serverURL i domain obiektu DRMContentData można przekazać do metody authenticate() klasy DRMManager razem z poświadczeniami użytkownika.

7. Po zakończeniu analizowania pliku wywoływana jest funkcja wywołania zwrotnego onPlayStatus(). Jeśli funkcja onDRMContentData() nie została wywołana, plik nie zawiera metadanych potrzebnych do uzyskania kuponu. Ten brak wywołania może także oznaczać, że moduł Flash Access nie chroni tego pliku.

Poniższy przykładowy kod dla środowiska AIR ilustruje sposób wstępnego ładowania kuponu dla lokalnego pliku multimedialnego:

package 
{ 
import flash.display.Sprite; 
import flash.events.DRMAuthenticationCompleteEvent; 
import flash.events.DRMAuthenticationErrorEvent; 
import flash.events.DRMErrorEvent;   
import flash.ev ents.DRMStatusEvent; 
import flash.events.NetStatusEvent; 
import flash.net.NetConnection; 
import flash.net.NetStream; 
import flash.net.NetStreamPlayOptions; 
import flash.net.drm.AuthenticationMethod; 
import flash.net.drm.DRMContentData; 
import flash.net.drm.DRMManager; 
import flash.net.drm.LoadVoucherSetting;   
public class DRMPreloader extends Sprite  
{ 
     private var videoURL:String = "app-storage:/video.flv"; 
    private var userName:String = "user"; 
    private var password:String = "password";  
    private var preloadConnection:NetConnection; 
    private var preloadStream:NetStream; 
    private var drmManager:DRMManager = DRMManager.getDRMManager(); 
    private var drmContentData:DRMContentData; 
    public function DRMPreloader():void { 
        drmManager.addEventListener( 
            DRMAuthenticationCompleteEvent.AUTHENTICATION_COMPLETE, 
            onAuthenticationComplete); 
        drmManager.addEventListener(DRMAuthenticationErrorEvent.AUTHENTICATION_ERROR, 
            onAuthenticationError);             
        drmManager.addEventListener(DRMStatusEvent.DRM_STATUS, onDRMStatus); 
        drmManager.addEventListener(DRMErrorEvent.DRM_ERROR, onDRMError); 
        preloadConnection = new NetConnection(); 
        preloadConnection.addEventListener(NetStatusEvent.NET_STATUS, onConnect); 
        preloadConnection.connect(null);            
    } 
 
    private function onConnect( event:NetStatusEvent ):void 
    { 
        preloadMetadata(); 
    } 
    private function preloadMetadata():void 
    { 
        preloadStream = new NetStream( preloadConnection ); 
        preloadStream.client = this; 
        var options:NetStreamPlayOptions = new NetStreamPlayOptions(); 
        options.streamName = videoURL; 
        preloadStream.preloadEmbeddedData( options );                         
    }     
    public function onDRMContentData( drmMetadata:DRMContentData ):void 
    { 
        drmContentData = drmMetadata; 
        if ( drmMetadata.authenticationMethod == AuthenticationMethod.USERNAME_AND_PASSWORD ) 
        { 
            authenticateUser(); 
        } 
        else 
            { 
                getVoucher(); 
            } 
    } 
    private function getVoucher():void 
    { 
        drmManager.loadVoucher( drmContentData, LoadVoucherSetting.ALLOW_SERVER ); 
    } 
 
    private function authenticateUser():void 
    { 
        drmManager.authenticate( drmContentData.serverURL, drmContentData.domain, userName, password ); 
    } 
    private function onAuthenticationError( event:DRMAuthenticationErrorEvent ):void 
    { 
        trace( "Authentication error: " + event.errorID + ", " + event.subErrorID ); 
    } 
 
    private function onAuthenticationComplete( event:DRMAuthenticationCompleteEvent ):void 
    { 
        trace( "Authenticated to: " + event.serverURL + ", domain: " + event.domain ); 
        getVoucher(); 
    } 
    private function onDRMStatus( event:DRMStatusEvent ):void 
    { 
        trace( "DRM Status: " + event.detail); 
        trace("--Voucher allows offline playback = " + event.isAvailableOffline ); 
        trace("--Voucher already cached          = " + event.isLocal ); 
        trace("--Voucher required authentication = " + !event.isAnonymous ); 
    } 
    private function onDRMError( event:DRMErrorEvent ):void 
    { 
        trace( "DRM error event: " + event.errorID + ", " + event.subErrorID + ", " + event.text ); 
    } 
    public function onPlayStatus( info:Object ):void 
    { 
        preloadStream.close(); 
    } 
} 
}