Workflow voor beveiligde inhoud

De volgende procedure beschrijft de workflow voor het vooraf laden van de voucher voor een beveiligd mediabestand met een DRMContentData-object.

1. Haal de binaire metagegevens op voor de inhoud die in een pakket is opgenomen. Als u Flash Access Java Reference Packager gebruikt, wordt dit metagegevensbetand automatisch gegenereerd. Het bestand heeft de extensie .metadata. U kunt deze metagegevens bijvoorbeeld downloaden met de URLLoader-klasse.

2. Maak een DRMContentData-object en geef de metagegevens door aan de constructorfunctie:

   var drmData:DRMContentData = new DRMContentData( metadata );

3. De overige stappen zijn gelijk aan de procedure die is beschreven in Workflow voor beveiligde inhoud.

In de volgende stappen wordt de workflow beschreven voor het vooraf laden van een voucher voor een DRM-beveiligd mediabestand met preloadEmbeddedMetadata():

1. Download het mediabestand en sla het op. (DRM-metagegevens kunnen alleen vooraf worden geladen uit lokaal opgeslagen bestanden.)

2. Maak de NetConnection- en NetStream-objecten en geef hierbij implementaties op voor de callback-functies onDRMContentData() en onPlayStatus() van het NetStream-clientobject.

3. Maak een NetStreamPlayOptions-object en stel de waarde van de eigenschap stream in op de URL van het lokale mediabestand.

4. Roep de methode preloadEmbeddedMetadata() van NetStream aan en geef het NetStreamPlayOptions-object door waarin het mediabestand wordt geïdentificeerd dat moet worden geparseerd.

5. Als het mediabestand DRM-metagegevens bevat, wordt de callback-functie onDRMContentData() aangeroepen. De metagegevens worden doorgegeven naar deze functie in de vorm van een DRMContentData-object.

6. Gebruik het DRMContentData-object om de bon te verkrijgen met behulp van de methode loadVoucher() van DRMManager.

   Als de eigenschap authenticationMethod van het DRMContentData-object de waarde userNameAndPassword heeft, moet u de gebruiker verifiëren op de mediarechtenserver voordat u de voucher laadt. De eigenschappen serverURL en domain van het DRMContentData-object kunnen samen met de gebruikersreferenties worden doorgegeven aan de DRMManager-methode authenticate().

7. De callback-functie onPlayStatus() wordt geactiveerd wanneer de bestandsparsering is voltooid. Als de functie onDRMContentData() niet is aangeroepen, bevat het bestand niet de vereiste metagegevens om een voucher te verkrijgen. Als deze aanroep ontbreekt, betekent dit mogelijk ook dat dit bestand niet door Flash Access wordt beveiligd.

In de volgende code voor AIR wordt geïllustreerd hoe u een voucher vooraf kunt laden voor een lokaal mediabestand:

package 
{ 
import flash.display.Sprite; 
import flash.events.DRMAuthenticationCompleteEvent; 
import flash.events.DRMAuthenticationErrorEvent; 
import flash.events.DRMErrorEvent;   
import flash.ev ents.DRMStatusEvent; 
import flash.events.NetStatusEvent; 
import flash.net.NetConnection; 
import flash.net.NetStream; 
import flash.net.NetStreamPlayOptions; 
import flash.net.drm.AuthenticationMethod; 
import flash.net.drm.DRMContentData; 
import flash.net.drm.DRMManager; 
import flash.net.drm.LoadVoucherSetting;   
public class DRMPreloader extends Sprite  
{ 
     private var videoURL:String = "app-storage:/video.flv"; 
    private var userName:String = "user"; 
    private var password:String = "password";  
    private var preloadConnection:NetConnection; 
    private var preloadStream:NetStream; 
    private var drmManager:DRMManager = DRMManager.getDRMManager(); 
    private var drmContentData:DRMContentData; 
    public function DRMPreloader():void { 
        drmManager.addEventListener( 
            DRMAuthenticationCompleteEvent.AUTHENTICATION_COMPLETE, 
            onAuthenticationComplete); 
        drmManager.addEventListener(DRMAuthenticationErrorEvent.AUTHENTICATION_ERROR, 
            onAuthenticationError);             
        drmManager.addEventListener(DRMStatusEvent.DRM_STATUS, onDRMStatus); 
        drmManager.addEventListener(DRMErrorEvent.DRM_ERROR, onDRMError); 
        preloadConnection = new NetConnection(); 
        preloadConnection.addEventListener(NetStatusEvent.NET_STATUS, onConnect); 
        preloadConnection.connect(null);            
    } 
 
    private function onConnect( event:NetStatusEvent ):void 
    { 
        preloadMetadata(); 
    } 
    private function preloadMetadata():void 
    { 
        preloadStream = new NetStream( preloadConnection ); 
        preloadStream.client = this; 
        var options:NetStreamPlayOptions = new NetStreamPlayOptions(); 
        options.streamName = videoURL; 
        preloadStream.preloadEmbeddedData( options );                         
    }     
    public function onDRMContentData( drmMetadata:DRMContentData ):void 
    { 
        drmContentData = drmMetadata; 
        if ( drmMetadata.authenticationMethod == AuthenticationMethod.USERNAME_AND_PASSWORD ) 
        { 
            authenticateUser(); 
        } 
        else 
            { 
                getVoucher(); 
            } 
    } 
    private function getVoucher():void 
    { 
        drmManager.loadVoucher( drmContentData, LoadVoucherSetting.ALLOW_SERVER ); 
    } 
 
    private function authenticateUser():void 
    { 
        drmManager.authenticate( drmContentData.serverURL, drmContentData.domain, userName, password ); 
    } 
    private function onAuthenticationError( event:DRMAuthenticationErrorEvent ):void 
    { 
        trace( "Authentication error: " + event.errorID + ", " + event.subErrorID ); 
    } 
 
    private function onAuthenticationComplete( event:DRMAuthenticationCompleteEvent ):void 
    { 
        trace( "Authenticated to: " + event.serverURL + ", domain: " + event.domain ); 
        getVoucher(); 
    } 
    private function onDRMStatus( event:DRMStatusEvent ):void 
    { 
        trace( "DRM Status: " + event.detail); 
        trace("--Voucher allows offline playback = " + event.isAvailableOffline ); 
        trace("--Voucher already cached          = " + event.isLocal ); 
        trace("--Voucher required authentication = " + !event.isAnonymous ); 
    } 
    private function onDRMError( event:DRMErrorEvent ):void 
    { 
        trace( "DRM error event: " + event.errorID + ", " + event.subErrorID + ", " + event.text ); 
    } 
    public function onPlayStatus( info:Object ):void 
    { 
        preloadStream.close(); 
    } 
} 
}