네트워킹 및 통신의 기초

NetworkInfo 객체를 사용하면 응용 프로그램에서 사용할 수 있는 하드웨어 및 소프트웨어 네트워크 인터페이스를 검색할 수 있습니다. NetworkInfo 객체는 단일 객체이므로 만들 필요가 없습니다. 대신 정적 클래스 속성인 networkInfo를 사용하여 단일 NetworkInfo 객체에 액세스하십시오. NetworkInfo 객체는 또한 사용 가능한 인터페이스 중 하나가 변경되는 경우에도 networkChange 이벤트를 전달합니다.

NetworkInterface 객체 목록을 가져오려면 findInterfaces() 메서드를 호출합니다. 목록에 있는 각 NetworkInterface 객체는 사용 가능한 인터페이스 중 하나를 설명합니다. NetworkInterface 객체는 IP 주소, 하드웨어 주소, 최대 전송 단위 및 인터페이스의 활성 여부와 같은 정보를 제공합니다.

다음 코드 예제에서는 클라이언트 컴퓨터의 각 인터페이스에 대한 NetworkInterface 속성을 추적합니다.

package { 
import flash.display.Sprite; 
import flash.net.InterfaceAddress; 
import flash.net.NetworkInfo; 
import flash.net.NetworkInterface; 
 
public class NetworkInformationExample extends Sprite 
{ 
    public function NetworkInformationExample() 
    { 
        var networkInfo:NetworkInfo = NetworkInfo.networkInfo; 
        var interfaces:Vector.<NetworkInterface> = networkInfo.findInterfaces(); 
         
        if( interfaces != null ) 
        { 
            trace( "Interface count: " + interfaces.length ); 
            for each ( var interfaceObj:NetworkInterface in interfaces ) 
            { 
                trace( "\nname: "             + interfaceObj.name ); 
                trace( "display name: "     + interfaceObj.displayName ); 
                trace( "mtu: "                 + interfaceObj.mtu ); 
                trace( "active?: "             + interfaceObj.active ); 
                trace( "parent interface: " + interfaceObj.parent ); 
                trace( "hardware address: " + interfaceObj.hardwareAddress ); 
                if( interfaceObj.subInterfaces != null ) 
                { 
                    trace( "# subinterfaces: " + interfaceObj.subInterfaces.length ); 
                } 
                trace("# addresses: "     + interfaceObj.addresses.length ); 
                for each ( var address:InterfaceAddress in interfaceObj.addresses ) 
                { 
                    trace( "  type: "           + address.ipVersion ); 
                    trace( "  address: "         + address.address ); 
                    trace( "  broadcast: "         + address.broadcast ); 
                    trace( "  prefix length: "     + address.prefixLength ); 
                } 
            }             
        } 
    }     
} 
}

자세한 내용은 다음 항목을 참조하십시오.

• NetworkInfo

• NetworkInterface

• InterfaceAddress

AIR 응용 프로그램은 네트워크 연결이 확실하지 않고 변경되는 환경에서 실행될 수 있습니다. 응용 프로그램에서 온라인 리소스에 대한 연결을 관리하는 것을 지원하기 위해 Adobe AIR은 네트워크 연결을 사용할 수 있게 되거나 사용할 수 없게 될 때마다 네트워크 변경 이벤트를 보냅니다. NetworkInfo 객체 및 응용 프로그램의 NativeApplication 객체는 모두 networkChange 이벤트를 전달합니다. 이 이벤트에 응답하려면 리스너를 추가합니다.

NetworkInfo.networkInfo.addEventListener(Event.NETWORK_CHANGE, onNetworkChange); 

그런 다음 이벤트 핸들러 함수를 정의합니다.

function onNetworkChange(event:Event) 
{ 
    //Check resource availability 
} 

networkChange 이벤트는 모든 네트워크 활동의 변경을 나타내지는 않으며 개별 네트워크 연결이 변경된 것만 나타냅니다. AIR에서는 네트워크 변경의 의미를 해석하려고 하지 않습니다. 네트워크에 연결된 컴퓨터에는 많은 실제 연결과 가상 연결이 있을 수 있으므로 연결이 손실되어도 리소스가 반드시 손실되지는 않습니다. 반면에 새로운 연결은 향상된 리소스 가용성을 보장하지 않습니다. 새 연결이 이전에 사용할 수 있던 리소스에 대한 액세스를 차단하는 경우도 있습니다(예: VPN에 연결하는 경우).

일반적으로 응용 프로그램에서 원격 리소스에 연결할 수 있는지 확인하는 유일한 방법은 연결을 시도하는 것입니다. 서비스 모니터링 프레임워크는 지정된 호스트에 대한 네트워크 연결이 변경되는 경우 적용할 수 있는 이벤트 기반 응답 방법을 제공합니다.

DNSResolver 클래스를 사용하여 DNS 리소스 레코드를 조회할 수 있습니다. DNS 리소스 레코드는 도메인 이름의 IP 주소 및 IP 주소의 도메인 이름과 같은 정보를 제공합니다. 다음과 같은 DNS 리소스 레코드의 유형을 조회할 수 있습니다.

• ARecord - 호스트의 IPv4 주소입니다.

• AAAARecord - 호스트의 IPv6 주소입니다.

• MXRecord - 호스트의 메일 교환 레코드입니다.

• PTRRecord - IP 주소의 호스트 이름입니다.

• SRVRecord - 서비스에 대한 서비스 레코드입니다.

레코드를 조회하려면 쿼리 문자열과 레코드 유형을 나타내는 클래스 객체를 DNSResolver 객체의 lookup() 메서드에 전달합니다. 사용할 쿼리 문자열은 레코드 유형에 따라 달라집니다.

다음 코드 예제에서는 “example.com” 호스트의 IP 주소를 조회합니다.

package 
{ 
    import flash.display.Sprite; 
    import flash.events.DNSResolverEvent; 
    import flash.events.ErrorEvent; 
    import flash.net.dns.ARecord; 
    import flash.net.dns.DNSResolver; 
 
    public class DNSResolverExample extends Sprite 
    { 
         
        public function DNSResolverExample() 
        { 
            var resolver:DNSResolver = new DNSResolver(); 
            resolver.addEventListener( DNSResolverEvent.LOOKUP, lookupComplete ); 
            resolver.addEventListener( ErrorEvent.ERROR, lookupError ); 
 
            resolver.lookup( "example.com.", ARecord ); 
        } 
         
        private function lookupComplete( event:DNSResolverEvent ):void 
        { 
            trace( "Query string: " + event.host ); 
            trace( "Record count: " + event.resourceRecords.length ); 
            for each( var record:* in event.resourceRecords ) 
            { 
                if( record is ARecord ) trace( record.address ); 
            } 
             
        } 
 
        private function lookupError( error:ErrorEvent ):void 
        { 
            trace("Error: " + error.text ); 
        } 
    } 
}

자세한 내용은 다음 항목을 참조하십시오.

• DNSResolver

• DNSResolverEvent

• ARecord

• AAAARecord

• MXRecord

• PTRRecord

• SRVRecord