De klasse Math gebruiken met tekenmethoden

Flash Player 9 of hoger, Adobe AIR 1.0 of hoger

Een object Graphics tekent cirkels en vierkanten, maar kan ook meer ingewikkelde vormen tekenen, vooral wanneer de tekenmethoden worden gebruikt in combinatie met de eigenschappen en methoden van de klasse Math. De klasse Math bevat constanten die veel voorkomen in wiskundige formules, zoals Math.PI (ongeveer 3,14159265...), een constante voor de verhouding van de omtrek van een cirkel ten opzichte van de diameter. Het bevat ook methoden voor trigonometriefuncties, onder meer Math.sin() , Math.cos() en Math.tan() . Vormen die met deze methoden en constanten worden getekend, zorgen dat de visuele effecten dynamischer zijn, vooral wanneer ze met herhaling of recursie worden gebruikt.

Veel methoden van de klasse Match verwachten circulaire metingen in eenheden van radialen in plaats van graden. Omzetting tussen deze twee soorten eenheden wordt veel gedaan met de klasse Math:

var degrees = 121; 
var radians = degrees * Math.PI / 180; 
trace(radians) // 2.111848394913139

In het volgende voorbeeld worden een sinusgolf en een cosinusgolf gemaakt om het verschil tussen de methoden Math.sin() en Math.cos() voor een bepaalde waarde aan te geven.

var sinWavePosition = 100; 
var cosWavePosition = 200; 
var sinWaveColor:uint = 0xFF0000; 
var cosWaveColor:uint = 0x00FF00; 
var waveMultiplier:Number = 10; 
var waveStretcher:Number = 5; 
 
var i:uint; 
for(i = 1; i < stage.stageWidth; i++) 
{ 
    var sinPosY:Number = Math.sin(i / waveStretcher) * waveMultiplier; 
    var cosPosY:Number = Math.cos(i / waveStretcher) * waveMultiplier; 
     
    graphics.beginFill(sinWaveColor); 
    graphics.drawRect(i, sinWavePosition + sinPosY, 2, 2);  
    graphics.beginFill(cosWaveColor); 
    graphics.drawRect(i, cosWavePosition + cosPosY, 2, 2); 
}