StorageVolume

패키지	flash.filesystem
클래스	public class StorageVolume
상속	StorageVolume Object

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 2

StorageVolume 객체는 대용량 저장소 볼륨을 정의하는 속성을 포함합니다. 이 클래스는 다음 두 가지 방식으로 사용됩니다.

StorageVolumeChangeEvent 객체의 storageVolume 속성은 StorageVolume 객체입니다. 이 객체는 마운트되거나 마운트 해제된 저장소 볼륨을 나타냅니다.
StorageVolumeInfo.storageVolumeInfo.getStorageVolumes() 메서드는 StorageVolume 객체의 벡터를 반환합니다. 이러한 각 StorageVolume 객체는 마운트된 저장소 볼륨을 나타냅니다.

예제 보기

	속성	정의 주체
		constructor : Object 지정된 객체 인스턴스의 클래스 객체 또는 생성자 함수에 대한 참조입니다.	Object
		drive : String [읽기 전용] Windows의 볼륨 드라이브 문자입니다.	StorageVolume
		fileSystemType : String [읽기 전용] 저장소 볼륨에 있는 파일 시스템의 유형입니다(예: "FAT", "NTFS", "HFS", "UFS").	StorageVolume
		isRemovable : Boolean [읽기 전용] 운영 체제가 저장소 볼륨을 제거할 수 있다고 보는지(true) 없다고 보는지(false) 여부입니다.	StorageVolume
		isWritable : Boolean [읽기 전용] 볼륨에 쓸 수 있는지(true) 아니면 쓸 수 없는지(false)입니다.	StorageVolume
		name : String [읽기 전용] 볼륨의 이름입니다.	StorageVolume
		rootDirectory : File [읽기 전용] 볼륨의 루트 디렉토리에 해당하는 File 객체입니다.	StorageVolume

	메서드	정의 주체
		StorageVolume(rootDirPath:File, name:String, writable:Boolean, removable:Boolean, fileSysType:String, drive:String) 생성자 함수입니다.	StorageVolume
		hasOwnProperty(name:String):Boolean 지정된 속성이 객체에 정의되어 있는지 여부를 나타냅니다.	Object
		isPrototypeOf(theClass:Object):Boolean Object 클래스의 인스턴스가 매개 변수로 지정된 객체의 프로토타입 체인에 있는지 여부를 나타냅니다.	Object
		propertyIsEnumerable(name:String):Boolean 지정된 속성이 존재하고 열거 가능한지 여부를 나타냅니다.	Object
		setPropertyIsEnumerable(name:String, isEnum:Boolean = true):void 루프 작업에서 동적 속성을 사용할 수 있는지 여부를 설정합니다.	Object
		toLocaleString():String 로캘별 규칙에 따라 서식이 지정된 이 객체의 문자열 표현을 반환합니다.	Object
		toString():String 지정된 객체의 문자열 표현을 반환합니다.	Object
		valueOf():Object 지정된 객체의 프리미티브 값을 반환합니다.	Object

drive

속성

drive:String [읽기 전용]

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 2

Windows의 볼륨 드라이브 문자입니다. 다른 플랫폼에서 이 속성은 null로 설정됩니다.

구현
public function get drive():String

fileSystemType

속성

fileSystemType:String [읽기 전용]

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 2

저장소 볼륨에 있는 파일 시스템의 유형입니다(예: "FAT", "NTFS", "HFS", "UFS").

구현
public function get fileSystemType():String

예제 ( 예제 사용 방법 )

다음 코드는 마운트된 각 저장소 볼륨의 루트 디렉토리에 대한 기본 경로와 파일 시스템 유형을 나열합니다.

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    trace(volumes[i].rootDirectory.nativePath, "(" + volumes[i].fileSystemType + ")");
}

isRemovable

속성

isRemovable:Boolean [읽기 전용]

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 2

운영 체제가 저장소 볼륨을 제거할 수 있다고 보는지(true) 없다고 보는지(false) 여부입니다.

다음 표에는 다양한 장치 유형에 대한 StorageVolume.isRemovable 값이 나와 있습니다.

장치 유형	Mac OS	Windows	Linux
CD/DVD(고정)	true	true	true
USB 플래시 드라이브	true	true	true
USB 하드 드라이브	false	false	true
FireWire 하드 드라이브	false	false	true
공유 볼륨	true	false	- ¹
네트워크 드라이브	false	false	false
저장소 카드 판독기(비어 있음)	- ²	false	- ²
저장소 카드 판독기(SD/CF 카드 포함)	true	true	true

¹ Linux에는 공유 볼륨 개념이 없습니다.

² Windows에서 비어 있는 카드 판독기는 제거할 수 없는 장치로 나열됩니다. Mac OS 및 Linux에서 비어 있는 카드 판독기는 저장소 볼륨으로 나열되지 않습니다.

구현
public function get isRemovable():Boolean

예제 ( 예제 사용 방법 )

다음 코드는 제거할 수 없는 저장소 볼륨의 목록을 출력한 후 제거할 수 있는 저장소 볼륨의 목록을 출력합니다.

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();

trace("Non-removeable volumes:");
for (var i:int = 0; i < volumes.length; i++)
{
    if (!volumes[i].isRemovable)
    {
        trace(volumes[i].rootDirectory.nativePath);
    }
}

trace("\nRemoveable volumes:");
for (i = 0; i < volumes.length; i++)
{
    if (volumes[i].isRemovable)
    {
        trace(volumes[i].rootDirectory.nativePath);
    }
}

isWritable

속성

isWritable:Boolean [읽기 전용]

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 2

볼륨에 쓸 수 있는지(true) 아니면 쓸 수 없는지(false)입니다.

참고: StorageVolume 객체의 rootDirectory.spaceAvailble 속성을 호출하여 볼륨에서 사용할 수 있는 공간의 양을 확인할 수 있습니다.

구현
public function get isWritable():Boolean

name

속성

name:String [읽기 전용]

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 2

볼륨의 이름입니다. 이름이 없는 경우 이 속성은 null로 설정됩니다.

구현
public function get name():String

예제 ( 예제 사용 방법 )

다음 코드는 마운트된 각 저장소 볼륨의 루트 디렉토리에 대한 기본 경로와 파일 시스템 이름(있는 경우)을 나열합니다.

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    var name:String = new String();
    if (volumes[i].name)
    {
        name = "(" + volumes[i].name + ")";
    }
    trace(volumes[i].rootDirectory.nativePath, name);
}

rootDirectory

속성

rootDirectory:File [읽기 전용]

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 2

볼륨의 루트 디렉토리에 해당하는 File 객체입니다.

구현
public function get rootDirectory():File

예제 ( 예제 사용 방법 )

다음 코드는 마운트된 각 저장소 볼륨의 루트 디렉토리에 대한 기본 경로를 나열합니다.

var volumes:Vector.<StorageVolume> = new Vector.<StorageVolume>;
volumes = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
for (var i:int = 0; i < volumes.length; i++)
{
    trace(volumes[i].rootDirectory.nativePath);
}

생성자 세부 정보

()

생성자

public function StorageVolume(rootDirPath:File, name:String, writable:Boolean, removable:Boolean, fileSysType:String, drive:String)

언어 버전:

ActionScript 3.0

런타임 버전:

AIR 2

생성자 함수입니다. 일반적으로 (새 StorageVolume 객체를 만들기 위해) 이 생성자 함수를 직접 호출하지 않습니다. 대신, StorageVolumeChangeEvent 객체의 storageVolume 속성에 액세스하거나 StorageVolumeInfo.storageVolumeInfo.getStorageVolumes()를 호출하여 StorageVolume 객체를 참조합니다.

매개 변수

	`rootDirPath:File`

	`name:String`

	`writable:Boolean`

	`removable:Boolean`

	`fileSysType:String`

	`drive:String`

예제 예제 사용 방법

StorageVolumeExample.as

다음 코드는 마운트된 각 저장소 볼륨의 속성을 나열합니다.

package
{
    import flash.display.Sprite;
    import flash.filesystem.StorageVolume;
    import flash.filesystem.StorageVolumeInfo;

    public class StorageVolumeExample extends Sprite
    {
        public function StorageVolumeExample()
        {
            var volumes:Vector.<StorageVolume> = StorageVolumeInfo.storageVolumeInfo.getStorageVolumes();
            for (var i:int = 0; i < volumes.length; i++)
            {
                var volume:StorageVolume = volumes[i];
                trace("nativePath:", volume.rootDirectory.nativePath);
                trace("fileSystemType:", volume.fileSystemType);
                trace("isRemovable:", volume.isRemovable);
                trace("isWritable:", volume.isWritable);
                trace("drive:", volume.drive);
                trace("name:", volume.name);
                trace("________________________________________________________");
            }
        }
    }
}

StorageVolumeChangeEventExample.as

다음 코드는 마운트 또는 마운트 해제된 각 저장소 볼륨의 속성을 나열합니다. StorageVolumeChangeEvent의 storageVolume 속성은 storageVolumeMount 이벤트에 대해서만 설정됩니다. storageVolumeUnmount 이벤트에 대해서는 이 속성이 null입니다.

package
{
    import flash.display.Sprite;
    import flash.events.StorageVolumeChangeEvent;
    import flash.filesystem.StorageVolume;
    import flash.filesystem.StorageVolumeInfo;

    public class StorageVolumeChangeEventExample extends Sprite
    {
        public function StorageVolumeChangeEventExample()
        {
            StorageVolumeInfo.storageVolumeInfo.addEventListener(StorageVolumeChangeEvent.STORAGE_VOLUME_MOUNT, mountEventHandler);
            StorageVolumeInfo.storageVolumeInfo.addEventListener(StorageVolumeChangeEvent.STORAGE_VOLUME_UNMOUNT, unmountEventHandler);
        }
        public function mountEventHandler(event:StorageVolumeChangeEvent):void
        {            
            var volume:StorageVolume = event.storageVolume;
            trace("VOLUME MOUNTED:");
            trace("nativePath:", event.rootDirectory.nativePath);
            trace("fileSystemType:", volume.fileSystemType);
            trace("isRemovable:", volume.isRemovable);
            trace("isWritable:", volume.isWritable);
            trace("drive:", volume.drive);
            trace("name:", volume.name);
            trace();
        }
        public function unmountEventHandler(event:StorageVolumeChangeEvent):void
        {            
            trace("VOLUME UNMOUNTED:");
            trace("nativePath:", event.rootDirectory.nativePath);
            trace();
        }        
    }
}

법적 고지 사항 | 온라인 개인 정보 보호 정책

StorageVolume - AS3

클래스 x

drive

fileSystemType

isRemovable

isWritable

name

rootDirectory

StorageVolume