List 구성 요소 사용

새 Flash(ActionScript 3.0) 문서를 만듭니다.

[구성 요소] 패널의 List 구성 요소를 스테이지로 드래그합니다.

속성 관리자에서 다음을 수행합니다.

• 인스턴스 이름으로 aList 를 입력합니다.

• W(폭) 값을 200 으로 지정합니다.

[텍스트 도구]를 사용하여 aList 아래에 텍스트 필드를 만들고 인스턴스 이름을 aTf 로 지정합니다.

[액션] 패널을 열고 기본 타임라인에서 프레임 1을 선택한 후 다음 ActionScript 코드를 입력합니다.

import fl.controls.List; 
import flash.text.TextField; 
 
aTf.type = TextFieldType.DYNAMIC; 
aTf.border = false; 
 
// Create these items in the Property inspector when data and label 
// parameters are available. 
aList.addItem({label:"1956 Chevy (Cherry Red)", data:35000}); 
aList.addItem({label:"1966 Mustang (Classic)", data:27000}); 
aList.addItem({label:"1976 Volvo (Xcllnt Cond)", data:17000}); 
aList.allowMultipleSelection = true; 
 
aList.addEventListener(Event.CHANGE, showData); 
 
function showData(event:Event) { 
    aTf.text = "This car is priced at: $" + event.target.selectedItem.data; 
}

이 코드에서는 addItem() 메서드를 사용하여 세 가지 항목으로 aList 를 채우고, 목록에 표시되는 label 값과 data 값을 각 항목에 지정합니다. List에서 항목을 선택하면 이벤트 리스너가 showData() 함수를 호출하여 선택한 항목의 data 값을 표시합니다.

[컨트롤] > [무비 테스트]를 선택하여 응용 프로그램을 컴파일하고 실행합니다.

새 Flash(ActionScript 3.0) 문서를 만듭니다.

[구성 요소] 패널의 List 구성 요소를 스테이지로 드래그합니다.

속성 관리자에서 다음을 수행합니다.

• 인스턴스 이름으로 aList 를 입력합니다.

• W(폭) 값을 200 으로 지정합니다.

[텍스트 도구]를 사용하여 aList 아래에 텍스트 필드를 만들고 인스턴스 이름을 aTf 로 지정합니다.

[액션] 패널을 열고 기본 타임라인에서 프레임 1을 선택한 후 다음 ActionScript 코드를 입력합니다.

import fl.controls.List; 
import fl.data.DataProvider; 
import flash.text.TextField; 
 
aTf.type = TextFieldType.DYNAMIC; 
aTf.border = false; 
 
var cars:Array = [ 
{label:"1956 Chevy (Cherry Red)", data:35000}, 
{label:"1966 Mustang (Classic)", data:27000}, 
{label:"1976 Volvo (Xcllnt Cond)", data:17000}, 
]; 
aList.dataProvider = new DataProvider(cars); 
aList.allowMultipleSelection = true; 
 
aList.addEventListener(Event.CHANGE, showData); 
 
function showData(event:Event) { 
    aTf.text = "This car is priced at: $" + event.target.selectedItem.data; 
}

[컨트롤] > [무비 테스트]를 선택하여 List와 해당 항목을 봅니다.

Flash(ActionScript 3.0) 문서를 만듭니다.

[구성 요소] 패널의 List 구성 요소를 스테이지로 드래그하고 속성 관리자에서 다음 값을 지정합니다.

• 인스턴스 이름으로 aList 를 입력합니다.

• H 값으로 60 을 입력합니다.

• X 값으로 100 를 입력합니다.

• Y 값으로 150 을 입력합니다.

[액션] 패널을 열고 기본 타임라인에서 프레임 1을 선택한 후 다음 ActionScript 코드를 입력합니다.

aList.addItem({label:"Blue", data:0x0000CC}); 
aList.addItem({label:"Green", data:0x00CC00}); 
aList.addItem({label:"Yellow", data:0xFFFF00}); 
aList.addItem({label:"Orange", data:0xFF6600}); 
aList.addItem({label:"Black", data:0x000000}); 
 
var aBox:MovieClip = new MovieClip(); 
addChild(aBox); 
 
aList.addEventListener(Event.CHANGE, changeHandler); 
function changeHandler(event:Event) { 
    drawBox(aBox, event.target.selectedItem.data); 
}; 
 
function drawBox(box:MovieClip,color:uint):void { 
            box.graphics.beginFill(color, 1.0); 
            box.graphics.drawRect(225, 150, 100, 100); 
            box.graphics.endFill();         
}

[컨트롤] > [무비 테스트]를 선택하여 응용 프로그램을 실행합니다.

List에서 색상을 클릭하여 MovieClip에 표시되는지 확인합니다.

새 Flash(ActionScript 3.0) 문서를 만듭니다.

[구성 요소] 패널의 List 구성 요소를 [라이브러리] 패널로 드래그합니다.

[액션] 패널을 열고 기본 타임라인에서 프레임 1을 선택한 후 다음 ActionScript 코드를 입력합니다.

import fl.controls.List; 
 
var aList:List = new List(); 
aList.addItem({label:"One", data:1}); 
aList.addItem({label:"Two", data:2}); 
aList.addItem({label:"Three", data:3}); 
aList.addItem({label:"Four", data:4}); 
aList.addItem({label:"Five", data:5}); 
aList.setSize(60, 40); 
aList.move(200,200); 
addChild(aList); 
aList.addEventListener(Event.CHANGE, changeHandler); 
function changeHandler(event:Event):void { 
    trace(event.target.selectedItem.data); 
}

[컨트롤] > [무비 테스트]를 선택하여 응용 프로그램을 실행합니다.