Schermvullende vensters weergeven

Adobe AIR 1.0 of hoger

Door de eigenschap displayState van het werkgebied in te stellen op StageDisplayState.FULL_SCREEN_INTERACTIVE wordt het venster in het volledige scherm weergegeven; in deze modus is toetsenbordinvoer wel toegestaan. (In SWF-inhoud die in een browser wordt uitgevoerd, is toetsenbordinvoer niet toegestaan.) Als de gebruiker de schermvullende modus wil verlaten, kan deze op Esc drukken.

Opmerking: Bepaalde Linux-vensterbeheerprogramma's wijzigen de vensterafmetingen niet zo dat het scherm helemaal wordt gevuld wanneer een maximumformaat is ingesteld voor het venster (het venstersysteemchroom wordt echter wel verwijderd).

Met de volgende Flex-code wordt bijvoorbeeld een eenvoudige AIR-toepassing gedefinieerd die een eenvoudige schermvullende terminal instelt: 

<?xml version="1.0" encoding="utf-8"?> 
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml"  
    layout="vertical"  
    applicationComplete="init()" backgroundColor="0x003030" focusRect="false"> 
    <mx:Script> 
        <![CDATA[ 
            private function init():void  
            { 
                stage.displayState = StageDisplayState.FULL_SCREEN_INTERACTIVE; 
                focusManager.setFocus(terminal); 
                terminal.text = "Welcome to the dumb terminal app. Press the ESC key to exit..\n"; 
                terminal.selectionBeginIndex = terminal.text.length; 
                terminal.selectionEndIndex = terminal.text.length; 
            } 
        ]]> 
    </mx:Script> 
    <mx:TextArea  
        id="terminal"  
        height="100%" width="100%"  
        scroll="false" 
        backgroundColor="0x003030"  
        color="0xCCFF00"  
        fontFamily="Lucida Console"  
        fontSize="44"/> 
</mx:WindowedApplication>

In het volgende ActionScript-voorbeeld voor Flash wordt een eenvoudige schermvullende tekstterminal gesimuleerd: 

    import flash.display.Sprite; 
    import flash.display.StageDisplayState; 
    import flash.text.TextField; 
    import flash.text.TextFormat; 
     
    public class FullScreenTerminalExample extends Sprite 
    { 
        public function FullScreenTerminalExample():void  
        { 
            var terminal:TextField = new TextField(); 
            terminal.multiline = true; 
            terminal.wordWrap = true; 
            terminal.selectable = true; 
            terminal.background = true; 
            terminal.backgroundColor = 0x00333333; 
             
            this.stage.displayState = StageDisplayState.FULL_SCREEN_INTERACTIVE; 
             
            addChild(terminal); 
            terminal.width = 550; 
            terminal.height = 400; 
             
            terminal.text = "Welcome to the dumb terminal application. Press the ESC key to exit.\n_"; 
             
            var tf:TextFormat = new TextFormat(); 
            tf.font = "Courier New"; 
            tf.color = 0x00CCFF00; 
            tf.size = 12; 
            terminal.setTextFormat(tf); 
             
            terminal.setSelection(terminal.text.length - 1, terminal.text.length); 
        } 
    }