Voorbeeld van XML in ActionScript: RSS-gegevens van internet laden

De klasse RSSParser bevat een methode xmlLoaded() waarmee de RSS-invoergegevens die zijn opgeslagen in de variabele rssXML , worden omgezet in een tekenreeks met uitvoer die is opgemaakt in HTML, rssOutput .

Aan het begin van de methode wordt de standaard XML-naamruimte via de code ingesteld wanneer de RSS-brongegevens een standaardnaamruimte bevatten:

if (rssXML.namespace("") != undefined) 
{ 
    default xml namespace = rssXML.namespace(""); 
}

De volgende regels doorlopen de inhoud van de XML-brongegevens en onderzoeken elke afstammende eigenschap met de naam item :

for each (var item:XML in rssXML..item) 
{ 
    var itemTitle:String = item.title.toString(); 
    var itemDescription:String = item.description.toString(); 
    var itemLink:String = item.link.toString(); 
    outXML += buildItemHTML(itemTitle,  
                            itemDescription, 
                            itemLink); 
}

Met de eerste drie regels worden tekenreeksvariabelen ingesteld voor de weergave van de titel, beschrijving en koppelingseigenschappen van de eigenschap item van de XML-gegevens. Met de volgende regel wordt de methode buildItemHTML() aangeroepen voor het omzetten van HTML-gegevens in een object XMLList met behulp van de drie nieuwe tekenreeksvariabelen als parameters.

De HTML-gegevens (een object XMLList) hebben de volgende notatie:

<b>itemTitle</b> 
<p> 
    itemDescription 
    <br /> 
    <a href="link"> 
        <font color="#008000">More...</font> 
    </a> 
</p>

Met de eerste regels van de methode wordt de standaard XML-naamruimte verwijderd:

default xml namespace = new Namespace();

De compileraanwijzing default xml namespace heeft een bereik op het niveau van functieblokken. Dit houdt in dat het bereik van deze declaratie de methode buildItemHTML() is.

Met de regels die hierna volgen, wordt het XMLList samengesteld op grond van de tekenreeksargumenten die zijn doorgegeven aan de functie:

var body:XMLList = new XMLList(); 
body += new XML("<b>" + itemTitle + "</b>"); 
var p:XML = new XML("<p>" + itemDescription + "</p>"); 
 
var link:XML = <a></a>; 
link.@href = itemLink; // <link href="itemLinkString"></link> 
link.font.@color = "#008000";  
        // <font color="#008000"></font></a> 
        // 0x008000 = green 
link.font = "More..."; 
 
p.appendChild(<br/>);  
p.appendChild(link);  
body += p;

Dit object XMLList vertegenwoordigt tekenreeksgegevens die geschikt zijn voor een HTML-tekstveld van ActionScript.

De methode xmlLoaded() maakt gebruik van de geretourneerde waarde van de methode buildItemHTML() en zet deze om in een tekenreeks:

XML.prettyPrinting = false; 
rssOutput = outXML.toXMLString();    

Met de methode xmlLoaded() wordt een tekenreeksvariabele rssTitle ingesteld op grond van informatie in de RSS XML-brongegevens:

rssTitle = rssXML.channel.title.toString();

Tot slot genereert de methode xmlLoaded() een gebeurtenis die aan de toepassing meldt dat de gegevens zijn geparseerd en dat deze beschikbaar zijn:

            dataWritten = new Event("dataWritten", true);