Werken met SQL-instructies

Creëer een SQLStatement-instantie.

Het SQLStatement-object vertegenwoordigt de SQL-instructie in uw toepassing.

var selectData:SQLStatement = new SQLStatement(); 

Geef de database op waarop u de query wilt toepassen.

Hiervoor stelt u de eigenschap sqlConnection van het SQLStatement-object in op de SQLConnection-instantie die met de gewenste database is verbonden.

// A SQLConnection named "conn" has been created previously 
selectData.sqlConnection = conn;

Geef de daadwerkelijke SQL-instructie op.

Creëer de instructietekst als een tekenreeks (String) en wijs deze toe aan de eigenschap text van de SQLStatement-instantie.

selectData.text = "SELECT col1, col2 FROM my_table WHERE col1 = :param1";

Definieer functies om het resultaat van de uitvoeringsbewerking (alleen asynchrone uitvoeringsmodus) te verwerken.

Gebruik de methode addEventListener() om functies als listeners voor de gebeurtenissen result en error van de SQLStatement-instantie te registreren.

// using listener methods and addEventListener() 
     
selectData.addEventListener(SQLEvent.RESULT, resultHandler); 
selectData.addEventListener(SQLErrorEvent.ERROR, errorHandler); 
     
function resultHandler(event:SQLEvent):void 
{ 
    // do something after the statement execution succeeds 
} 
     
function errorHandler(event:SQLErrorEvent):void 
{ 
    // do something after the statement execution fails 
} 

U kunt ook listenermethoden opgeven met behulp van een Responder-object. In dat geval creëert u de Responder-instantie en koppelt u de listenermethoden aan die instantie.

// using a Responder (flash.net.Responder) 
     
var selectResponder = new Responder(onResult, onError); 
     
function onResult(result:SQLResult):void 
{ 
    // do something after the statement execution succeeds 
} 
     
function onError(error:SQLError):void 
{ 
    // do something after the statement execution fails 
} 

Als de instructietekst parameterdefinities bevat, wijst u waarden toe aan de desbetreffende parameters.

U wijst parameterwaarden toe via de associatieve-array-eigenschap parameters van de SQLStatement-instantie.

selectData.parameters[":param1"] = 25;

Voer de SQL-instructie uit.

Roep de methode execute() van de SQLStatement-instantie op.

// using synchronous execution mode 
// or listener methods in asynchronous execution mode 
selectData.execute();

Als u een Responder in plaats van gebeurtenislisteners gebruikt in asynchrone uitvoeringsmodus, moet u ook de Responder-instantie opgeven voor de methode execute().

// using a Responder in asynchronous execution mode 
selectData.execute(-1, selectResponder);

Zie de volgende onderwerpen voor specifieke voorbeelden die deze procedurestappen illustreren:

Gegevens ophalen uit een database

 Gegevens invoegen

 Gegevens wijzigen of verwijderen