ComboBox 구성 요소 사용

다음 예제에서는 ActionScript로 ComboBox를 만들어 미국 캘리포니아주 샌프란시스코 지역에 있는 대학 목록으로 채웁니다. 그런 다음 ComboBox의 width 속성을 프롬프트 텍스트 폭에 맞는 크기로 설정하고 dropdownWidth 속성을 가장 긴 대학 이름보다 약간 넓게 설정합니다.

이 예제에서는 학교 이름을 저장하는 데 label 속성을, 학교의 웹 사이트 URL을 저장하는 데 data 속성을 사용하여 Array 인스턴스에 대학 목록을 만듭니다. 그런 다음 ComboBox의 dataProvider 속성을 설정하여 ComboBox에 Array를 지정합니다.

사용자가 목록에서 대학을 선택하면 Event. CHANGE 이벤트가 트리거되고 changeHandler() 함수가 호출되어 data 속성이 URL 요청에 로드되므로 결과적으로 학교의 웹 사이트에 액세스할 수 있게 됩니다.

마지막 행에서는 ComboBox 인스턴스의 selectedIndex 속성을 -1로 설정하여 목록이 닫힐 때 확인 대화 상자가 다시 표시되게 합니다. 이 행이 없으면 선택한 학교의 이름이 대신 표시됩니다.

1. 새 Flash(ActionScript 3.0) 문서를 만듭니다.

2. [구성 요소] 패널의 ComboBox 구성 요소를 [라이브러리] 패널로 드래그합니다.

3. [액션] 패널을 열고 기본 타임라인에서 프레임 1을 선택한 후 다음 ActionScript 코드를 입력합니다.

   import fl.controls.ComboBox; 
   import fl.data.DataProvider; 
   import flash.net.navigateToURL; 
    
   var sfUniversities:Array = new Array( 
       {label:"University of California, Berkeley",  
                   data:"http://www.berkeley.edu/"}, 
       {label:"University of San Francisco",  
                   data:"http://www.usfca.edu/"}, 
       {label:"San Francisco State University",  
                   data:"http://www.sfsu.edu/"}, 
       {label:"California State University, East Bay",  
                   data:"http://www.csuhayward.edu/"}, 
       {label:"Stanford University", data:"http://www.stanford.edu/"}, 
       {label:"University of Santa Clara", data:"http://www.scu.edu/"}, 
       {label:"San Jose State University", data:"http://www.sjsu.edu/"} 
   ); 
    
   var aCb:ComboBox = new ComboBox(); 
   aCb.dropdownWidth = 210; 
   aCb.width = 200;  
   aCb.move(150, 50); 
   aCb.prompt = "San Francisco Area Universities"; 
   aCb.dataProvider = new DataProvider(sfUniversities); 
   aCb.addEventListener(Event.CHANGE, changeHandler); 
    
   addChild(aCb); 
    
   function changeHandler(event:Event):void { 
       var request:URLRequest = new URLRequest(); 
       request.url = ComboBox(event.target).selectedItem.data; 
       navigateToURL(request); 
       aCb.selectedIndex = -1; 
   }

4. [컨트롤] > [무비 테스트]를 선택합니다.

Flash 제작 환경에서 이 예제를 구현하고 실행할 수는 있지만 ComboBox에서 항목을 클릭하여 대학 웹 사이트에 액세스하려고 하면 경고 메시지가 나타납니다. 인터넷에서 기능을 제대로 갖춘 ComboBox에 액세스하려면 다음 위치에 액세스하십시오.

http://www.helpexamples.com/peter/bayAreaColleges/bayAreaColleges.html