Taakbalkpictogrammen in AIR

U kunt opdrachten toevoegen aan het standaardmenu van een dock door een NativeMenu-object met deze opdrachten te maken en dit object vervolgens toe te wijzen aan de eigenschap NativeApplication.nativeApplication.icon.menu . De items in het menu worden boven de standaarditems in het dock-menu weergegeven.

U kunt een pictogram in het dock laten bewegen door de methode NativeApplication.nativeApplication.icon.bounce() op te roepen. Als u de parameter bounce() priority instelt op informational (informatief), beweegt het pictogram één keer. Als u deze parameter instelt op critical (kritiek), beweegt het pictogram totdat de gebruiker de toepassing activeert. Constanten voor de parameter priority worden gedefineerd in de klasse NotificationType.

Wanneer op een dock-pictogram wordt geklikt, verzendt het NativeApplication-object de gebeurtenis invoke . Als de toepassing nog niet wordt uitgevoerd, wordt deze door het systeem gestart. Als de toepassing wel wordt uitgevoerd, wordt de gebeurtenis invoke verzonden naar de actieve toepassingsinstantie.

U kunt een menu aan een systeemvakpictogram toevoegen door een NativeMenu-object te maken en dit object vervolgens aan de eigenschap NativeApplication.nativeApplication.icon.menu toe te wijzen (er is geen standaardmenu beschikbaar in het besturingssysteem). U kunt het menu van het systeemvakpictogram openen door met de rechtermuisknop op het pictogram te klikken.

Voeg knopinfo toe aan een pictogram door de eigenschap voor knopinfo in te stellen:

NativeApplication.nativeApplication.icon.tooltip = "Application name"; 

Het object SystemTrayIcon waarnaar wordt verwezen met de eigenschap NativeApplication.nativeApplication.icon, verzendt een ScreenMouseEvent voor de gebeurtenissen click , mouseDown , mouseUp , rightClick , rightMouseDown en rightMouseUp . U kunt deze gebeurtenissen samen met een pictogrammenu gebruiken om gebruikers in staat te stellen met uw toepassing te interageren wanneer deze geen zichtbare vensters heeft.

In het volgende voorbeeld wordt een AIR-toepassing gemaakt met een systeemvakpictogram maar zonder zichtbare vensters. (De eigenschap visible van de toepassing mag niet zijn ingesteld op true in de toepassingsdescriptor. Als dit wel het geval is, zal het venster zichtbaar zijn wanneer de toepassing wordt opgestart.)

package 
{ 
    import flash.display.Loader; 
    import flash.display.NativeMenu; 
    import flash.display.NativeMenuItem; 
    import flash.display.NativeWindow; 
    import flash.display.Sprite; 
    import flash.desktop.DockIcon; 
    import flash.desktop.SystemTrayIcon; 
    import flash.events.Event; 
    import flash.net.URLRequest; 
    import flash.desktop.NativeApplication; 
 
    public class SysTrayApp extends Sprite 
    { 
        public function SysTrayApp():void{ 
            NativeApplication.nativeApplication.autoExit = false; 
            var icon:Loader = new Loader(); 
            var iconMenu:NativeMenu = new NativeMenu(); 
            var exitCommand:NativeMenuItem = iconMenu.addItem(new NativeMenuItem("Exit")); 
                exitCommand.addEventListener(Event.SELECT, function(event:Event):void { 
                    NativeApplication.nativeApplication.icon.bitmaps = []; 
                    NativeApplication.nativeApplication.exit(); 
                }); 
 
            if (NativeApplication.supportsSystemTrayIcon) { 
                NativeApplication.nativeApplication.autoExit = false; 
                icon.contentLoaderInfo.addEventListener(Event.COMPLETE, iconLoadComplete); 
                icon.load(new URLRequest("icons/AIRApp_16.png")); 
                 
                var systray:SystemTrayIcon =  
                    NativeApplication.nativeApplication.icon as SystemTrayIcon; 
                systray.tooltip = "AIR application"; 
                systray.menu = iconMenu; 
            } 
 
            if (NativeApplication.supportsDockIcon){ 
                icon.contentLoaderInfo.addEventListener(Event.COMPLETE,iconLoadComplete); 
                icon.load(new URLRequest("icons/AIRApp_128.png")); 
                var dock:DockIcon = NativeApplication.nativeApplication.icon as DockIcon;  
                dock.menu = iconMenu; 
            } 
        } 
         
        private function iconLoadComplete(event:Event):void 
        { 
            NativeApplication.nativeApplication.icon.bitmaps = 
                [event.target.content.bitmapData]; 
        } 
    } 
} 

Wanneer een venster zich op de achtergrond bevindt, kunt u de gebruiker waarschuwen wanneer betreffende dat venster een gebeurtenis plaatsvindt die van belang is voor de gebruiker. In Mac OS X kunt u de gebruiker waarschuwen door het toepassingspictogram in het dock te laten bewegen (zoals is beschreven in Het pictogram in het dock laten bewegen ). In Windows en Linux kunt u de taakbalkknop van het venster markeren door de methode notifyUser() van het NativeWindow-exemplaar aan te roepen. De parameter type die aan de methode wordt doorgegeven, bepaalt de urgentie van de waarschuwing:

• NotificationType.CRITICAL : het pictogram van het venster knippert totdat de gebruiker het venster op de voorgrond plaatst.

• NotificationType.INFORMATIONAL : het pictogram van het venster wordt gemarkeerd door een kleurwijziging.

  Opmerking: In Linux wordt alleen de melding van het informatieve type ondersteund. Wanneer u een waarde van een van deze typen aan de functie notifyUser() doorgeeft, leidt dit tot hetzelfde effect.

  Met de volgende instructie zorgt u dat de taakbalkknop van een venster wordt gemarkeerd:

  stage.nativeWindow.notifyUser(NotificationType.CRITICAL); 

  De methode NativeWindow.notifyUser() heeft alleen effect als u deze methode oproept in een besturingssysteem dat waarschuwingen op vensterniveau ondersteunt. Gebruik de eigenschap NativeWindow.supportsNotification om te controleren of vensterwaarschuwingen worden ondersteund.

In Windows worden vensters van het type utility of lightweight niet op de taakbalk weergegeven. Ook onzichtbare vensters verschijnen niet op de taakbalk.

Omdat het beginvenster noodzakelijkerwijs van het type normal is, moet u dit beginvenster sluiten of zorgen dat het onzichtbaar blijft als u een toepassing wilt maken waarvan de vensters niet als knop op de taakbalk worden weergegeven. Als u alle vensters van uw toepassing wilt sluiten zonder de toepassing af te sluiten, stelt u de eigenschap autoExit van het object NativeApplication in op false voordat u het laatste venster sluit. Als u eenvoudig wilt voorkomen dat het beginvenster ooit zichtbaar wordt, voegt u <visible>false</visible> toe aan het element <initialWindow> van het descriptorbestand van de toepassing. (Stel de eigenschap visible niet in op true en roep ook niet de methode activate() van het venster op.)

Stel voor nieuwe vensters die door de toepassing worden geopend, de eigenschap type van het object NativeWindowInitOption dat wordt doorgegeven aan de vensterconstructor, in op NativeWindowType.UTILITY of NativeWindowType.LIGHTWEIGHT .

In Mac OS X worden geminimaliseerde vensters weergegeven op de dock-taakbalk. U kunt voorkomen dat het pictogram van een geminimaliseerd venster wordt weergegeven door het venster te verbergen in plaats van te minimaliseren. In het volgende voorbeeld wordt geluisterd naar een gebeurtenis die nativeWindowDisplayState verandert en wordt deze gebeurtenis geannuleerd als het venster wordt geminimaliseerd. In plaats daarvan stelt de handler de eigenschap visible van het venster in op false :

private function preventMinimize(event:NativeWindowDisplayStateEvent):void{ 
    if(event.afterDisplayState == NativeWindowDisplayState.MINIMIZED){ 
        event.preventDefault(); 
        event.target.visible = false; 
    } 
} 

Als een venster wordt geminimaliseerd in het dock van Mac OS X wanneer u de eigenschap visible op false instelt, wordt het pictogram niet uit het dock verwijderd. Een gebruiker kan in dat geval nog steeds op het pictogram klikken om het venster opnieuw weer te geven.