외부 데이터 로드

외부 데이터를 로드하는 많은 API는 URLRequest 클래스를 사용하여 필요한 네트워크 요청 속성을 정의합니다.

URLLoader 클래스를 사용하면 서버에 요청을 보내고 반환된 정보에 액세스할 수 있습니다. 또한 URLLoader 클래스를 사용하면 로컬 파일 액세스가 허용되는 상황(예: Flash Player local-with-filesystem 샌드박스 및 AIR 응용 프로그램 샌드박스)에서 로컬 파일 시스템에 있는 파일에 액세스할 수 있습니다. URLLoader 클래스는 URL에서 텍스트, 이진 데이터 또는 URL 인코딩된 변수 형식으로 데이터를 다운로드합니다. URLLoader 클래스는 complete, httpStatus, ioError, open, progress, securityError 등의 이벤트를 전달합니다.

ActionScript 3.0 이벤트 처리 모델은 ActionScript 2.0 모델과 많은 차이가 있습니다. 2.0 모델의 경우 LoadVars.onData, LoadVars.onHTTPStatus 및 LoadVars.onLoad 이벤트 핸들러를 사용했습니다. ActionScript 3.0에서의 이벤트 처리에 대한 자세한 내용은 이벤트 처리를 참조하십시오.

다운로드되는 데이터는 다운로드가 완료될 때까지 사용할 수 없습니다. progress 이벤트를 수신하여 전달되는 다운로드의 진행률(로드된 바이트 및 총 바이트)을 모니터링할 수 있습니다. 그러나 파일이 너무 빠르게 로드되면 progress 이벤트가 전달되지 않을 수 있습니다. 파일이 성공적으로 다운로드되면 complete 이벤트가 전달됩니다. URLLoader dataFormat 속성을 설정하면 데이터를 텍스트, 원시 이진 데이터 또는 URLVariables 객체로 받을 수 있습니다.

URLLoader.load() 메서드 및 URLLoader 클래스 생성자(선택 항목)는 URLRequest 객체인 request 하나만 매개 변수로 사용합니다. URLRequest 객체에는 대상 URL, 요청 메서드(GET 또는 POST), 추가 헤더 정보 및 MIME 유형과 같은 단일 HTTP 요청의 모든 정보가 들어 있습니다.

예를 들어 XML 패킷을 서버측 스크립트에 업로드할 때 다음과 같은 코드를 사용할 수 있습니다.

var secondsUTC:Number = new Date().time; 
var dataXML:XML =  
    <clock> 
        <time>{secondsUTC}</time> 
    </clock>; 
var request:URLRequest = new URLRequest("http://www.yourdomain.com/time.cfm"); 
request.contentType = "text/xml"; 
request.data = dataXML.toXMLString(); 
request.method = URLRequestMethod.POST; 
var loader:URLLoader = new URLLoader(); 
loader.load(request); 

앞의 코드 예제에서는 dataXML이라는 XML 문서(서버에 보낼 XML 패킷 포함)를 만듭니다. 예제에서는 먼저 URLRequest contentType 속성을 "text/xml"로 설정하고 XML 문서를 URLRequest data 속성에 할당합니다. 마지막으로, URLLoader 객체를 생성하고 load() 메서드를 사용하여 원격 스크립트로 요청을 보냅니다.

URLStream 클래스는 데이터가 도착하면 다운로드 중인 데이터에 대한 액세스를 제공합니다. URLStream 클래스를 사용하면 다운로드가 완료되기 전에 스트림을 닫을 수도 있습니다. 다운로드된 데이터는 원시 이진 데이터로 사용할 수 있습니다.

URLStream 객체에서 데이터를 읽을 때는 먼저 bytesAvailable 속성을 통해 충분한 데이터를 사용할 수 있는지 확인합니다. 사용할 수 있는 데이터 이상으로 데이터를 읽으려고 하면 EOFError 예외가 발생합니다.

동적 응용 프로그램을 작성하는 경우 외부 파일 또는 서버 측 스크립트에서 데이터를 로드하는 것이 좋을 수 있습니다. 그러면 응용 프로그램을 편집하거나 다시 컴파일하지 않고도 동적 응용 프로그램을 작성할 수 있습니다. 예를 들어 "오늘의 팁"을 표시하는 응용 프로그램을 작성하는 경우 하루에 한 번씩 데이터베이스에서 임의로 하나의 팁을 가져와 텍스트 파일로 저장하는 서버 측 스크립트를 작성할 수 있습니다. 그러면 응용 프로그램에서 매번 데이터베이스를 쿼리하지 않고 정적 텍스트 파일의 내용을 로드할 수 있습니다.

다음 코드 예제에서는 외부 텍스트 파일인 params.txt의 내용을 로드하는 URLRequest 및 URLLoader 객체를 만듭니다.

var request:URLRequest = new URLRequest("params.txt"); 
var loader:URLLoader = new URLLoader(); 
loader.load(request);

var request:URLRequest = new URLRequest("sendfeedback.cfm"); 
request.method = URLRequestMethod.POST;

런타임에 로드되는 외부 문서 params.txt에는 다음 데이터가 포함됩니다.

monthNames=January,February,March,April,May,June,July,August,September,October,November,December&dayNames=Sunday,Monday,Tuesday,Wednesday,Thursday,Friday,Saturday

이 파일에는 monthNames 및 dayNames라는 두 개의 매개 변수가 포함됩니다. 각 매개 변수에는 쉼표로 구분되어 문자열로 파싱된 목록이 들어 있습니다. String.split() 메서드를 사용하여 이 목록을 배열로 나눌 수 있습니다.

코드를 읽거나 디버깅하기가 어려워지므로 외부 데이터 파일에서 예약어나 언어 구문을 변수 이름으로 사용하지 마십시오.

function completeHandler(event) 
{ 
    var loader2 = event.target; 
    air.trace(loader2.data); 
}

원격 문서에 이름-값 쌍이 있으면 다음과 같이 로드된 파일의 내용에서 전달하는 방식으로 URLVariables 클래스를 사용하여 데이터를 파싱할 수 있습니다.

private function completeHandler(event:Event):void 
{ 
    var loader2:URLLoader = URLLoader(event.target); 
    var variables:URLVariables = new URLVariables(loader2.data); 
    trace(variables.dayNames); 
}

외부 파일의 각 이름-값 쌍은 URLVariables 객체에서 속성으로 만들어집니다. 앞의 코드 샘플에서 변수 객체의 각 속성은 문자열로 처리됩니다. 이름-값 쌍의 값이 항목의 목록이면 다음과 같이 String.split() 메서드를 호출하여 문자열을 배열로 변환할 수 있습니다.

var dayNameArray:Array = variables.dayNames.split(",");

외부 텍스트 파일에서 숫자 데이터를 로드하는 경우 int(), uint() 또는 Number() 등 최상위 함수를 사용하여 값을 숫자 값으로 변환합니다.

원격 파일의 내용을 문자열로 로드하여 새 URLVariables 객체를 만드는 대신 URLLoader.dataFormat 속성을 URLLoaderDataFormat 클래스에 있는 정적 속성 중 하나로 설정할 수 있습니다. URLLoader.dataFormat 속성에 사용할 수 있는 값은 다음 세 가지입니다.

• URLLoaderDataFormat.BINARY - ByteArray 객체에 저장된 이진 데이터가 URLLoader.data 속성에 포함됩니다.

• URLLoaderDataFormat.TEXT - 문자열 객체의 텍스트가 URLLoader.data 속성에 포함됩니다.

• URLLoaderDataFormat.VARIABLES - URLVariables 객체에 저장된 URL 인코딩된 변수가 URLLoader.data 속성에 포함됩니다.

다음 코드는 URLLoader.dataFormat 속성을 URLLoaderDataFormat.VARIABLES로 설정하는 경우 로드된 데이터가 자동으로 URLVariables 객체로 구문 분석되는 방법을 보여 줍니다.

package 
{ 
    import flash.display.Sprite; 
    import flash.events.*; 
    import flash.net.URLLoader; 
    import flash.net.URLLoaderDataFormat; 
    import flash.net.URLRequest; 
 
    public class URLLoaderDataFormatExample extends Sprite 
    { 
        public function URLLoaderDataFormatExample() 
        { 
            var request:URLRequest = new URLRequest("http://www.[yourdomain].com/params.txt"); 
            var variables:URLLoader = new URLLoader(); 
            variables.dataFormat = URLLoaderDataFormat.VARIABLES; 
            variables.addEventListener(Event.COMPLETE, completeHandler); 
            try 
            { 
                variables.load(request); 
            }  
            catch (error:Error) 
            { 
                trace("Unable to load URL: " + error); 
            } 
        } 
        private function completeHandler(event:Event):void 
        { 
        var loader:URLLoader = URLLoader(event.target); 
        trace(loader.data.dayNames); 
        } 
    } 
}

다음 예제에 나와 있듯이 외부 파일에서 XML을 로드하는 것은 URLVariables를 로드하는 것과 같습니다. URLRequest 인스턴스와 URLLoader 인스턴스를 만들고 이러한 인스턴스를 사용하여 원격 XML 문서를 다운로드할 수 있습니다. 파일이 완전히 다운로드되면 Event.COMPLETE 이벤트가 전달되고 외부 파일의 내용이 XML 인스턴스로 변환됩니다. 이 인스턴스는 XML 메서드와 속성을 사용하여 구문 분석할 수 있습니다.

package 
{ 
    import flash.display.Sprite; 
    import flash.errors.*; 
    import flash.events.*; 
    import flash.net.URLLoader; 
    import flash.net.URLRequest; 
 
    public class ExternalDocs extends Sprite 
    { 
        public function ExternalDocs() 
        { 
            var request:URLRequest = new URLRequest("http://www.[yourdomain].com/data.xml"); 
            var loader:URLLoader = new URLLoader(); 
            loader.addEventListener(Event.COMPLETE, completeHandler); 
            try 
            { 
                loader.load(request); 
            } 
            catch (error:ArgumentError) 
            { 
                trace("An ArgumentError has occurred."); 
            } 
            catch (error:SecurityError) 
            { 
                trace("A SecurityError has occurred."); 
            } 
        } 
        private function completeHandler(event:Event):void 
        { 
            var dataXML:XML = XML(event.target.data); 
            trace(dataXML.toXMLString()); 
        } 
    } 
}

외부 데이터 파일 로드 외에 URLVariables 클래스를 사용하여 변수를 서버측 스크립트로 전송하고 서버의 응답을 처리할 수도 있습니다. 예를 들어 이 방법은 게임을 프로그래밍하는 경우 사용자의 점수를 서버에 전송하여 고득점 목록에 추가할지 여부를 계산하거나 사용자 로그인 정보를 서버에 전송하여 확인하려는 경우에 유용합니다. 서버측 스크립트는 사용자 이름과 암호를 처리하고, 데이터베이스에서 해당 이름과 암호의 유효성을 검사하며, 사용자가 제공한 자격 증명이 유효한지 여부를 확인하여 반환할 수 있습니다.

다음 코드 예제에서는 variables라는 URLVariables 객체를 만듭니다. 이 객체는 name이라는 새 변수를 만듭니다. 다음으로, 변수를 보낼 서버측 스크립트의 URL을 지정하는 URLRequest 객체를 만듭니다. 그런 다음 URLRequest 객체의 method 속성을 설정하여 변수를 HTTP POST 요청으로 보냅니다. URLVariables 객체를 URL 요청에 추가하려면 URLRequest 객체의 data 속성을 이전에 만든 URLVariables 객체로 설정합니다. 마지막으로 URLLoader 인스턴스가 만들고 URLLoader.load() 메서드를 호출하여 요청을 시작합니다.

var variables:URLVariables = new URLVariables("name=Franklin"); 
var request:URLRequest = new URLRequest(); 
request.url = "http://www.[yourdomain].com/greeting.cfm"; 
request.method = URLRequestMethod.POST; 
request.data = variables; 
var loader:URLLoader = new URLLoader(); 
loader.dataFormat = URLLoaderDataFormat.VARIABLES; 
loader.addEventListener(Event.COMPLETE, completeHandler); 
try 
{ 
    loader.load(request); 
} 
catch (error:Error) 
{ 
    trace("Unable to load URL"); 
} 
 
function completeHandler(event:Event):void 
{ 
    trace(event.target.data.welcomeMessage); 
}

다음 코드에는 앞의 예제에서 사용된 Adobe ColdFusion® greeting.cfm 문서의 내용이 포함되어 있습니다.

<cfif NOT IsDefined("Form.name") OR Len(Trim(Form.Name)) EQ 0> 
    <cfset Form.Name = "Stranger" /> 
</cfif> 
<cfoutput>welcomeMessage=#UrlEncodedFormat("Welcome, " & Form.name)# 
</cfoutput>