ActionScript의 XML 예제: 인터넷에서 RSS 데이터 로드

RSSParser 클래스에는 rssXML 변수에 저장된 입력 RSS 데이터를 HTML 형식 출력(rssOutput)이 들어 있는 문자열로 변환하는 xmlLoaded() 메서드가 포함되어 있습니다.

소스 RSS 데이터에 기본 네임스페이스가 포함되어 있는 경우 코드에서는 메서드의 시작 부분에서 기본 XML 네임스페이스를 설정합니다.

if (rssXML.namespace("") != undefined) 
{ 
    default xml namespace = rssXML.namespace(""); 
}

그러면 다음 줄에서 소스 XML 데이터의 내용을 반복하여 item이라는 각 하위 속성을 검사합니다.

for each (var item:XML in rssXML..item) 
{ 
    var itemTitle:String = item.title.toString(); 
    var itemDescription:String = item.description.toString(); 
    var itemLink:String = item.link.toString(); 
    outXML += buildItemHTML(itemTitle,  
                            itemDescription, 
                            itemLink); 
}

처음 세 줄에서는 문자열 변수를 설정하여 XML 데이터에 대한 item 속성의 제목, 설명 및 링크 속성을 나타냅니다. 그러면 다음 줄에서 buildItemHTML() 메서드를 호출하여 HTML 데이터를 XMLList 객체 형식으로 가져옵니다. 이때 세 개의 새 문자열 변수를 매개 변수로 사용합니다.

HTML 데이터(XMLList 객체)는 다음과 같은 형식으로 되어 있습니다.

<b>itemTitle</b> 
<p> 
    itemDescription 
    <br /> 
    <a href="link"> 
        <font color="#008000">More...</font> 
    </a> 
</p>

메서드의 첫 번째 줄에서는 기본 xml 네임스페이스를 제거합니다.

default xml namespace = new Namespace();

default xml namespace 지시문에는 함수 블록 수준 범위가 있습니다. 즉, 이 선언의 범위가 buildItemHTML() 메서드입니다.

그 다음에 나오는 줄에서는 함수에 전달된 문자열 인수에 따라 XMLList를 어셈블합니다.

var body:XMLList = new XMLList(); 
body += new XML("<b>" + itemTitle + "</b>"); 
var p:XML = new XML("<p>" + itemDescription + "</p>"); 
 
var link:XML = <a></a>; 
link.@href = itemLink; // <link href="itemLinkString"></link> 
link.font.@color = "#008000";  
        // <font color="#008000"></font></a> 
        // 0x008000 = green 
link.font = "More..."; 
 
p.appendChild(<br/>);  
p.appendChild(link);  
body += p;

이 XMLList 객체는 ActionScript HTML 텍스트 필드에 적합한 문자열 데이터를 나타냅니다.

xmlLoaded() 메서드는 buildItemHTML() 메서드의 반환값을 사용하고 이 값을 문자열로 변환합니다.

XML.prettyPrinting = false; 
rssOutput = outXML.toXMLString();    

xmlLoaded() 메서드는 소스 RSS XML 데이터의 정보를 기초로 rssTitle 문자열 변수를 설정합니다.

rssTitle = rssXML.channel.title.toString();

마지막으로 xmlLoaded() 메서드는 데이터가 파싱되어 사용할 수 있음을 응용 프로그램에 알리는 이벤트를 생성합니다.

            dataWritten = new Event("dataWritten", true);