Gebeurtenislisteners

Listenerfunctie die buiten een klasse is gedefinieerd

Met de volgende code wordt een eenvoudig SWF-bestand gemaakt waarmee een rood vierkant wordt weergegeven. Een listenerfunctie met de naam clickHandler() , die geen deel uitmaakt van een klasse, luistert naar muisklikgebeurtenissen op het rode vierkant.

package 
{ 
    import flash.display.Sprite; 
 
    public class ClickExample extends Sprite 
    { 
        public function ClickExample() 
        { 
            var child:ChildSprite = new ChildSprite(); 
            addChild(child); 
        } 
    } 
} 
 
import flash.display.Sprite; 
import flash.events.MouseEvent; 
 
class ChildSprite extends Sprite 
{ 
    public function ChildSprite() 
    { 
        graphics.beginFill(0xFF0000); 
        graphics.drawRect(0,0,100,100); 
        graphics.endFill(); 
        addEventListener(MouseEvent.CLICK, clickHandler); 
    } 
} 
 
function clickHandler(event:MouseEvent):void 
{ 
    trace("clickHandler detected an event of type: " + event.type); 
    trace("the this keyword refers to: " + this); 
}

Wanneer een gebruiker met het resulterende SWF-bestand communiceert door op het vierkant te klikken, genereert Flash Player of AIR de volgende trace-uitvoer:

clickHandler detected an event of type: click 
the this keyword refers to: [object global]

Het gebeurtenisobject wordt als argument doorgegeven aan clickHandler() . Hierdoor kan het gebeurtenisobject door de listenerfunctie worden gecontroleerd. In dit voorbeeld gebruikt u de eigenschap type van het gebeurtenisobject om te controleren of de gebeurtenis een klikgebeurtenis is.

In het voorbeeld wordt ook de waarde van het trefwoord this gecontroleerd. In dit geval vertegenwoordigt this het algemene object. Dit is logisch, omdat de functie buiten enige aangepaste klasse of enig aangepast object is gedefinieerd.

Listenerfunctie die als klassenmethode is gedefinieerd

Het volgende voorbeeld is gelijk aan het vorige ClickExample-voorbeeld, met het verschil dat de functie clickHandler() als een methode van de klasse ChildSprite is gedefinieerd:

package 
{ 
    import flash.display.Sprite; 
 
    public class ClickExample extends Sprite 
    { 
        public function ClickExample() 
        { 
            var child:ChildSprite = new ChildSprite(); 
            addChild(child); 
        } 
    } 
} 
 
import flash.display.Sprite; 
import flash.events.MouseEvent; 
 
class ChildSprite extends Sprite 
{ 
    public function ChildSprite() 
    { 
        graphics.beginFill(0xFF0000); 
        graphics.drawRect(0,0,100,100); 
        graphics.endFill(); 
        addEventListener(MouseEvent.CLICK, clickHandler); 
    } 
    private function clickHandler(event:MouseEvent):void 
    { 
        trace("clickHandler detected an event of type: " + event.type); 
        trace("the this keyword refers to: " + this); 
    } 
}

Wanneer een gebruiker met het resulterende SWF-bestand communiceert door op het rode vierkant te klikken, genereert Flash Player of AIR de volgende trace-uitvoer:

clickHandler detected an event of type: click 
the this keyword refers to: [object ChildSprite]

Het trefwoord this verwijst naar de ChildSprite-instantie met de naam child . Dit gedrag wijkt af van het gedrag in ActionScript 2.0. Als u componenten gebruikte in ActionScript 2.0, weet u wellicht nog wel dat wanneer een klassenmethode werd doorgegeven aan UIEventDispatcher.addEventListener() , het bereik van de methode was gekoppeld aan de component waardoor de gebeurtenis werd verzonden en niet aan de klasse waarin de listenermethode werd gedefinieerd. Met andere woorden, als u deze techniek in ActionScript 2.0 gebruikte, verwees het trefwoord this naar de component die de gebeurtenis verzond en niet naar de ChildSprite-instantie.

Dit kon een serieus probleem voor sommige programmeurs zijn, omdat dit betekende dat deze geen toegang hadden tot andere methoden en eigenschappen van de klasse waarin de listenermethode werd gedefinieerd. Als oplossing konden ActionScript 2.0-programmeurs de klasse mx.util.Delegate gebruiken om het bereik van de listenermethode te wijzigen. Dit is echter niet meer nodig, omdat ActionScript 3.0 een gekoppelde methode maakt wanneer addEventListener() wordt aangeroepen. Als gevolg hiervan verwijst het trefwoord this naar de ChildSprite-instantie met de naam child en heeft de programmeur toegang tot de andere methoden en eigenschappen van de klasse ChildSprite.

Gebeurtenislistener waarvan het gebruik wordt afgeraden

Er bestaat een derde techniek waarbij u een algemeen object maakt met een eigenschap die verwijst naar een dynamisch toegewezen listenerfunctie. Het gebruik hiervan wordt echter niet aanbevolen. Deze techniek wordt hier besproken, omdat deze veel werd gebruikt in ActionScript 2.0, maar in ActionScript 3.0 beter niet gebruikt kan worden. Deze techniek wordt afgeraden omdat het trefwoord this naar het algemene object verwijst en niet naar het listenerobject.

Het volgende voorbeeld is gelijk aan het vorige ClickExample-voorbeeld, met het verschil dat de listenerfunctie is gedefinieerd als deel van een algemeen object met de naam myListenerObj :

package 
{ 
    import flash.display.Sprite; 
 
    public class ClickExample extends Sprite 
    { 
        public function ClickExample() 
        { 
            var child:ChildSprite = new ChildSprite(); 
            addChild(child); 
        } 
    } 
} 
 
import flash.display.Sprite; 
import flash.events.MouseEvent; 
 
class ChildSprite extends Sprite 
{ 
    public function ChildSprite() 
    { 
        graphics.beginFill(0xFF0000); 
        graphics.drawRect(0,0,100,100); 
        graphics.endFill(); 
        addEventListener(MouseEvent.CLICK, myListenerObj.clickHandler); 
    } 
} 
 
var myListenerObj:Object = new Object(); 
myListenerObj.clickHandler = function (event:MouseEvent):void 
{ 
        trace("clickHandler detected an event of type: " + event.type); 
        trace("the this keyword refers to: " + this); 
}

De resultaten van de trace zien er als volgt uit:

clickHandler detected an event of type: click 
the this keyword refers to: [object global]

Men zou verwachten dat this naar myListenerObj verwijst en dat de trace-uitvoer [ object Object ] is. Dit is echter niet het geval, this verwijst naar het algemene object. Wanneer u de naam van een dynamische eigenschap als argument doorgeeft aan addEventListener() , kan Flash Player of AIR geen gekoppelde methode maken. De reden hiervoor is dat u als parameter listener slechts het geheugenadres van de listenerfunctie doorgeeft en dat Flash Player en AIR dit geheugenadres op geen enkele manier kunnen koppelen aan de instantie myListenerObj .

Gebeurtenislisteners toevoegen

De methode addEventListener() is het werkpaard van de interface IEventDispatcher. U gebruikt deze voor het registreren van de listenerfuncties. De twee vereiste parameters zijn type en listener . U gebruikt de parameter type om het type gebeurtenis op te geven. U gebruikt de parameter listener om op te geven welke listenerfunctie wordt uitgevoerd wanneer de gebeurtenis plaatsvindt. De parameter listener kan een verwijzing zijn naar een functie of naar een klassenmethode.

addEventListener(MouseEvent.CLICK, clickHandler)

Met de parameter useCapture van de methode addEventListener() kunt u controleren in welke fase van de gebeurtenisstroom de listener actief wordt. Als useCapture op true is ingesteld, wordt de listener actief tijdens de vastlegfase van de gebeurtenisstroom. Als useCapture op false is ingesteld, wordt de listener actief tijdens de doel- en terugkoppelfasen van de gebeurtenisstroom. Wanneer u in alle drie fasen naar de gebeurtenis wilt luisteren, roept u addEventListener() tweemaal aan, één keer met useCapture ingesteld op true en één keer met useCapture ingesteld op false .

De parameter priority van de methode addEventListener() maakt niet officieel deel uit van het DOM Level 3-gebeurtenismodel. Het is opgenomen in ActionScript 3.0 om u meer flexibiliteit te bieden bij het indelen van de gebeurtenislisteners. Wanneer u addEventListener() aanroept, kunt u de prioriteit voor die gebeurtenislistener instellen door een geheel-getalwaarde als parameter priority door te geven. De standaardwaarde is 0, maar u kunt deze wijzigen in een negatieve of positieve geheel-getalwaarde. Hoe hoger het getal, des te sneller die gebeurtenislistener wordt uitgevoerd. Gebeurtenislisteners met dezelfde prioriteit worden uitgevoerd in de volgorde waarin deze zijn toegevoegd. Hoe eerder een listener wordt toegevoegd, des te sneller deze wordt uitgevoerd.

Met de parameter useWeakReference kunt u opgeven of de verwijzing naar de listenerfunctie zwak of normaal is. Als u deze parameter op true instelt, kunt u situaties vermijden waarbij listenerfuncties in het geheugen aanwezig blijven, terwijl deze niet meer vereist zijn. Flash Player en AIR maken gebruik van een techniek voor het verwijderen van objecten uit het geheugen die niet meer in gebruik zijn. Deze techniek wordt opschonen genoemd. Een object is niet meer in gebruik als er geen verwijzingen naar bestaan. De opschoonfunctie negeert zwakke verwijzingen. Dit betekent dat als er alleen een zwakke verwijzing naar een listenerfunctie bestaat, de listenerfunctie in aanmerking komt voor opschonen.

Gebeurtenislisteners verwijderen

U kunt de methode removeEventListener() gebruiken om een gebeurtenislistener te verwijderen die u niet meer nodig hebt. Het is raadzaam om alle listeners die niet meer worden gebruikt, te verwijderen. Vereiste parameters zijn onder meer de parameters eventName en listener . Dit zijn dezelfde vereiste parameters als voor de methode addEventListener() . U kunt tijdens alle gebeurtenisfasen naar gebeurtenissen luisteren door addEventListener() tweemaal aan te roepen, één keer met useCapture ingesteld op true en één keer met deze parameter ingesteld op false . Als u beide gebeurtenislisteners wilt verwijderen, roept u removeEventListener() tweemaal aan, één keer met useCapture ingesteld op true en één keer met deze parameter ingesteld op false .

Gebeurtenissen verzenden

De methode dispatchEvent() kan door gevorderde programmeurs worden gebruikt om een aangepast gebeurtenisobject naar de gebeurtenisstroom te verzenden. De enige parameter die door deze methode wordt geaccepteerd, is een verwijzing naar een gebeurtenisobject, dat een instantie moet zijn van de klasse Event of van een subklasse van de klasse Event. Als de gebeurtenis is verzonden, wordt de eigenschap target van het gebeurtenisobject ingesteld op het object waarop dispatchEvent() was aangeroepen.

Controleren op bestaande gebeurtenislisteners

De laatste twee methoden van de interface IEventDispatcher bevatten nuttige informatie over het bestaan van gebeurtenislisteners. De methode hasEventListener() retourneert true als er een gebeurtenislistener is gevonden voor een specifiek gebeurtenistype op een bepaald weergaveoverzichtobject. De methode willTrigger() retourneert ook true als er een listener is gevonden voor een bepaald weergaveobject, maar willTrigger() zoekt niet alleen naar listeners op dat weergaveobject, maar ook naar listeners op alle voorouders van dat weergaveoverzichtobject voor alle fasen van de gebeurtenisstroom.