配列の例：PlayList

PlayList クラスは Song オブジェクトセットを管理するクラスで、 曲をプレイリストに追加するための addSong() メソッドや、リストの曲をソートするための sortList() メソッドなど、様々な機能のパブリックメソッドを備えています。このクラスには、読み取り専用アクセッサープロパティの songList もあり、これによってプレイリストの実際の曲セットにアクセスできます。内部的には、PlayList クラスは、Array プライベート変数を使用して曲を追跡し続けます。

public class PlayList 
{ 
    private var _songs:Array; 
    private var _currentSort:SortProperty = null; 
    private var _needToSort:Boolean = false; 
    ... 
}

PlayList クラスが曲のリストを追跡し続けるために使用する _songs という Array 変数のほかに、2 つのプライベート変数（ _needToSort と _currentSort ）があり、前者はリストのソートが必要であるかどうかを、後者は指定の時刻にどのプロパティで曲のリストをソートするかを追跡し続けます。

すべてのオブジェクトの場合と同様に、Array インスタンスを宣言するだけでは Array の作成作業は完了しません。 Array インスタンスのプロパティまたはメソッドにアクセスする前に、このインスタンスを PlayList クラスのコンストラクターでインスタンス化しておく必要があります。

    public function PlayList() 
    { 
        this._songs = new Array(); 
        // Set the initial sorting. 
        this.sortList(SortProperty.TITLE); 
    }

コンストラクターの 1 行目は、 _songs 変数をインスタンス化して使用できる状態にします。さらに、 sortList() メソッドを呼び出し、最初のソート基準プロパティを設定します。

ユーザーが新しい曲をアプリケーションに登録すると、データ入力フォームのコードが PlayList クラスの addSong() メソッドを呼び出します。

    /** 
     * Adds a song to the playlist. 
     */ 
    public function addSong(song:Song):void 
    { 
        this._songs.push(song); 
        this._needToSort = true; 
    }

addSong() 内では、 _songs 配列の push() メソッドが呼び出され、その配列の新しい要素として addSong() に渡された Song オブジェクトが追加されます。 push() メソッドでは、以前に適用していたソートとは関係なく、新しい要素を配列の末尾に追加します。つまり、 push() メソッドを呼び出した後では、曲のリストはソート順が正しくなっていない可能性が高いため、 _needToSort 変数は true に設定されます。理論上は、 sortList() メソッドをすぐに呼び出すため、指定の時刻にリストをソートするかどうかを追跡し続けることは不要になります。しかし、実際には、取得する直前まで曲のリストをソートする必要はありません。 例えば、取得前に何曲かリストに追加したときなど、ソート操作を遅らせると、アプリケーションは不要なソートを実行しなくなります。

プレイリストが管理する Song インスタンスは複雑なオブジェクトであるため、そのアプリケーションのユーザーは、曲のタイトルまたは発表の年など、様々なプロパティに従ってプレイリストをソートしたいと考えることがあります。 PlayList アプリケーションにおいて、曲のリストをソートするタスクは、リストのソート基準としてのプロパティを見分けること、そのプロパティによるソート時に必要なソートオプションを指定すること、実際のソート操作を実行することの 3 つの部分から構成されます。

    public static const TITLE:SortProperty = new SortProperty("title"); 
    public static const ARTIST:SortProperty = new SortProperty("artist"); 
    public static const YEAR:SortProperty = new SortProperty("year");

        // Set the initial sorting. 
        this.sortList(SortProperty.TITLE);

    /** 
     * Sorts the list of songs according to the specified property. 
     */ 
    public function sortList(sortProperty:SortProperty):void 
    { 
        ... 
        var sortOptions:uint; 
        switch (sortProperty) 
        { 
            case SortProperty.TITLE: 
                sortOptions = Array.CASEINSENSITIVE; 
                break; 
            case SortProperty.ARTIST: 
                sortOptions = Array.CASEINSENSITIVE; 
                break; 
            case SortProperty.YEAR: 
                sortOptions = Array.NUMERIC; 
                break; 
        } 
         
        // Perform the actual sorting of the data. 
        this._songs.sortOn(sortProperty.propertyName, sortOptions); 
             
        // Save the current sort property. 
        this._currentSort = sortProperty; 
 
        // Record that the list is sorted. 
        this._needToSort = false; 
    }

配列を使用して曲のリストを PlayList クラスで維持する以外に、この例では Song クラスでも配列を使用して、曲についてのジャンルリストを管理するのに役立てています。 次の例で、Song クラスの定義からこのコードについて考えます。

private var _genres:String; 
 
public function Song(title:String, artist:String, year:uint, filename:String, genres:Array) 
{ 
    ... 
    // Genres are passed in as an array 
    // but stored as a semicolon-separated string. 
    this._genres = genres.join(";"); 
}

新しい Song インスタンスの作成時に、曲のジャンルの指定に使用する genres パラメーターが Array インスタンスとして定義されます。そのため、複数のジャンルを一緒のグループにまとめ、コンストラクターに渡せる 1 つの変数とするのに便利です。 ただし、内部的には Song クラスは、セミコロンで区切られた String インスタンスとして _genres プライベート変数にジャンルを維持します。Array パラメーターは、リテラルストリング値「 ; 」を区切り文字として指定して join() メソッドを呼び出すと、セミコロンで区切られたストリングに変換されます。

同じように、 genres アクセッサーを使用して、ジャンルを配列として設定また取得できます。

    public function get genres():Array 
    { 
        // Genres are stored as a semicolon-separated String, 
        // so they need to be transformed into an Array to pass them back out. 
        return this._genres.split(";"); 
    } 
    public function set genres(value:Array):void 
    { 
        // Genres are passed in as an array, 
        // but stored as a semicolon-separated string. 
        this._genres = value.join(";"); 
    }

genres set アクセッサーの動作は、コンストラクターの動作とまったく同じです。配列を受け取って join() メソッドを呼び出し、セミコロン区切りのストリングに変換します。 get アクセッサーは反対の操作を実行します。つまり、 _genres 変数の split() メソッドが呼び出されると、指定された区切り文字（リテラルストリング値 ";" など）を使用して、ストリングを値の配列に分割します。