보호된 내용 작업 과정 이해

다음 단계에서는 DRMContentData 객체를 사용하여 보호된 미디어 파일에 대한 바우처를 미리 로드하는 작업 과정에 대해 설명합니다.

1. 패키지화된 내용에 대한 이진 메타데이터를 가져옵니다. Adobe Access Java Reference Packager를 사용하는 경우 이 메타데이터 파일이 .metadata 확장자를 사용하여 자동으로 생성됩니다. URLLoader 클래스를 사용하여 예를 들어 이 메타데이터를 다운로드할 수 있습니다.

2. DRMContentData 객체를 만들어 메타데이터를 생성자 함수에 전달합니다.

   var drmData:DRMContentData = new DRMContentData( metadata );

3. 나머지 작업 과정은 보호된 내용 작업 과정 이해 에서 설명한 작업 단계와 동일합니다.

다음 단계에서는 preloadEmbeddedMetadata() 를 사용하여 DRM으로 보호된 미디어 파일에 대한 바우처를 미리 로드하는 작업 과정에 대해 설명합니다.

1. 미디어 파일을 다운로드하고 저장합니다. DRM 메타데이터는 로컬로 저장된 파일에서만 미리 로드할 수 있습니다.

2. NetConnection 및 NetStream 객체를 만들어 NetStream 클라이언트 객체의 onDRMContentData() 및 onPlayStatus() 콜백 함수에 대한 구현을 제공합니다.

3. NetStreamPlayOptions 객체를 만들고 stream 속성을 로컬 미디어 파일의 URL로 설정합니다.

4. NetStream preloadEmbeddedMetadata() 를 호출하여 파싱할 미디어 파일을 식별하는 NetStreamPlayOptions 객체를 전달합니다.

5. 미디어 파일에 DRM 메타데이터가 포함되어 있는 경우에는 onDRMContentData() 콜백 함수가 호출됩니다. 메타데이터는 이 함수에 DRMContentData 객체로 전달됩니다.

6. DRMContentData 객체를 사용하여 DRMManager loadVoucher() 메서드를 통해 바우처를 가져옵니다.

   DRMContentData 객체의 authenticationMethod 속성 값이 flash.net.drm.AuthenticationMethod.USERNAME_AND_PASSWORD 인 경우에는 바우처를 로드하기 전에 미디어 권한 서버에서 사용자를 인증해야 합니다. DRMContentData 객체의 serverURL 및 domain 속성은 사용자의 자격 증명과 함께 DRMManager authenticate() 메서드로 전달할 수 있습니다.

7. 파일 파싱이 완료되면 onPlayStatus() 콜백 함수가 호출됩니다. onDRMContentData() 함수가 호출되지 않은 경우에는 파일에 바우처를 가져오는 데 필요한 메타데이터가 포함되지 않습니다. 이 호출이 누락되었다는 것은 Adobe Access가 이 파일을 보호하지 않는다는 것을 의미할 수도 있습니다.

AIR에 대한 다음 코드 예제에서는 로컬 미디어 파일에 대한 바우처를 미리 로드하는 방법을 보여 줍니다.

package 
{ 
import flash.display.Sprite; 
import flash.events.DRMAuthenticationCompleteEvent; 
import flash.events.DRMAuthenticationErrorEvent; 
import flash.events.DRMErrorEvent;   
import flash.ev ents.DRMStatusEvent; 
import flash.events.NetStatusEvent; 
import flash.net.NetConnection; 
import flash.net.NetStream; 
import flash.net.NetStreamPlayOptions; 
import flash.net.drm.AuthenticationMethod; 
import flash.net.drm.DRMContentData; 
import flash.net.drm.DRMManager; 
import flash.net.drm.LoadVoucherSetting;   
public class DRMPreloader extends Sprite  
{ 
     private var videoURL:String = "app-storage:/video.flv"; 
    private var userName:String = "user"; 
    private var password:String = "password";  
    private var preloadConnection:NetConnection; 
    private var preloadStream:NetStream; 
    private var drmManager:DRMManager = DRMManager.getDRMManager(); 
    private var drmContentData:DRMContentData; 
    public function DRMPreloader():void { 
        drmManager.addEventListener( 
            DRMAuthenticationCompleteEvent.AUTHENTICATION_COMPLETE, 
            onAuthenticationComplete); 
        drmManager.addEventListener(DRMAuthenticationErrorEvent.AUTHENTICATION_ERROR, 
            onAuthenticationError);             
        drmManager.addEventListener(DRMStatusEvent.DRM_STATUS, onDRMStatus); 
        drmManager.addEventListener(DRMErrorEvent.DRM_ERROR, onDRMError); 
        preloadConnection = new NetConnection(); 
        preloadConnection.addEventListener(NetStatusEvent.NET_STATUS, onConnect); 
        preloadConnection.connect(null);            
    } 
 
    private function onConnect( event:NetStatusEvent ):void 
    { 
        preloadMetadata(); 
    } 
    private function preloadMetadata():void 
    { 
        preloadStream = new NetStream( preloadConnection ); 
        preloadStream.client = this; 
        var options:NetStreamPlayOptions = new NetStreamPlayOptions(); 
        options.streamName = videoURL; 
        preloadStream.preloadEmbeddedData( options );                         
    }     
    public function onDRMContentData( drmMetadata:DRMContentData ):void 
    { 
        drmContentData = drmMetadata; 
        if ( drmMetadata.authenticationMethod == AuthenticationMethod.USERNAME_AND_PASSWORD ) 
        { 
            authenticateUser(); 
        } 
        else 
            { 
                getVoucher(); 
            } 
    } 
    private function getVoucher():void 
    { 
        drmManager.loadVoucher( drmContentData, LoadVoucherSetting.ALLOW_SERVER ); 
    } 
 
    private function authenticateUser():void 
    { 
        drmManager.authenticate( drmContentData.serverURL, drmContentData.domain, userName, password ); 
    } 
    private function onAuthenticationError( event:DRMAuthenticationErrorEvent ):void 
    { 
        trace( "Authentication error: " + event.errorID + ", " + event.subErrorID ); 
    } 
 
    private function onAuthenticationComplete( event:DRMAuthenticationCompleteEvent ):void 
    { 
        trace( "Authenticated to: " + event.serverURL + ", domain: " + event.domain ); 
        getVoucher(); 
    } 
    private function onDRMStatus( event:DRMStatusEvent ):void 
    { 
        trace( "DRM Status: " + event.detail); 
        trace("--Voucher allows offline playback = " + event.isAvailableOffline ); 
        trace("--Voucher already cached          = " + event.isLocal ); 
        trace("--Voucher required authentication = " + !event.isAnonymous ); 
    } 
    private function onDRMError( event:DRMErrorEvent ):void 
    { 
        trace( "DRM error event: " + event.errorID + ", " + event.subErrorID + ", " + event.text ); 
    } 
    public function onPlayStatus( info:Object ):void 
    { 
        preloadStream.close(); 
    } 
} 
}