アプリケーション表示の変更の処理

AIR では、アプリケーション記述子の softKeyboardBehavior エレメントを none ·に設定して、ソフトキーボードの表示に関連するデフォルトのパンおよびサイズ変更の動作を無効にすることができます。

<softKeyboardBehavior>none</softKeyboardBehavior>

自動的な動作を無効にした場合は、アプリケーション表示に対する必要な調整をアプリケーションで行う必要があります。キーボードが開くと、softKeyboardActivate イベントが送出されます。 softKeyboardActivate イベントの送出時に、ステージの softKeyboardRect プロパティに、開いているキーボードに隠された領域のサイズが設定されます。これらのサイズを使用してコンテンツの移動またはサイズ変更を行い、キーボードが開いてユーザーが入力するときにコンテンツが適切に表示されるようにします（キーボードが閉じると、softKeyboardRect 長方形のサイズはすべてゼロになります）。

キーボードが閉じると、 softKeyboardDeactivate イベントが送出され、アプリケーション表示を通常に戻すことができます。

package  {        
    import flash.display.MovieClip; 
    import flash.events.SoftKeyboardEvent; 
    import flash.events.Event; 
    import flash.display.StageScaleMode; 
    import flash.display.StageAlign; 
    import flash.display.InteractiveObject; 
    import flash.text.TextFieldType; 
    import flash.text.TextField; 
     
    public class PanningExample extends MovieClip { 
                     
        private var textField:TextField = new TextField(); 
         
        public function PanningExample() {             
            this.stage.scaleMode = StageScaleMode.NO_SCALE; 
            this.stage.align = StageAlign.TOP_LEFT; 
             
            textField.y = this.stage.stageHeight - 201; 
            textField.width = this.stage.stageWidth; 
            textField.height = 200; 
            textField.type = TextFieldType.INPUT; 
            textField.border = true; 
            textField.wordWrap = true; 
            textField.multiline = true; 
             
            this.addChild( textField ); 
             
            //track soft keyboard and stage resize events 
            textField.addEventListener(SoftKeyboardEvent.SOFT_KEYBOARD_ACTIVATE, onKeyboardChange ); 
            textField.addEventListener(SoftKeyboardEvent.SOFT_KEYBOARD_DEACTIVATE, onKeyboardChange ); 
            this.stage.addEventListener( Event.RESIZE, onDisplayAreaChange ); 
        } 
     
        private function onDisplayAreaChange( event:Event ):void 
        { 
            textField.y = this.stage.stageHeight - 201; 
            textField.width = this.stage.stageWidth; 
        } 
         
        private function onKeyboardChange( event:SoftKeyboardEvent ):void 
        { 
            var field:InteractiveObject = textField; 
            var offset:int = 0; 
 
            //if the softkeyboard is open and the field is at least partially covered 
            if( (this.stage.softKeyboardRect.y != 0) && (field.y + field.height > this.stage.softKeyboardRect.y) ) 
                offset = field.y + field.height - this.stage.softKeyboardRect.y; 
                 
            //but don't push the top of the field above the top of the screen 
            if( field.y - offset < 0 ) offset += field.y - offset; 
             
            this.y = -offset;             
        }         
    } 
}

Twitter™ および Facebook の投稿には、Creative Commons の規約内容は適用されません。