ProgressBar 구성 요소 사용

새 Flash(ActionScript 3.0) 문서를 만듭니다.

[구성 요소] 패널의 ProgressBar 구성 요소를 스테이지로 드래그하고 속성 관리자에서 다음 값을 입력합니다.

• 인스턴스 이름으로 aPb 를 입력합니다.

• X 값으로 185 를 입력합니다.

• Y 값으로 225 을 입력합니다.

Label 구성 요소를 스테이지로 드래그하고 속성 관리자에서 다음 값을 입력합니다.

• 인스턴스 이름으로 progLabel 을 입력합니다.

• X 값으로 180 를 입력합니다.

• Y 값으로 180 을 입력합니다.

• [매개 변수] 섹션에서 text 매개 변수 값을 지웁니다.

[액션] 패널을 열고 기본 타임라인에서 프레임 1을 선택한 후 다음 ActionScript 코드를 입력합니다. 이 코드는 Sound 객체( aSound )를 만들고 loadSound() 를 호출하여 Sound 객체에 사운드를 로드합니다.

import fl.controls.ProgressBarMode; 
import flash.events.ProgressEvent; 
import flash.media.Sound; 
 
var aSound:Sound = new Sound(); 
var url:String = "http://www.helpexamples.com/flash/sound/song1.mp3"; 
var request:URLRequest = new URLRequest(url); 
 
aPb.mode = ProgressBarMode.POLLED; 
aPb.source = aSound; 
aSound.addEventListener(ProgressEvent.PROGRESS, loadListener); 
 
aSound.load(request); 
 
function loadListener(event:ProgressEvent) { 
    var percentLoaded:int = event.target.bytesLoaded / event.target.bytesTotal * 100; 
    progLabel.text = "Percent loaded: " + percentLoaded + "%"; 
    trace("Percent loaded: " + percentLoaded + "%"); 
}

[컨트롤] > [무비 테스트]를 선택하여 응용 프로그램을 실행합니다.

새 Flash(ActionScript 3.0) 문서를 만듭니다.

[구성 요소] 패널의 ProgressBar 구성 요소를 스테이지로 드래그하고 속성 관리자에서 다음 값을 지정합니다.

• 인스턴스 이름으로 aPb 를 입력합니다.

• X 값으로 180 를 입력합니다.

• Y 값으로 175 을 입력합니다.

NumericStepper 구성 요소를 스테이지로 드래그하고 속성 관리자에서 다음 값을 입력합니다.

• 인스턴스 이름으로 aNs 를 입력합니다.

• X 값으로 220 를 입력합니다.

• Y 값으로 215 을 입력합니다.

• [매개 변수] 섹션에서 maximum 매개 변수로 250 , minimum 매개 변수로 0 , stepSize 매개 변수로 1 , value 매개 변수로 0 을 입력합니다.

Label 구성 요소를 스테이지로 드래그하고 속성 관리자에서 다음 값을 입력합니다.

• 인스턴스 이름으로 progLabel 을 입력합니다.

• W 값으로 150 을 입력합니다.

• X 값으로 180 를 입력합니다.

• Y 값으로 120 을 입력합니다.

• [매개 변수] 탭에서 Label의 text 매개 변수 값을 지웁니다.

[액션] 패널을 열고 기본 타임라인에서 프레임 1을 선택한 후 다음 코드를 입력합니다.

import fl.controls.ProgressBarDirection; 
import fl.controls.ProgressBarMode; 
import flash.events.Event; 
 
aPb.direction = ProgressBarDirection.RIGHT; 
aPb.mode = ProgressBarMode.MANUAL; 
aPb.minimum = aNs.minimum; 
aPb.maximum = aNs.maximum; 
aPb.indeterminate = false; 
 
aNs.addEventListener(Event.CHANGE, nsChangeHandler); 
 
function nsChangeHandler(event:Event):void { 
    aPb.value = aNs.value; 
    aPb.setProgress(aPb.value, aPb.maximum); 
progLabel.text = "Percent of progress = " + int(aPb.percentComplete) + "%"; 
}

[컨트롤] > [무비 테스트]를 선택하여 응용 프로그램을 실행합니다.

NumericStepper에서 위쪽 화살표를 클릭하여 ProgressBar를 진행시킵니다.

새 Flash(ActionScript 3.0) 문서를 만듭니다.

ProgressBar 구성 요소를 [라이브러리] 패널로 드래그합니다.

NumericStepper 구성 요소를 [라이브러리] 패널로 드래그합니다.

Label 구성 요소를 [라이브러리] 패널로 드래그합니다.

[액션] 패널을 열고 기본 타임라인에서 프레임 1을 선택한 후 다음 코드를 입력합니다.

import fl.controls.ProgressBar; 
import fl.controls.NumericStepper; 
import fl.controls.Label; 
import fl.controls.ProgressBarDirection; 
import fl.controls.ProgressBarMode; 
import flash.events.Event; 
 
var aPb:ProgressBar = new ProgressBar(); 
var aNs:NumericStepper = new NumericStepper(); 
var progLabel:Label = new Label(); 
 
addChild(aPb); 
addChild(aNs); 
addChild(progLabel); 
 
aPb.move(180,175); 
aPb.direction = ProgressBarDirection.RIGHT; 
aPb.mode = ProgressBarMode.MANUAL; 
 
progLabel.setSize(150, 22); 
progLabel.move(180, 150); 
progLabel.text = ""; 
 
aNs.move(220, 215); 
aNs.maximum = 250; 
aNs.minimum = 0; 
aNs.stepSize = 1; 
aNs.value = 0; 
 
aNs.addEventListener(Event.CHANGE, nsChangeHandler); 
 
function nsChangeHandler(event:Event):void { 
aPb.setProgress(aNs.value, aNs.maximum); 
progLabel.text = "Percent of progress = " + int(aPb.percentComplete) + "%"; 
}

[컨트롤] > [무비 테스트]를 선택하여 응용 프로그램을 실행합니다.

NumericStepper에서 위쪽 화살표를 클릭하여 ProgressBar를 진행시킵니다.